Mercurial > cpdt > repo

annotate src/Match.v @ 168:0c5a41e9e508

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Remove unnecessary imports
author Adam Chlipala <adamc@hcoop.net>
date Wed, 05 Nov 2008 09:32:19 -0500
parents ce4cc7fa9b2b
children cbf2f74a5130
rev   line source
adamc@132 1 (* Copyright (c) 2008, Adam Chlipala
adamc@132 2 *
adamc@132 3 * This work is licensed under a
adamc@132 4 * Creative Commons Attribution-Noncommercial-No Derivative Works 3.0
adamc@132 5 * Unported License.
adamc@132 6 * The license text is available at:
adamc@132 7 * http://creativecommons.org/licenses/by-nc-nd/3.0/
adamc@132 8 *)
adamc@132 9
adamc@132 10 (* begin hide *)
adamc@132 11 Require Import List.
adamc@132 12
adamc@132 13 Require Import Tactics.
adamc@132 14
adamc@132 15 Set Implicit Arguments.
adamc@132 16 (* end hide *)
adamc@132 17
adamc@132 18
adamc@132 19 (** %\part{Proof Engineering}
adamc@132 20
adamc@132 21 \chapter{Proof Search in Ltac}% *)
adamc@132 22
adamc@132 23 (** We have seen many examples of proof automation so far. This chapter aims to give a principled presentation of the features of Ltac, focusing in particular on the Ltac [match] construct, which supports a novel approach to backtracking search. First, though, we will run through some useful automation tactics that are built into Coq. They are described in detail in the manual, so we only outline what is possible. *)
adamc@132 24
adamc@132 25 (** * Some Built-In Automation Tactics *)
adamc@132 26
adamc@132 27 (** A number of tactics are called repeatedly by [crush]. [intuition] simplifies propositional structure of goals. [congruence] applies the rules of equality and congruence closure, plus properties of constructors of inductive types. The [omega] tactic provides a complete decision procedure for a theory that is called quantifier-free linear arithmetic or Presburger arithmetic, depending on whom you ask. That is, [omega] proves any goal that follows from looking only at parts of that goal that can be interpreted as propositional formulas whose atomic formulas are basic comparison operations on natural numbers or integers.
adamc@132 28
adamc@132 29 The [ring] tactic solves goals by appealing to the axioms of rings or semi-rings (as in algebra), depending on the type involved. Coq developments may declare new types to be parts of rings and semi-rings by proving the associated axioms. There is a simlar tactic [field] for simplifying values in fields by conversion to fractions over rings. Both [ring] and [field] can only solve goals that are equalities. The [fourier] tactic uses Fourier's method to prove inequalities over real numbers, which are axiomatized in the Coq standard library.
adamc@132 30
adamc@133 31 The %\textit{%#<i>#setoid#</i>#%}% facility makes it possible to register new equivalence relations to be understood by tactics like [rewrite]. For instance, [Prop] is registered as a setoid with the equivalence relation "if and only if." The ability to register new setoids can be very useful in proofs of a kind common in math, where all reasoning is done after "modding out by a relation." *)
adamc@132 32
adamc@132 33
adamc@133 34 (** * Hint Databases *)
adamc@132 35
adamc@133 36 (** Another class of built-in tactics includes [auto], [eauto], and [autorewrite]. These are based on %\textit{%#<i>#hint databases#</i>#%}%, which we have seen extended in many examples so far. These tactics are important, because, in Ltac programming, we cannot create "global variables" whose values can be extended seamlessly by different modules in different source files. We have seen the advantages of hints so far, where [crush] can be defined once and for all, while still automatically applying the hints we add throughout developments.
adamc@133 37
adamc@133 38 The basic hints for [auto] and [eauto] are [Hint Immediate lemma], asking to try solving a goal immediately by applying the premise-free lemma; [Resolve lemma], which does the same but may add new premises that are themselves to be subjects of proof search; [Constructor type], which acts like [Resolve] applied to every constructor of an inductive type; and [Unfold ident], which tries unfolding [ident] when it appears at the head of a proof goal. Each of these [Hint] commands may be used with a suffix, as in [Hint Resolve lemma : my_db]. This adds the hint only to the specified database, so that it would only be used by, for instance, [auto with my_db]. An additional argument to [auto] specifies the maximum depth of proof trees to search in depth-first order, as in [auto 8] or [auto 8 with my_db]. The default depth is 5.
adamc@133 39
adamc@133 40 All of these [Hint] commands can be issued alternatively with a more primitive hint kind, [Extern]. A few examples should do best to explain how [Hint Extern] works. *)
adamc@133 41
adamc@133 42 Theorem bool_neq : true <> false.
adamc@141 43 (* begin thide *)
adamc@133 44 auto.
adamc@133 45 (** [crush] would have discharged this goal, but the default hint database for [auto] contains no hint that applies. *)
adamc@133 46 Abort.
adamc@133 47
adamc@133 48 (** It is hard to come up with a [bool]-specific hint that is not just a restatement of the theorem we mean to prove. Luckily, a simpler form suffices. *)
adamc@133 49
adamc@133 50 Hint Extern 1 (_ <> _) => congruence.
adamc@133 51
adamc@133 52 Theorem bool_neq : true <> false.
adamc@133 53 auto.
adamc@133 54 Qed.
adamc@141 55 (* end thide *)
adamc@133 56
adamc@133 57 (** Our hint says: "whenever the conclusion matches the pattern [_ <> _], try applying [congruence]." The [1] is a cost for this rule. During proof search, whenever multiple rules apply, rules are tried in increasing cost order, so it pays to assign high costs to relatively expensive [Extern] hints.
adamc@133 58
adamc@133 59 [Extern] hints may be implemented with the full Ltac language. This example shows a case where a hint uses a [match]. *)
adamc@133 60
adamc@133 61 Section forall_and.
adamc@133 62 Variable A : Set.
adamc@133 63 Variables P Q : A -> Prop.
adamc@133 64
adamc@133 65 Hypothesis both : forall x, P x /\ Q x.
adamc@133 66
adamc@133 67 Theorem forall_and : forall z, P z.
adamc@141 68 (* begin thide *)
adamc@133 69 crush.
adamc@133 70 (** [crush] makes no progress beyond what [intros] would have accomplished. [auto] will not apply the hypothesis [both] to prove the goal, because the conclusion of [both] does not unify with the conclusion of the goal. However, we can teach [auto] to handle this kind of goal. *)
adamc@133 71
adamc@133 72 Hint Extern 1 (P ?X) =>
adamc@133 73 match goal with
adamc@133 74 | [ H : forall x, P x /\ _ |- _ ] => apply (proj1 (H X))
adamc@133 75 end.
adamc@133 76
adamc@133 77 auto.
adamc@133 78 Qed.
adamc@141 79 (* end thide *)
adamc@133 80
adamc@133 81 (** We see that an [Extern] pattern may bind unification variables that we use in the associated tactic. [proj1] is a function from the standard library for extracting a proof of [R] from a proof of [R /\ S]. *)
adamc@133 82 End forall_and.
adamc@133 83
adamc@133 84 (** After our success on this example, we might get more ambitious and seek to generalize the hint to all possible predicates [P].
adamc@133 85
adamc@133 86 [[
adamc@133 87 Hint Extern 1 (?P ?X) =>
adamc@133 88 match goal with
adamc@133 89 | [ H : forall x, ?P x /\ _ |- _ ] => apply (proj1 (H X))
adamc@133 90 end.
adamc@133 91
adamc@134 92 [[
adamc@133 93 User error: Bound head variable
adamc@134 94 ]]
adamc@133 95
adamc@134 96 Coq's [auto] hint databases work as tables mapping %\textit{%#<i>#head symbols#</i>#%}% to lists of tactics to try. Because of this, the constant head of an [Extern] pattern must be determinable statically. In our first [Extern] hint, the head symbol was [not], since [x <> y] desugars to [not (eq x y)]; and, in the second example, the head symbol was [P].
adamc@133 97
adamc@134 98 This restriction on [Extern] hints is the main limitation of the [auto] mechanism, preventing us from using it for general context simplifications that are not keyed off of the form of the conclusion. This is perhaps just as well, since we can often code more efficient tactics with specialized Ltac programs, and we will see how in later sections of the chapter.
adamc@134 99
adamc@134 100 We have used [Hint Rewrite] in many examples so far. [crush] uses these hints by calling [autorewrite]. Our rewrite hints have taken the form [Hint Rewrite lemma : cpdt], adding them to the [cpdt] rewrite database. This is because, in contrast to [auto], [autorewrite] has no default database. Thus, we set the convention that [crush] uses the [cpdt] database.
adamc@134 101
adamc@134 102 This example shows a direct use of [autorewrite]. *)
adamc@134 103
adamc@134 104 Section autorewrite.
adamc@134 105 Variable A : Set.
adamc@134 106 Variable f : A -> A.
adamc@134 107
adamc@134 108 Hypothesis f_f : forall x, f (f x) = f x.
adamc@134 109
adamc@134 110 Hint Rewrite f_f : my_db.
adamc@134 111
adamc@134 112 Lemma f_f_f : forall x, f (f (f x)) = f x.
adamc@134 113 intros; autorewrite with my_db; reflexivity.
adamc@134 114 Qed.
adamc@134 115
adamc@134 116 (** There are a few ways in which [autorewrite] can lead to trouble when insufficient care is taken in choosing hints. First, the set of hints may define a nonterminating rewrite system, in which case invocations to [autorewrite] may not terminate. Second, we may add hints that "lead [autorewrite] down the wrong path." For instance: *)
adamc@134 117
adamc@134 118 Section garden_path.
adamc@134 119 Variable g : A -> A.
adamc@134 120 Hypothesis f_g : forall x, f x = g x.
adamc@134 121 Hint Rewrite f_g : my_db.
adamc@134 122
adamc@134 123 Lemma f_f_f' : forall x, f (f (f x)) = f x.
adamc@134 124 intros; autorewrite with my_db.
adamc@134 125 (** [[
adamc@134 126
adamc@134 127 ============================
adamc@134 128 g (g (g x)) = g x
adamc@134 129 ]] *)
adamc@134 130 Abort.
adamc@134 131
adamc@134 132 (** Our new hint was used to rewrite the goal into a form where the old hint could no longer be applied. This "non-monotonicity" of rewrite hints contrasts with the situation for [auto], where new hints may slow down proof search but can never "break" old proofs. *)
adamc@134 133
adamc@134 134 Reset garden_path.
adamc@134 135
adamc@134 136 (** [autorewrite] works with quantified equalities that include additional premises, but we must be careful to avoid similar incorrect rewritings. *)
adamc@134 137
adamc@134 138 Section garden_path.
adamc@134 139 Variable P : A -> Prop.
adamc@134 140 Variable g : A -> A.
adamc@134 141 Hypothesis f_g : forall x, P x -> f x = g x.
adamc@134 142 Hint Rewrite f_g : my_db.
adamc@134 143
adamc@134 144 Lemma f_f_f' : forall x, f (f (f x)) = f x.
adamc@134 145 intros; autorewrite with my_db.
adamc@134 146 (** [[
adamc@134 147
adamc@134 148 ============================
adamc@134 149 g (g (g x)) = g x
adamc@134 150
adamc@134 151 subgoal 2 is:
adamc@134 152 P x
adamc@134 153 subgoal 3 is:
adamc@134 154 P (f x)
adamc@134 155 subgoal 4 is:
adamc@134 156 P (f x)
adamc@134 157 ]] *)
adamc@134 158 Abort.
adamc@134 159
adamc@134 160 (** The inappropriate rule fired the same three times as before, even though we know we will not be able to prove the premises. *)
adamc@134 161
adamc@134 162 Reset garden_path.
adamc@134 163
adamc@134 164 (** Our final, successful, attempt uses an extra argument to [Hint Rewrite] that specifies a tactic to apply to generated premises. *)
adamc@134 165
adamc@134 166 Section garden_path.
adamc@134 167 Variable P : A -> Prop.
adamc@134 168 Variable g : A -> A.
adamc@134 169 Hypothesis f_g : forall x, P x -> f x = g x.
adamc@141 170 (* begin thide *)
adamc@134 171 Hint Rewrite f_g using assumption : my_db.
adamc@141 172 (* end thide *)
adamc@134 173
adamc@134 174 Lemma f_f_f' : forall x, f (f (f x)) = f x.
adamc@141 175 (* begin thide *)
adamc@134 176 intros; autorewrite with my_db; reflexivity.
adamc@134 177 Qed.
adamc@141 178 (* end thide *)
adamc@134 179
adamc@134 180 (** [autorewrite] will still use [f_g] when the generated premise is among our assumptions. *)
adamc@134 181
adamc@134 182 Lemma f_f_f_g : forall x, P x -> f (f x) = g x.
adamc@141 183 (* begin thide *)
adamc@134 184 intros; autorewrite with my_db; reflexivity.
adamc@141 185 (* end thide *)
adamc@134 186 Qed.
adamc@134 187 End garden_path.
adamc@134 188
adamc@134 189 (** It can also be useful to use the [autorewrite with db in *] form, which does rewriting in hypotheses, as well as in the conclusion. *)
adamc@134 190
adamc@134 191 Lemma in_star : forall x y, f (f (f (f x))) = f (f y)
adamc@134 192 -> f x = f (f (f y)).
adamc@141 193 (* begin thide *)
adamc@134 194 intros; autorewrite with my_db in *; assumption.
adamc@141 195 (* end thide *)
adamc@134 196 Qed.
adamc@134 197
adamc@134 198 End autorewrite.
adamc@135 199
adamc@135 200
adamc@135 201 (** * Ltac Programming Basics *)
adamc@135 202
adamc@135 203 (** We have already seen many examples of Ltac programs. In the rest of this chapter, we attempt to give a more principled introduction to the important features and design patterns.
adamc@135 204
adamc@135 205 One common use for [match] tactics is identification of subjects for case analysis, as we see in this tactic definition. *)
adamc@135 206
adamc@141 207 (* begin thide *)
adamc@135 208 Ltac find_if :=
adamc@135 209 match goal with
adamc@135 210 | [ |- if ?X then _ else _ ] => destruct X
adamc@135 211 end.
adamc@141 212 (* end thide *)
adamc@135 213
adamc@135 214 (** The tactic checks if the conclusion is an [if], [destruct]ing the test expression if so. Certain classes of theorem are trivial to prove automatically with such a tactic. *)
adamc@135 215
adamc@135 216 Theorem hmm : forall (a b c : bool),
adamc@135 217 if a
adamc@135 218 then if b
adamc@135 219 then True
adamc@135 220 else True
adamc@135 221 else if c
adamc@135 222 then True
adamc@135 223 else True.
adamc@141 224 (* begin thide *)
adamc@135 225 intros; repeat find_if; constructor.
adamc@135 226 Qed.
adamc@141 227 (* end thide *)
adamc@135 228
adamc@135 229 (** The [repeat] that we use here is called a %\textit{%#<i>#tactical#</i>#%}%, or tactic combinator. The behavior of [repeat t] is to loop through running [t], running [t] on all generated subgoals, running [t] on %\textit{%#<i>#their#</i>#%}% generated subgoals, and so on. When [t] fails at any point in this search tree, that particular subgoal is left to be handled by later tactics. Thus, it is important never to use [repeat] with a tactic that always succeeds.
adamc@135 230
adamc@135 231 Another very useful Ltac building block is %\textit{%#<i>#context patterns#</i>#%}%. *)
adamc@135 232
adamc@141 233 (* begin thide *)
adamc@135 234 Ltac find_if_inside :=
adamc@135 235 match goal with
adamc@135 236 | [ |- context[if ?X then _ else _] ] => destruct X
adamc@135 237 end.
adamc@141 238 (* end thide *)
adamc@135 239
adamc@135 240 (** The behavior of this tactic is to find any subterm of the conclusion that is an [if] and then [destruct] the test expression. This version subsumes [find_if]. *)
adamc@135 241
adamc@135 242 Theorem hmm' : forall (a b c : bool),
adamc@135 243 if a
adamc@135 244 then if b
adamc@135 245 then True
adamc@135 246 else True
adamc@135 247 else if c
adamc@135 248 then True
adamc@135 249 else True.
adamc@141 250 (* begin thide *)
adamc@135 251 intros; repeat find_if_inside; constructor.
adamc@135 252 Qed.
adamc@141 253 (* end thide *)
adamc@135 254
adamc@135 255 (** We can also use [find_if_inside] to prove goals that [find_if] does not simplify sufficiently. *)
adamc@135 256
adamc@141 257 Theorem hmm2 : forall (a b : bool),
adamc@135 258 (if a then 42 else 42) = (if b then 42 else 42).
adamc@141 259 (* begin thide *)
adamc@135 260 intros; repeat find_if_inside; reflexivity.
adamc@135 261 Qed.
adamc@141 262 (* end thide *)
adamc@135 263
adamc@135 264 (** Many decision procedures can be coded in Ltac via "[repeat match] loops." For instance, we can implement a subset of the functionality of [tauto]. *)
adamc@135 265
adamc@141 266 (* begin thide *)
adamc@135 267 Ltac my_tauto :=
adamc@135 268 repeat match goal with
adamc@135 269 | [ H : ?P |- ?P ] => exact H
adamc@135 270
adamc@135 271 | [ |- True ] => constructor
adamc@135 272 | [ |- _ /\ _ ] => constructor
adamc@135 273 | [ |- _ -> _ ] => intro
adamc@135 274
adamc@135 275 | [ H : False |- _ ] => destruct H
adamc@135 276 | [ H : _ /\ _ |- _ ] => destruct H
adamc@135 277 | [ H : _ \/ _ |- _ ] => destruct H
adamc@135 278
adamc@135 279 | [ H1 : ?P -> ?Q, H2 : ?P |- _ ] =>
adamc@135 280 let H := fresh "H" in
adamc@135 281 generalize (H1 H2); clear H1; intro H
adamc@135 282 end.
adamc@141 283 (* end thide *)
adamc@135 284
adamc@135 285 (** Since [match] patterns can share unification variables between hypothesis and conclusion patterns, it is easy to figure out when the conclusion matches a hypothesis. The [exact] tactic solves a goal completely when given a proof term of the proper type.
adamc@135 286
adamc@135 287 It is also trivial to implement the "introduction rules" for a few of the connectives. Implementing elimination rules is only a little more work, since we must bind a name for a hypothesis to [destruct].
adamc@135 288
adamc@135 289 The last rule implements modus ponens. The most interesting part is the use of the Ltac-level [let] with a [fresh] expression. [fresh] takes in a name base and returns a fresh hypothesis variable based on that name. We use the new name variable [H] as the name we assign to the result of modus ponens. The use of [generalize] changes our conclusion to be an implication from [Q]. We clear the original hypothesis and move [Q] into the context with name [H]. *)
adamc@135 290
adamc@135 291 Section propositional.
adamc@135 292 Variables P Q R : Prop.
adamc@135 293
adamc@138 294 Theorem propositional : (P \/ Q \/ False) /\ (P -> Q) -> True /\ Q.
adamc@141 295 (* begin thide *)
adamc@135 296 my_tauto.
adamc@135 297 Qed.
adamc@141 298 (* end thide *)
adamc@135 299 End propositional.
adamc@135 300
adamc@135 301 (** It was relatively easy to implement modus ponens, because we do not lose information by clearing every implication that we use. If we want to implement a similarly-complete procedure for quantifier instantiation, we need a way to ensure that a particular proposition is not already included among our hypotheses. To do that effectively, we first need to learn a bit more about the semantics of [match].
adamc@135 302
adamc@135 303 It is tempting to assume that [match] works like it does in ML. In fact, there are a few critical differences in its behavior. One is that we may include arbitrary expressions in patterns, instead of being restricted to variables and constructors. Another is that the same variable may appear multiple times, inducing an implicit equality constraint.
adamc@135 304
adamc@135 305 There is a related pair of two other differences that are much more important than the others. [match] has a %\textit{%#<i>#backtracking semantics for failure#</i>#%}%. In ML, pattern matching works by finding the first pattern to match and then executing its body. If the body raises an exception, then the overall match raises the same exception. In Coq, failures in case bodies instead trigger continued search through the list of cases.
adamc@135 306
adamc@135 307 For instance, this (unnecessarily verbose) proof script works: *)
adamc@135 308
adamc@135 309 Theorem m1 : True.
adamc@135 310 match goal with
adamc@135 311 | [ |- _ ] => intro
adamc@135 312 | [ |- True ] => constructor
adamc@135 313 end.
adamc@141 314 (* begin thide *)
adamc@135 315 Qed.
adamc@141 316 (* end thide *)
adamc@135 317
adamc@135 318 (** The first case matches trivially, but its body tactic fails, since the conclusion does not begin with a quantifier or implication. In a similar ML match, that would mean that the whole pattern-match fails. In Coq, we backtrack and try the next pattern, which also matches. Its body tactic succeeds, so the overall tactic succeeds as well.
adamc@135 319
adamc@135 320 The example shows how failure can move to a different pattern within a [match]. Failure can also trigger an attempt to find %\textit{%#<i>#a different way of matching a single pattern#</i>#%}%. Consider another example: *)
adamc@135 321
adamc@135 322 Theorem m2 : forall P Q R : Prop, P -> Q -> R -> Q.
adamc@135 323 intros; match goal with
adamc@135 324 | [ H : _ |- _ ] => pose H
adamc@135 325 end.
adamc@135 326 (** [[
adamc@135 327
adamc@135 328 r := H1 : R
adamc@135 329 ============================
adamc@135 330 Q
adamc@135 331 ]]
adamc@135 332
adamc@135 333 By applying [pose], a convenient debugging tool for "leaking information out of [match]es," we see that this [match] first tries binding [H] to [H1], which cannot be used to prove [Q]. Nonetheless, the following variation on the tactic succeeds at proving the goal: *)
adamc@135 334
adamc@141 335 (* begin thide *)
adamc@135 336 match goal with
adamc@135 337 | [ H : _ |- _ ] => exact H
adamc@135 338 end.
adamc@135 339 Qed.
adamc@141 340 (* end thide *)
adamc@135 341
adamc@135 342 (** The tactic first unifies [H] with [H1], as before, but [exact H] fails in that case, so the tactic engine searches for more possible values of [H]. Eventually, it arrives at the correct value, so that [exact H] and the overall tactic succeed. *)
adamc@135 343
adamc@135 344 (** Now we are equipped to implement a tactic for checking that a proposition is not among our hypotheses: *)
adamc@135 345
adamc@141 346 (* begin thide *)
adamc@135 347 Ltac notHyp P :=
adamc@135 348 match goal with
adamc@135 349 | [ _ : P |- _ ] => fail 1
adamc@135 350 | _ =>
adamc@135 351 match P with
adamc@135 352 | ?P1 /\ ?P2 => first [ notHyp P1 | notHyp P2 | fail 2 ]
adamc@135 353 | _ => idtac
adamc@135 354 end
adamc@135 355 end.
adamc@141 356 (* end thide *)
adamc@135 357
adamc@135 358 (** We use the equality checking that is built into pattern-matching to see if there is a hypothesis that matches the proposition exactly. If so, we use the [fail] tactic. Without arguments, [fail] signals normal tactic failure, as you might expect. When [fail] is passed an argument [n], [n] is used to count outwards through the enclosing cases of backtracking search. In this case, [fail 1] says "fail not just in this pattern-matching branch, but for the whole [match]." The second case will never be tried when the [fail 1] is reached.
adamc@135 359
adamc@135 360 This second case, used when [P] matches no hypothesis, checks if [P] is a conjunction. Other simplifications may have split conjunctions into their component formulas, so we need to check that at least one of those components is also not represented. To achieve this, we apply the [first] tactical, which takes a list of tactics and continues down the list until one of them does not fail. The [fail 2] at the end says to [fail] both the [first] and the [match] wrapped around it.
adamc@135 361
adamc@135 362 The body of the [?P1 /\ ?P2] case guarantees that, if it is reached, we either succeed completely or fail completely. Thus, if we reach the wildcard case, [P] is not a conjunction. We use [idtac], a tactic that would be silly to apply on its own, since its effect is to succeed at doing nothing. Nonetheless, [idtac] is a useful placeholder for cases like what we see here.
adamc@135 363
adamc@135 364 With the non-presence check implemented, it is easy to build a tactic that takes as input a proof term and adds its conclusion as a new hypothesis, only if that conclusion is not already present, failing otherwise. *)
adamc@135 365
adamc@141 366 (* begin thide *)
adamc@135 367 Ltac extend pf :=
adamc@135 368 let t := type of pf in
adamc@135 369 notHyp t; generalize pf; intro.
adamc@141 370 (* end thide *)
adamc@135 371
adamc@135 372 (** We see the useful [type of] operator of Ltac. This operator could not be implemented in Gallina, but it is easy to support in Ltac. We end up with [t] bound to the type of [pf]. We check that [t] is not already present. If so, we use a [generalize]/[intro] combo to add a new hypothesis proved by [pf].
adamc@135 373
adamc@135 374 With these tactics defined, we can write a tactic [completer] for adding to the context all consequences of a set of simple first-order formulas. *)
adamc@135 375
adamc@141 376 (* begin thide *)
adamc@135 377 Ltac completer :=
adamc@135 378 repeat match goal with
adamc@135 379 | [ |- _ /\ _ ] => constructor
adamc@135 380 | [ H : _ /\ _ |- _ ] => destruct H
adamc@135 381 | [ H : ?P -> ?Q, H' : ?P |- _ ] =>
adamc@135 382 generalize (H H'); clear H; intro H
adamc@135 383 | [ |- forall x, _ ] => intro
adamc@135 384
adamc@135 385 | [ H : forall x, ?P x -> _, H' : ?P ?X |- _ ] =>
adamc@135 386 extend (H X H')
adamc@135 387 end.
adamc@141 388 (* end thide *)
adamc@135 389
adamc@135 390 (** We use the same kind of conjunction and implication handling as previously. Note that, since [->] is the special non-dependent case of [forall], the fourth rule handles [intro] for implications, too.
adamc@135 391
adamc@135 392 In the fifth rule, when we find a [forall] fact [H] with a premise matching one of our hypotheses, we add the appropriate instantiation of [H]'s conclusion, if we have not already added it.
adamc@135 393
adamc@135 394 We can check that [completer] is working properly: *)
adamc@135 395
adamc@135 396 Section firstorder.
adamc@135 397 Variable A : Set.
adamc@135 398 Variables P Q R S : A -> Prop.
adamc@135 399
adamc@135 400 Hypothesis H1 : forall x, P x -> Q x /\ R x.
adamc@135 401 Hypothesis H2 : forall x, R x -> S x.
adamc@135 402
adamc@135 403 Theorem fo : forall x, P x -> S x.
adamc@141 404 (* begin thide *)
adamc@135 405 completer.
adamc@135 406 (** [[
adamc@135 407
adamc@135 408 x : A
adamc@135 409 H : P x
adamc@135 410 H0 : Q x
adamc@135 411 H3 : R x
adamc@135 412 H4 : S x
adamc@135 413 ============================
adamc@135 414 S x
adamc@135 415 ]] *)
adamc@135 416
adamc@135 417 assumption.
adamc@135 418 Qed.
adamc@141 419 (* end thide *)
adamc@135 420 End firstorder.
adamc@135 421
adamc@135 422 (** We narrowly avoided a subtle pitfall in our definition of [completer]. Let us try another definition that even seems preferable to the original, to the untrained eye. *)
adamc@135 423
adamc@141 424 (* begin thide *)
adamc@135 425 Ltac completer' :=
adamc@135 426 repeat match goal with
adamc@135 427 | [ |- _ /\ _ ] => constructor
adamc@135 428 | [ H : _ /\ _ |- _ ] => destruct H
adamc@135 429 | [ H : ?P -> _, H' : ?P |- _ ] =>
adamc@135 430 generalize (H H'); clear H; intro H
adamc@135 431 | [ |- forall x, _ ] => intro
adamc@135 432
adamc@135 433 | [ H : forall x, ?P x -> _, H' : ?P ?X |- _ ] =>
adamc@135 434 extend (H X H')
adamc@135 435 end.
adamc@141 436 (* end thide *)
adamc@135 437
adamc@135 438 (** The only difference is in the modus ponens rule, where we have replaced an unused unification variable [?Q] with a wildcard. Let us try our example again with this version: *)
adamc@135 439
adamc@135 440 Section firstorder'.
adamc@135 441 Variable A : Set.
adamc@135 442 Variables P Q R S : A -> Prop.
adamc@135 443
adamc@135 444 Hypothesis H1 : forall x, P x -> Q x /\ R x.
adamc@135 445 Hypothesis H2 : forall x, R x -> S x.
adamc@135 446
adamc@135 447 Theorem fo' : forall x, P x -> S x.
adamc@141 448 (* begin thide *)
adamc@135 449 (** [[
adamc@135 450
adamc@135 451 completer'.
adamc@135 452
adamc@135 453 Coq loops forever at this point. What went wrong? *)
adamc@135 454 Abort.
adamc@141 455 (* end thide *)
adamc@135 456 End firstorder'.
adamc@136 457
adamc@136 458 (** A few examples should illustrate the issue. Here we see a [match]-based proof that works fine: *)
adamc@136 459
adamc@136 460 Theorem t1 : forall x : nat, x = x.
adamc@136 461 match goal with
adamc@136 462 | [ |- forall x, _ ] => trivial
adamc@136 463 end.
adamc@141 464 (* begin thide *)
adamc@136 465 Qed.
adamc@141 466 (* end thide *)
adamc@136 467
adamc@136 468 (** This one fails. *)
adamc@136 469
adamc@141 470 (* begin thide *)
adamc@136 471 Theorem t1' : forall x : nat, x = x.
adamc@136 472 (** [[
adamc@136 473
adamc@136 474 match goal with
adamc@136 475 | [ |- forall x, ?P ] => trivial
adamc@136 476 end.
adamc@136 477
adamc@136 478 [[
adamc@136 479 User error: No matching clauses for match goal
adamc@136 480 ]] *)
adamc@136 481 Abort.
adamc@141 482 (* end thide *)
adamc@136 483
adamc@136 484 (** The problem is that unification variables may not contain locally-bound variables. In this case, [?P] would need to be bound to [x = x], which contains the local quantified variable [x]. By using a wildcard in the earlier version, we avoided this restriction.
adamc@136 485
adamc@136 486 The Coq 8.2 release includes a special pattern form for a unification variable with an explicit set of free variables. That unification variable is then bound to a function from the free variables to the "real" value. In Coq 8.1 and earlier, there is no such workaround.
adamc@136 487
adamc@136 488 No matter which version you use, it is important to be aware of this restriction. As we have alluded to, the restriction is the culprit behind the infinite-looping behavior of [completer']. We unintentionally match quantified facts with the modus ponens rule, circumventing the "already present" check and leading to different behavior. *)
adamc@137 489
adamc@137 490
adamc@137 491 (** * Functional Programming in Ltac *)
adamc@137 492
adamc@141 493 (* EX: Write a list length function in Ltac. *)
adamc@141 494
adamc@137 495 (** Ltac supports quite convenient functional programming, with a Lisp-with-syntax kind of flavor. However, there are a few syntactic conventions involved in getting programs to be accepted. The Ltac syntax is optimized for tactic-writing, so one has to deal with some inconveniences in writing more standard functional programs.
adamc@137 496
adamc@137 497 To illustrate, let us try to write a simple list length function. We start out writing it just like in Gallina, simply replacing [Fixpoint] (and its annotations) with [Ltac].
adamc@137 498
adamc@137 499 [[
adamc@137 500 Ltac length ls :=
adamc@137 501 match ls with
adamc@137 502 | nil => O
adamc@137 503 | _ :: ls' => S (length ls')
adamc@137 504 end.
adamc@137 505
adamc@137 506 [[
adamc@137 507 Error: The reference ls' was not found in the current environment
adamc@137 508 ]]
adamc@137 509
adamc@137 510 At this point, we hopefully remember that pattern variable names must be prefixed by question marks in Ltac.
adamc@137 511
adamc@137 512 [[
adamc@137 513 Ltac length ls :=
adamc@137 514 match ls with
adamc@137 515 | nil => O
adamc@137 516 | _ :: ?ls' => S (length ls')
adamc@137 517 end.
adamc@137 518
adamc@137 519 [[
adamc@137 520 Error: The reference S was not found in the current environment
adamc@137 521 ]]
adamc@137 522
adamc@137 523 The problem is that Ltac treats the expression [S (length ls')] as an invocation of a tactic [S] with argument [length ls']. We need to use a special annotation to "escape into" the Gallina parsing nonterminal. *)
adamc@137 524
adamc@141 525 (* begin thide *)
adamc@137 526 Ltac length ls :=
adamc@137 527 match ls with
adamc@137 528 | nil => O
adamc@137 529 | _ :: ?ls' => constr:(S (length ls'))
adamc@137 530 end.
adamc@137 531
adamc@137 532 (** This definition is accepted. It can be a little awkward to test Ltac definitions like this. Here is one method. *)
adamc@137 533
adamc@137 534 Goal False.
adamc@137 535 let n := length (1 :: 2 :: 3 :: nil) in
adamc@137 536 pose n.
adamc@137 537 (** [[
adamc@137 538
adamc@137 539 n := S (length (2 :: 3 :: nil)) : nat
adamc@137 540 ============================
adamc@137 541 False
adamc@137 542 ]]
adamc@137 543
adamc@137 544 [n] only has the length calculation unrolled one step. What has happened here is that, by escaping into the [constr] nonterminal, we referred to the [length] function of Gallina, rather than the [length] Ltac function that we are defining. *)Abort.
adamc@137 545
adamc@137 546 Reset length.
adamc@137 547
adamc@137 548 (** The thing to remember is that Gallina terms built by tactics must be bound explicitly via [let] or a similar technique, rather than inserting Ltac calls directly in other Gallina terms. *)
adamc@137 549
adamc@137 550 Ltac length ls :=
adamc@137 551 match ls with
adamc@137 552 | nil => O
adamc@137 553 | _ :: ?ls' =>
adamc@137 554 let ls'' := length ls' in
adamc@137 555 constr:(S ls'')
adamc@137 556 end.
adamc@137 557
adamc@137 558 Goal False.
adamc@137 559 let n := length (1 :: 2 :: 3 :: nil) in
adamc@137 560 pose n.
adamc@137 561 (** [[
adamc@137 562
adamc@137 563 n := 3 : nat
adamc@137 564 ============================
adamc@137 565 False
adamc@137 566 ]] *)
adamc@137 567 Abort.
adamc@141 568 (* end thide *)
adamc@141 569
adamc@141 570 (* EX: Write a list map function in Ltac. *)
adamc@137 571
adamc@137 572 (** We can also use anonymous function expressions and local function definitions in Ltac, as this example of a standard list [map] function shows. *)
adamc@137 573
adamc@141 574 (* begin thide *)
adamc@137 575 Ltac map T f :=
adamc@137 576 let rec map' ls :=
adamc@137 577 match ls with
adamc@137 578 | nil => constr:(@nil T)
adamc@137 579 | ?x :: ?ls' =>
adamc@137 580 let x' := f x in
adamc@137 581 let ls'' := map' ls' in
adamc@137 582 constr:(x' :: ls'')
adamc@137 583 end in
adamc@137 584 map'.
adamc@137 585
adamc@137 586 (** Ltac functions can have no implicit arguments. It may seem surprising that we need to pass [T], the carried type of the output list, explicitly. We cannot just use [type of f], because [f] is an Ltac term, not a Gallina term, and Ltac programs are dynamically typed. [f] could use very syntactic methods to decide to return differently typed terms for different inputs. We also could not replace [constr:(@nil T)] with [constr:nil], because we have no strongly-typed context to use to infer the parameter to [nil]. Luckily, we do have sufficient context within [constr:(x' :: ls'')].
adamc@137 587
adamc@137 588 Sometimes we need to employ the opposite direction of "nonterminal escape," when we want to pass a complicated tactic expression as an argument to another tactic, as we might want to do in invoking [map]. *)
adamc@137 589
adamc@137 590 Goal False.
adamc@137 591 let ls := map (nat * nat)%type ltac:(fun x => constr:(x, x)) (1 :: 2 :: 3 :: nil) in
adamc@137 592 pose ls.
adamc@137 593 (** [[
adamc@137 594
adamc@137 595 l := (1, 1) :: (2, 2) :: (3, 3) :: nil : list (nat * nat)
adamc@137 596 ============================
adamc@137 597 False
adamc@137 598 ]] *)
adamc@137 599 Abort.
adamc@141 600 (* end thide *)
adamc@137 601
adamc@138 602
adamc@139 603 (** * Recursive Proof Search *)
adamc@139 604
adamc@139 605 (** Deciding how to instantiate quantifiers is one of the hardest parts of automated first-order theorem proving. For a given problem, we can consider all possible bounded-length sequences of quantifier instantiations, applying only propositional reasoning at the end. This is probably a bad idea for almost all goals, but it makes for a nice example of recursive proof search procedures in Ltac.
adamc@139 606
adamc@139 607 We can consider the maximum "dependency chain" length for a first-order proof. We define the chain length for a hypothesis to be 0, and the chain length for an instantiation of a quantified fact to be one greater than the length for that fact. The tactic [inster n] is meant to try all possible proofs with chain length at most [n]. *)
adamc@139 608
adamc@141 609 (* begin thide *)
adamc@139 610 Ltac inster n :=
adamc@139 611 intuition;
adamc@139 612 match n with
adamc@139 613 | S ?n' =>
adamc@139 614 match goal with
adamc@139 615 | [ H : forall x : ?T, _, x : ?T |- _ ] => generalize (H x); inster n'
adamc@139 616 end
adamc@139 617 end.
adamc@141 618 (* end thide *)
adamc@139 619
adamc@139 620 (** [inster] begins by applying propositional simplification. Next, it checks if any chain length remains. If so, it tries all possible ways of instantiating quantified hypotheses with properly-typed local variables. It is critical to realize that, if the recursive call [inster n'] fails, then the [match goal] just seeks out another way of unifying its pattern against proof state. Thus, this small amount of code provides an elegant demonstration of how backtracking [match] enables exhaustive search.
adamc@139 621
adamc@139 622 We can verify the efficacy of [inster] with two short examples. The built-in [firstorder] tactic (with no extra arguments) is able to prove the first but not the second. *)
adamc@139 623
adamc@139 624 Section test_inster.
adamc@139 625 Variable A : Set.
adamc@139 626 Variables P Q : A -> Prop.
adamc@139 627 Variable f : A -> A.
adamc@139 628 Variable g : A -> A -> A.
adamc@139 629
adamc@139 630 Hypothesis H1 : forall x y, P (g x y) -> Q (f x).
adamc@139 631
adamc@139 632 Theorem test_inster : forall x y, P (g x y) -> Q (f x).
adamc@139 633 intros; inster 2.
adamc@139 634 Qed.
adamc@139 635
adamc@139 636 Hypothesis H3 : forall u v, P u /\ P v /\ u <> v -> P (g u v).
adamc@139 637 Hypothesis H4 : forall u, Q (f u) -> P u /\ P (f u).
adamc@139 638
adamc@139 639 Theorem test_inster2 : forall x y, x <> y -> P x -> Q (f y) -> Q (f x).
adamc@139 640 intros; inster 3.
adamc@139 641 Qed.
adamc@139 642 End test_inster.
adamc@139 643
adamc@140 644 (** The style employed in the definition of [inster] can seem very counterintuitive to functional programmers. Usually, functional programs accumulate state changes in explicit arguments to recursive functions. In Ltac, the state of the current subgoal is always implicit. Nonetheless, in contrast to general imperative programming, it is easy to undo any changes to this state, and indeed such "undoing" happens automatically at failures within [match]es. In this way, Ltac programming is similar to programming in Haskell with a stateful failure monad that supports a composition operator along the lines of the [first] tactical.
adamc@140 645
adamc@140 646 Functional programming purists may react indignantly to the suggestion of programming this way. Nonetheless, as with other kinds of "monadic programming," many problems are much simpler to solve with Ltac than they would be with explicit, pure proof manipulation in ML or Haskell. To demonstrate, we will write a basic simplification procedure for logical implications.
adamc@140 647
adamc@140 648 This procedure is inspired by one for separation logic, where conjuncts in formulas are thought of as "resources," such that we lose no completeness by "crossing out" equal conjuncts on the two sides of an implication. This process is complicated by the fact that, for reasons of modularity, our formulas can have arbitrary nested tree structure (branching at conjunctions) and may include existential quantifiers. It is helpful for the matching process to "go under" quantifiers and in fact decide how to instantiate existential quantifiers in the conclusion.
adamc@140 649
adamc@140 650 To distinguish the implications that our tactic handles from the implications that will show up as "plumbing" in various lemmas, we define a wrapper definition, a notation, and a tactic. *)
adamc@138 651
adamc@138 652 Definition imp (P1 P2 : Prop) := P1 -> P2.
adamc@140 653 Infix "-->" := imp (no associativity, at level 95).
adamc@140 654 Ltac imp := unfold imp; firstorder.
adamc@138 655
adamc@140 656 (** These lemmas about [imp] will be useful in the tactic that we will write. *)
adamc@138 657
adamc@138 658 Theorem and_True_prem : forall P Q,
adamc@138 659 (P /\ True --> Q)
adamc@138 660 -> (P --> Q).
adamc@138 661 imp.
adamc@138 662 Qed.
adamc@138 663
adamc@138 664 Theorem and_True_conc : forall P Q,
adamc@138 665 (P --> Q /\ True)
adamc@138 666 -> (P --> Q).
adamc@138 667 imp.
adamc@138 668 Qed.
adamc@138 669
adamc@138 670 Theorem assoc_prem1 : forall P Q R S,
adamc@138 671 (P /\ (Q /\ R) --> S)
adamc@138 672 -> ((P /\ Q) /\ R --> S).
adamc@138 673 imp.
adamc@138 674 Qed.
adamc@138 675
adamc@138 676 Theorem assoc_prem2 : forall P Q R S,
adamc@138 677 (Q /\ (P /\ R) --> S)
adamc@138 678 -> ((P /\ Q) /\ R --> S).
adamc@138 679 imp.
adamc@138 680 Qed.
adamc@138 681
adamc@138 682 Theorem comm_prem : forall P Q R,
adamc@138 683 (P /\ Q --> R)
adamc@138 684 -> (Q /\ P --> R).
adamc@138 685 imp.
adamc@138 686 Qed.
adamc@138 687
adamc@138 688 Theorem assoc_conc1 : forall P Q R S,
adamc@138 689 (S --> P /\ (Q /\ R))
adamc@138 690 -> (S --> (P /\ Q) /\ R).
adamc@138 691 imp.
adamc@138 692 Qed.
adamc@138 693
adamc@138 694 Theorem assoc_conc2 : forall P Q R S,
adamc@138 695 (S --> Q /\ (P /\ R))
adamc@138 696 -> (S --> (P /\ Q) /\ R).
adamc@138 697 imp.
adamc@138 698 Qed.
adamc@138 699
adamc@138 700 Theorem comm_conc : forall P Q R,
adamc@138 701 (R --> P /\ Q)
adamc@138 702 -> (R --> Q /\ P).
adamc@138 703 imp.
adamc@138 704 Qed.
adamc@138 705
adamc@140 706 (** The first order of business in crafting our [matcher] tactic will be auxiliary support for searching through formula trees. The [search_prem] tactic implements running its tactic argument [tac] on every subformula of an [imp] premise. As it traverses a tree, [search_prem] applies some of the above lemmas to rewrite the goal to bring different subformulas to the head of the goal. That is, for every subformula [P] of the implication premise, we want [P] to "have a turn," where the premise is rearranged into the form [P /\ Q] for some [Q]. The tactic [tac] should expect to see a goal in this form and focus its attention on the first conjunct of the premise. *)
adamc@140 707
adamc@141 708 (* begin thide *)
adamc@138 709 Ltac search_prem tac :=
adamc@138 710 let rec search P :=
adamc@138 711 tac
adamc@138 712 || (apply and_True_prem; tac)
adamc@138 713 || match P with
adamc@138 714 | ?P1 /\ ?P2 =>
adamc@138 715 (apply assoc_prem1; search P1)
adamc@138 716 || (apply assoc_prem2; search P2)
adamc@138 717 end
adamc@138 718 in match goal with
adamc@138 719 | [ |- ?P /\ _ --> _ ] => search P
adamc@138 720 | [ |- _ /\ ?P --> _ ] => apply comm_prem; search P
adamc@138 721 | [ |- _ --> _ ] => progress (tac || (apply and_True_prem; tac))
adamc@138 722 end.
adamc@138 723
adamc@140 724 (** To understand how [search_prem] works, we turn first to the final [match]. If the premise begins with a conjunction, we call the [search] procedure on each of the conjuncts, or only the first conjunct, if that already yields a case where [tac] does not fail. [search P] expects and maintains the invariant that the premise is of the form [P /\ Q] for some [Q]. We pass [P] explicitly as a kind of decreasing induction measure, to avoid looping forever when [tac] always fails. The second [match] case calls a commutativity lemma to realize this invariant, before passing control to [search]. The final [match] case tries applying [tac] directly and then, if that fails, changes the form of the goal by adding an extraneous [True] conjunct and calls [tac] again.
adamc@140 725
adamc@140 726 [search] itself tries the same tricks as in the last case of the final [match]. Additionally, if neither works, it checks if [P] is a conjunction. If so, it calls itself recursively on each conjunct, first applying associativity lemmas to maintain the goal-form invariant.
adamc@140 727
adamc@140 728 We will also want a dual function [search_conc], which does tree search through an [imp] conclusion. *)
adamc@140 729
adamc@138 730 Ltac search_conc tac :=
adamc@138 731 let rec search P :=
adamc@138 732 tac
adamc@138 733 || (apply and_True_conc; tac)
adamc@138 734 || match P with
adamc@138 735 | ?P1 /\ ?P2 =>
adamc@138 736 (apply assoc_conc1; search P1)
adamc@138 737 || (apply assoc_conc2; search P2)
adamc@138 738 end
adamc@138 739 in match goal with
adamc@138 740 | [ |- _ --> ?P /\ _ ] => search P
adamc@138 741 | [ |- _ --> _ /\ ?P ] => apply comm_conc; search P
adamc@138 742 | [ |- _ --> _ ] => progress (tac || (apply and_True_conc; tac))
adamc@138 743 end.
adamc@138 744
adamc@140 745 (** Now we can prove a number of lemmas that are suitable for application by our search tactics. A lemma that is meant to handle a premise should have the form [P /\ Q --> R] for some interesting [P], and a lemma that is meant to handle a conclusion should have the form [P --> Q /\ R] for some interesting [Q]. *)
adamc@140 746
adamc@138 747 Theorem False_prem : forall P Q,
adamc@138 748 False /\ P --> Q.
adamc@138 749 imp.
adamc@138 750 Qed.
adamc@138 751
adamc@138 752 Theorem True_conc : forall P Q : Prop,
adamc@138 753 (P --> Q)
adamc@138 754 -> (P --> True /\ Q).
adamc@138 755 imp.
adamc@138 756 Qed.
adamc@138 757
adamc@138 758 Theorem Match : forall P Q R : Prop,
adamc@138 759 (Q --> R)
adamc@138 760 -> (P /\ Q --> P /\ R).
adamc@138 761 imp.
adamc@138 762 Qed.
adamc@138 763
adamc@138 764 Theorem ex_prem : forall (T : Type) (P : T -> Prop) (Q R : Prop),
adamc@138 765 (forall x, P x /\ Q --> R)
adamc@138 766 -> (ex P /\ Q --> R).
adamc@138 767 imp.
adamc@138 768 Qed.
adamc@138 769
adamc@138 770 Theorem ex_conc : forall (T : Type) (P : T -> Prop) (Q R : Prop) x,
adamc@138 771 (Q --> P x /\ R)
adamc@138 772 -> (Q --> ex P /\ R).
adamc@138 773 imp.
adamc@138 774 Qed.
adamc@138 775
adamc@140 776 (** We will also want a "base case" lemma for finishing proofs where cancelation has removed every constituent of the conclusion. *)
adamc@140 777
adamc@138 778 Theorem imp_True : forall P,
adamc@138 779 P --> True.
adamc@138 780 imp.
adamc@138 781 Qed.
adamc@138 782
adamc@140 783 (** Our final [matcher] tactic is now straightforward. First, we [intros] all variables into scope. Then we attempt simple premise simplifications, finishing the proof upon finding [False] and eliminating any existential quantifiers that we find. After that, we search through the conclusion. We remove [True] conjuncts, remove existential quantifiers by introducing unification variables for their bound variables, and search for matching premises to cancel. Finally, when no more progress is made, we see if the goal has become trivial and can be solved by [imp_True]. *)
adamc@140 784
adamc@138 785 Ltac matcher :=
adamc@138 786 intros;
adamc@138 787 repeat search_prem ltac:(apply False_prem || (apply ex_prem; intro));
adamc@140 788 repeat search_conc ltac:(apply True_conc || eapply ex_conc
adamc@140 789 || search_prem ltac:(apply Match));
adamc@140 790 try apply imp_True.
adamc@141 791 (* end thide *)
adamc@140 792
adamc@140 793 (** Our tactic succeeds at proving a simple example. *)
adamc@138 794
adamc@138 795 Theorem t2 : forall P Q : Prop,
adamc@138 796 Q /\ (P /\ False) /\ P --> P /\ Q.
adamc@138 797 matcher.
adamc@138 798 Qed.
adamc@138 799
adamc@140 800 (** In the generated proof, we find a trace of the workings of the search tactics. *)
adamc@140 801
adamc@140 802 Print t2.
adamc@140 803 (** [[
adamc@140 804
adamc@140 805 t2 =
adamc@140 806 fun P Q : Prop =>
adamc@140 807 comm_prem (assoc_prem1 (assoc_prem2 (False_prem (P:=P /\ P /\ Q) (P /\ Q))))
adamc@140 808 : forall P Q : Prop, Q /\ (P /\ False) /\ P --> P /\ Q
adamc@140 809 ]] *)
adamc@140 810
adamc@140 811 (** We can also see that [matcher] is well-suited for cases where some human intervention is needed after the automation finishes. *)
adamc@140 812
adamc@138 813 Theorem t3 : forall P Q R : Prop,
adamc@138 814 P /\ Q --> Q /\ R /\ P.
adamc@138 815 matcher.
adamc@140 816 (** [[
adamc@140 817
adamc@140 818 ============================
adamc@140 819 True --> R
adamc@140 820 ]]
adamc@140 821
adamc@140 822 [matcher] canceled those conjuncts that it was able to cancel, leaving a simplified subgoal for us, much as [intuition] does. *)
adamc@138 823 Abort.
adamc@138 824
adamc@140 825 (** [matcher] even succeeds at guessing quantifier instantiations. It is the unification that occurs in uses of the [Match] lemma that does the real work here. *)
adamc@140 826
adamc@138 827 Theorem t4 : forall (P : nat -> Prop) Q, (exists x, P x /\ Q) --> Q /\ (exists x, P x).
adamc@138 828 matcher.
adamc@138 829 Qed.
adamc@138 830
adamc@140 831 Print t4.
adamc@140 832
adamc@140 833 (** [[
adamc@140 834
adamc@140 835 t4 =
adamc@140 836 fun (P : nat -> Prop) (Q : Prop) =>
adamc@140 837 and_True_prem
adamc@140 838 (ex_prem (P:=fun x : nat => P x /\ Q)
adamc@140 839 (fun x : nat =>
adamc@140 840 assoc_prem2
adamc@140 841 (Match (P:=Q)
adamc@140 842 (and_True_conc
adamc@140 843 (ex_conc (fun x0 : nat => P x0) x
adamc@140 844 (Match (P:=P x) (imp_True (P:=True))))))))
adamc@140 845 : forall (P : nat -> Prop) (Q : Prop),
adamc@140 846 (exists x : nat, P x /\ Q) --> Q /\ (exists x : nat, P x)
adamc@140 847 ]] *)