Mercurial > cpdt > repo

annotate src/DataStruct.v @ 439:393b8ed99c2f

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
A pass of improvements to vertical spacing, up through end of InductiveTypes
author Adam Chlipala <adam@chlipala.net>
date Mon, 30 Jul 2012 13:21:36 -0400
parents 8077352044b2
children 97c60ffdb998
rev   line source
adam@398 1 (* Copyright (c) 2008-2012, Adam Chlipala
adamc@105 2 *
adamc@105 3 * This work is licensed under a
adamc@105 4 * Creative Commons Attribution-Noncommercial-No Derivative Works 3.0
adamc@105 5 * Unported License.
adamc@105 6 * The license text is available at:
adamc@105 7 * http://creativecommons.org/licenses/by-nc-nd/3.0/
adamc@105 8 *)
adamc@105 9
adamc@105 10 (* begin hide *)
adamc@111 11 Require Import Arith List.
adamc@105 12
adam@314 13 Require Import CpdtTactics.
adamc@105 14
adamc@105 15 Set Implicit Arguments.
adamc@105 16 (* end hide *)
adamc@105 17
adamc@105 18
adamc@105 19 (** %\chapter{Dependent Data Structures}% *)
adamc@105 20
adamc@106 21 (** Our red-black tree example from the last chapter illustrated how dependent types enable static enforcement of data structure invariants. To find interesting uses of dependent data structures, however, we need not look to the favorite examples of data structures and algorithms textbooks. More basic examples like length-indexed and heterogeneous lists come up again and again as the building blocks of dependent programs. There is a surprisingly large design space for this class of data structure, and we will spend this chapter exploring it. *)
adamc@105 22
adamc@105 23
adamc@106 24 (** * More Length-Indexed Lists *)
adamc@106 25
adam@342 26 (** We begin with a deeper look at the length-indexed lists that began the last chapter.%\index{Gallina terms!ilist}% *)
adamc@105 27
adamc@105 28 Section ilist.
adamc@105 29 Variable A : Set.
adamc@105 30
adamc@105 31 Inductive ilist : nat -> Set :=
adamc@105 32 | Nil : ilist O
adamc@105 33 | Cons : forall n, A -> ilist n -> ilist (S n).
adamc@105 34
adam@426 35 (** We might like to have a certified function for selecting an element of an [ilist] by position. We could do this using subset types and explicit manipulation of proofs, but dependent types let us do it more directly. It is helpful to define a type family %\index{Gallina terms!fin}%[fin], where [fin n] is isomorphic to [{m : nat | m < n}]. The type family name stands for "finite." *)
adamc@106 36
adamc@113 37 (* EX: Define a function [get] for extracting an [ilist] element by position. *)
adamc@113 38
adamc@113 39 (* begin thide *)
adamc@215 40 Inductive fin : nat -> Set :=
adamc@215 41 | First : forall n, fin (S n)
adamc@215 42 | Next : forall n, fin n -> fin (S n).
adamc@105 43
adam@406 44 (** An instance of [fin] is essentially a more richly typed copy of the natural numbers. Every element is a [First] iterated through applying [Next] a number of times that indicates which number is being selected. For instance, the three values of type [fin 3] are [First 2], [Next (First 1)], and [Next (Next (First 0))].
adamc@106 45
adamc@106 46 Now it is easy to pick a [Prop]-free type for a selection function. As usual, our first implementation attempt will not convince the type checker, and we will attack the deficiencies one at a time.
adamc@106 47
adamc@106 48 [[
adamc@215 49 Fixpoint get n (ls : ilist n) : fin n -> A :=
adamc@215 50 match ls with
adamc@106 51 | Nil => fun idx => ?
adamc@106 52 | Cons _ x ls' => fun idx =>
adamc@106 53 match idx with
adamc@106 54 | First _ => x
adamc@106 55 | Next _ idx' => get ls' idx'
adamc@106 56 end
adamc@106 57 end.
adamc@106 58
adamc@205 59 ]]
adamc@205 60
adamc@215 61 We apply the usual wisdom of delaying arguments in [Fixpoint]s so that they may be included in [return] clauses. This still leaves us with a quandary in each of the [match] cases. First, we need to figure out how to take advantage of the contradiction in the [Nil] case. Every [fin] has a type of the form [S n], which cannot unify with the [O] value that we learn for [n] in the [Nil] case. The solution we adopt is another case of [match]-within-[return].
adamc@106 62
adamc@106 63 [[
adamc@215 64 Fixpoint get n (ls : ilist n) : fin n -> A :=
adamc@215 65 match ls with
adamc@106 66 | Nil => fun idx =>
adamc@215 67 match idx in fin n' return (match n' with
adamc@106 68 | O => A
adamc@106 69 | S _ => unit
adamc@106 70 end) with
adamc@106 71 | First _ => tt
adamc@106 72 | Next _ _ => tt
adamc@106 73 end
adamc@106 74 | Cons _ x ls' => fun idx =>
adamc@106 75 match idx with
adamc@106 76 | First _ => x
adamc@106 77 | Next _ idx' => get ls' idx'
adamc@106 78 end
adamc@106 79 end.
adamc@106 80
adamc@205 81 ]]
adamc@205 82
adam@284 83 Now the first [match] case type-checks, and we see that the problem with the [Cons] case is that the pattern-bound variable [idx'] does not have an apparent type compatible with [ls']. In fact, the error message Coq gives for this exact code can be confusing, thanks to an overenthusiastic type inference heuristic. We are told that the [Nil] case body has type [match X with | 0 => A | S _ => unit end] for a unification variable [X], while it is expected to have type [A]. We can see that setting [X] to [0] resolves the conflict, but Coq is not yet smart enough to do this unification automatically. Repeating the function's type in a [return] annotation, used with an [in] annotation, leads us to a more informative error message, saying that [idx'] has type [fin n1] while it is expected to have type [fin n0], where [n0] is bound by the [Cons] pattern and [n1] by the [Next] pattern. As the code is written above, nothing forces these two natural numbers to be equal, though we know intuitively that they must be.
adam@284 84
adam@284 85 We need to use [match] annotations to make the relationship explicit. Unfortunately, the usual trick of postponing argument binding will not help us here. We need to match on both [ls] and [idx]; one or the other must be matched first. To get around this, we apply the convoy pattern that we met last chapter. This application is a little more clever than those we saw before; we use the natural number predecessor function [pred] to express the relationship between the types of these variables.
adamc@106 86
adamc@106 87 [[
adamc@215 88 Fixpoint get n (ls : ilist n) : fin n -> A :=
adamc@215 89 match ls with
adamc@106 90 | Nil => fun idx =>
adamc@215 91 match idx in fin n' return (match n' with
adamc@106 92 | O => A
adamc@106 93 | S _ => unit
adamc@106 94 end) with
adamc@106 95 | First _ => tt
adamc@106 96 | Next _ _ => tt
adamc@106 97 end
adamc@106 98 | Cons _ x ls' => fun idx =>
adamc@215 99 match idx in fin n' return ilist (pred n') -> A with
adamc@106 100 | First _ => fun _ => x
adamc@106 101 | Next _ idx' => fun ls' => get ls' idx'
adamc@106 102 end ls'
adamc@106 103 end.
adamc@106 104
adamc@205 105 ]]
adamc@205 106
adamc@106 107 There is just one problem left with this implementation. Though we know that the local [ls'] in the [Next] case is equal to the original [ls'], the type-checker is not satisfied that the recursive call to [get] does not introduce non-termination. We solve the problem by convoy-binding the partial application of [get] to [ls'], rather than [ls'] by itself. *)
adamc@106 108
adamc@215 109 Fixpoint get n (ls : ilist n) : fin n -> A :=
adamc@215 110 match ls with
adamc@105 111 | Nil => fun idx =>
adamc@215 112 match idx in fin n' return (match n' with
adamc@105 113 | O => A
adamc@105 114 | S _ => unit
adamc@105 115 end) with
adamc@105 116 | First _ => tt
adamc@105 117 | Next _ _ => tt
adamc@105 118 end
adamc@105 119 | Cons _ x ls' => fun idx =>
adamc@215 120 match idx in fin n' return (fin (pred n') -> A) -> A with
adamc@105 121 | First _ => fun _ => x
adamc@105 122 | Next _ idx' => fun get_ls' => get_ls' idx'
adamc@105 123 end (get ls')
adamc@105 124 end.
adamc@113 125 (* end thide *)
adamc@105 126 End ilist.
adamc@105 127
adamc@105 128 Implicit Arguments Nil [A].
adamc@108 129 Implicit Arguments First [n].
adamc@105 130
adamc@108 131 (** A few examples show how to make use of these definitions. *)
adamc@108 132
adamc@108 133 Check Cons 0 (Cons 1 (Cons 2 Nil)).
adamc@215 134 (** %\vspace{-.15in}% [[
adamc@215 135 Cons 0 (Cons 1 (Cons 2 Nil))
adamc@108 136 : ilist nat 3
adam@302 137 ]]
adam@302 138 *)
adamc@215 139
adamc@113 140 (* begin thide *)
adamc@108 141 Eval simpl in get (Cons 0 (Cons 1 (Cons 2 Nil))) First.
adamc@215 142 (** %\vspace{-.15in}% [[
adamc@108 143 = 0
adamc@108 144 : nat
adam@302 145 ]]
adam@302 146 *)
adamc@215 147
adamc@108 148 Eval simpl in get (Cons 0 (Cons 1 (Cons 2 Nil))) (Next First).
adamc@215 149 (** %\vspace{-.15in}% [[
adamc@108 150 = 1
adamc@108 151 : nat
adam@302 152 ]]
adam@302 153 *)
adamc@215 154
adamc@108 155 Eval simpl in get (Cons 0 (Cons 1 (Cons 2 Nil))) (Next (Next First)).
adamc@215 156 (** %\vspace{-.15in}% [[
adamc@108 157 = 2
adamc@108 158 : nat
adam@302 159 ]]
adam@302 160 *)
adamc@113 161 (* end thide *)
adamc@108 162
adam@426 163 (* begin hide *)
adam@437 164 (* begin thide *)
adam@426 165 Definition map' := map.
adam@437 166 (* end thide *)
adam@426 167 (* end hide *)
adam@426 168
adamc@108 169 (** Our [get] function is also quite easy to reason about. We show how with a short example about an analogue to the list [map] function. *)
adamc@107 170
adamc@105 171 Section ilist_map.
adamc@105 172 Variables A B : Set.
adamc@105 173 Variable f : A -> B.
adamc@105 174
adamc@215 175 Fixpoint imap n (ls : ilist A n) : ilist B n :=
adamc@215 176 match ls with
adamc@105 177 | Nil => Nil
adamc@105 178 | Cons _ x ls' => Cons (f x) (imap ls')
adamc@105 179 end.
adamc@105 180
adam@426 181 (** It is easy to prove that [get] "distributes over" [imap] calls. *)
adamc@107 182
adam@342 183 (* EX: Prove that [get] distributes over [imap]. *)
adam@342 184
adam@342 185 (* begin thide *)
adamc@215 186 Theorem get_imap : forall n (idx : fin n) (ls : ilist A n),
adamc@105 187 get (imap ls) idx = f (get ls idx).
adamc@107 188 induction ls; dep_destruct idx; crush.
adamc@105 189 Qed.
adamc@113 190 (* end thide *)
adamc@105 191 End ilist_map.
adamc@107 192
adam@406 193 (** The only tricky bit is remembering to use our [dep_destruct] tactic in place of plain [destruct] when faced with a baffling tactic error message. *)
adamc@107 194
adamc@107 195 (** * Heterogeneous Lists *)
adamc@107 196
adam@426 197 (** Programmers who move to statically typed functional languages from scripting languages often complain about the requirement that every element of a list have the same type. With fancy type systems, we can partially lift this requirement. We can index a list type with a "type-level" list that explains what type each element of the list should have. This has been done in a variety of ways in Haskell using type classes, and we can do it much more cleanly and directly in Coq. *)
adamc@107 198
adamc@107 199 Section hlist.
adamc@107 200 Variable A : Type.
adamc@107 201 Variable B : A -> Type.
adamc@107 202
adamc@113 203 (* EX: Define a type [hlist] indexed by a [list A], where the type of each element is determined by running [B] on the corresponding element of the index list. *)
adamc@113 204
adam@342 205 (** We parameterize our heterogeneous lists by a type [A] and an [A]-indexed type [B].%\index{Gallina terms!hlist}% *)
adamc@107 206
adamc@113 207 (* begin thide *)
adamc@107 208 Inductive hlist : list A -> Type :=
adamc@107 209 | MNil : hlist nil
adamc@107 210 | MCons : forall (x : A) (ls : list A), B x -> hlist ls -> hlist (x :: ls).
adamc@107 211
adam@342 212 (** We can implement a variant of the last section's [get] function for [hlist]s. To get the dependent typing to work out, we will need to index our element selectors by the types of data that they point to.%\index{Gallina terms!member}% *)
adamc@107 213
adamc@113 214 (* end thide *)
adamc@113 215 (* EX: Define an analogue to [get] for [hlist]s. *)
adamc@113 216
adamc@113 217 (* begin thide *)
adamc@107 218 Variable elm : A.
adamc@107 219
adamc@107 220 Inductive member : list A -> Type :=
adamc@107 221 | MFirst : forall ls, member (elm :: ls)
adamc@107 222 | MNext : forall x ls, member ls -> member (x :: ls).
adamc@107 223
adam@426 224 (** Because the element [elm] that we are "searching for" in a list does not change across the constructors of [member], we simplify our definitions by making [elm] a local variable. In the definition of [member], we say that [elm] is found in any list that begins with [elm], and, if removing the first element of a list leaves [elm] present, then [elm] is present in the original list, too. The form looks much like a predicate for list membership, but we purposely define [member] in [Type] so that we may decompose its values to guide computations.
adamc@107 225
adam@342 226 We can use [member] to adapt our definition of [get] to [hlist]s. The same basic [match] tricks apply. In the [MCons] case, we form a two-element convoy, passing both the data element [x] and the recursor for the sublist [mls'] to the result of the inner [match]. We did not need to do that in [get]'s definition because the types of list elements were not dependent there. *)
adamc@107 227
adamc@215 228 Fixpoint hget ls (mls : hlist ls) : member ls -> B elm :=
adamc@215 229 match mls with
adamc@107 230 | MNil => fun mem =>
adamc@107 231 match mem in member ls' return (match ls' with
adamc@107 232 | nil => B elm
adamc@107 233 | _ :: _ => unit
adamc@107 234 end) with
adamc@107 235 | MFirst _ => tt
adamc@107 236 | MNext _ _ _ => tt
adamc@107 237 end
adamc@107 238 | MCons _ _ x mls' => fun mem =>
adamc@107 239 match mem in member ls' return (match ls' with
adamc@107 240 | nil => Empty_set
adamc@107 241 | x' :: ls'' =>
adam@437 242 B x' -> (member ls'' -> B elm)
adam@437 243 -> B elm
adamc@107 244 end) with
adamc@107 245 | MFirst _ => fun x _ => x
adamc@107 246 | MNext _ _ mem' => fun _ get_mls' => get_mls' mem'
adamc@107 247 end x (hget mls')
adamc@107 248 end.
adamc@113 249 (* end thide *)
adamc@107 250 End hlist.
adamc@108 251
adamc@113 252 (* begin thide *)
adamc@108 253 Implicit Arguments MNil [A B].
adamc@108 254 Implicit Arguments MCons [A B x ls].
adamc@108 255
adamc@108 256 Implicit Arguments MFirst [A elm ls].
adamc@108 257 Implicit Arguments MNext [A elm x ls].
adamc@113 258 (* end thide *)
adamc@108 259
adamc@108 260 (** By putting the parameters [A] and [B] in [Type], we allow some very higher-order uses. For instance, one use of [hlist] is for the simple heterogeneous lists that we referred to earlier. *)
adamc@108 261
adamc@108 262 Definition someTypes : list Set := nat :: bool :: nil.
adamc@108 263
adamc@113 264 (* begin thide *)
adamc@113 265
adamc@108 266 Example someValues : hlist (fun T : Set => T) someTypes :=
adamc@108 267 MCons 5 (MCons true MNil).
adamc@108 268
adamc@108 269 Eval simpl in hget someValues MFirst.
adamc@215 270 (** %\vspace{-.15in}% [[
adamc@108 271 = 5
adamc@108 272 : (fun T : Set => T) nat
adam@302 273 ]]
adam@302 274 *)
adamc@215 275
adamc@108 276 Eval simpl in hget someValues (MNext MFirst).
adamc@215 277 (** %\vspace{-.15in}% [[
adamc@108 278 = true
adamc@108 279 : (fun T : Set => T) bool
adam@302 280 ]]
adam@302 281 *)
adamc@108 282
adamc@108 283 (** We can also build indexed lists of pairs in this way. *)
adamc@108 284
adamc@108 285 Example somePairs : hlist (fun T : Set => T * T)%type someTypes :=
adamc@108 286 MCons (1, 2) (MCons (true, false) MNil).
adamc@108 287
adamc@113 288 (* end thide *)
adamc@113 289
adamc@113 290
adamc@108 291 (** ** A Lambda Calculus Interpreter *)
adamc@108 292
adam@342 293 (** Heterogeneous lists are very useful in implementing %\index{interpreters}%interpreters for functional programming languages. Using the types and operations we have already defined, it is trivial to write an interpreter for simply typed lambda calculus%\index{lambda calculus}%. Our interpreter can alternatively be thought of as a denotational semantics.
adamc@108 294
adamc@108 295 We start with an algebraic datatype for types. *)
adamc@108 296
adamc@108 297 Inductive type : Set :=
adamc@108 298 | Unit : type
adamc@108 299 | Arrow : type -> type -> type.
adamc@108 300
adam@342 301 (** Now we can define a type family for expressions. An [exp ts t] will stand for an expression that has type [t] and whose free variables have types in the list [ts]. We effectively use the de Bruijn index variable representation%~\cite{DeBruijn}%. Variables are represented as [member] values; that is, a variable is more or less a constructive proof that a particular type is found in the type environment. *)
adamc@108 302
adamc@108 303 Inductive exp : list type -> type -> Set :=
adamc@108 304 | Const : forall ts, exp ts Unit
adamc@113 305 (* begin thide *)
adamc@108 306 | Var : forall ts t, member t ts -> exp ts t
adamc@108 307 | App : forall ts dom ran, exp ts (Arrow dom ran) -> exp ts dom -> exp ts ran
adamc@108 308 | Abs : forall ts dom ran, exp (dom :: ts) ran -> exp ts (Arrow dom ran).
adamc@113 309 (* end thide *)
adamc@108 310
adamc@108 311 Implicit Arguments Const [ts].
adamc@108 312
adamc@108 313 (** We write a simple recursive function to translate [type]s into [Set]s. *)
adamc@108 314
adamc@108 315 Fixpoint typeDenote (t : type) : Set :=
adamc@108 316 match t with
adamc@108 317 | Unit => unit
adamc@108 318 | Arrow t1 t2 => typeDenote t1 -> typeDenote t2
adamc@108 319 end.
adamc@108 320
adam@342 321 (** Now it is straightforward to write an expression interpreter. The type of the function, [expDenote], tells us that we translate expressions into functions from properly typed environments to final values. An environment for a free variable list [ts] is simply a [hlist typeDenote ts]. That is, for each free variable, the heterogeneous list that is the environment must have a value of the variable's associated type. We use [hget] to implement the [Var] case, and we use [MCons] to extend the environment in the [Abs] case. *)
adamc@108 322
adamc@113 323 (* EX: Define an interpreter for [exp]s. *)
adamc@113 324
adamc@113 325 (* begin thide *)
adamc@215 326 Fixpoint expDenote ts t (e : exp ts t) : hlist typeDenote ts -> typeDenote t :=
adamc@215 327 match e with
adamc@108 328 | Const _ => fun _ => tt
adamc@108 329
adamc@108 330 | Var _ _ mem => fun s => hget s mem
adamc@108 331 | App _ _ _ e1 e2 => fun s => (expDenote e1 s) (expDenote e2 s)
adamc@108 332 | Abs _ _ _ e' => fun s => fun x => expDenote e' (MCons x s)
adamc@108 333 end.
adamc@108 334
adamc@108 335 (** Like for previous examples, our interpreter is easy to run with [simpl]. *)
adamc@108 336
adamc@108 337 Eval simpl in expDenote Const MNil.
adamc@215 338 (** %\vspace{-.15in}% [[
adamc@108 339 = tt
adamc@108 340 : typeDenote Unit
adam@302 341 ]]
adam@302 342 *)
adamc@215 343
adamc@108 344 Eval simpl in expDenote (Abs (dom := Unit) (Var MFirst)) MNil.
adamc@215 345 (** %\vspace{-.15in}% [[
adamc@108 346 = fun x : unit => x
adamc@108 347 : typeDenote (Arrow Unit Unit)
adam@302 348 ]]
adam@302 349 *)
adamc@215 350
adamc@108 351 Eval simpl in expDenote (Abs (dom := Unit)
adamc@108 352 (Abs (dom := Unit) (Var (MNext MFirst)))) MNil.
adamc@215 353 (** %\vspace{-.15in}% [[
adamc@108 354 = fun x _ : unit => x
adamc@108 355 : typeDenote (Arrow Unit (Arrow Unit Unit))
adam@302 356 ]]
adam@302 357 *)
adamc@215 358
adamc@108 359 Eval simpl in expDenote (Abs (dom := Unit) (Abs (dom := Unit) (Var MFirst))) MNil.
adamc@215 360 (** %\vspace{-.15in}% [[
adamc@108 361 = fun _ x0 : unit => x0
adamc@108 362 : typeDenote (Arrow Unit (Arrow Unit Unit))
adam@302 363 ]]
adam@302 364 *)
adamc@215 365
adamc@108 366 Eval simpl in expDenote (App (Abs (Var MFirst)) Const) MNil.
adamc@215 367 (** %\vspace{-.15in}% [[
adamc@108 368 = tt
adamc@108 369 : typeDenote Unit
adam@302 370 ]]
adam@302 371 *)
adamc@108 372
adamc@113 373 (* end thide *)
adamc@113 374
adam@342 375 (** We are starting to develop the tools behind dependent typing's amazing advantage over alternative approaches in several important areas. Here, we have implemented complete syntax, typing rules, and evaluation semantics for simply typed lambda calculus without even needing to define a syntactic substitution operation. We did it all without a single line of proof, and our implementation is manifestly executable. Other, more common approaches to language formalization often state and prove explicit theorems about type safety of languages. In the above example, we got type safety, termination, and other meta-theorems for free, by reduction to CIC, which we know has those properties. *)
adamc@108 376
adamc@108 377
adamc@109 378 (** * Recursive Type Definitions *)
adamc@109 379
adam@426 380 (** %\index{recursive type definition}%There is another style of datatype definition that leads to much simpler definitions of the [get] and [hget] definitions above. Because Coq supports "type-level computation," we can redo our inductive definitions as _recursive_ definitions. *)
adamc@109 381
adamc@113 382 (* EX: Come up with an alternate [ilist] definition that makes it easier to write [get]. *)
adamc@113 383
adamc@109 384 Section filist.
adamc@109 385 Variable A : Set.
adamc@109 386
adamc@113 387 (* begin thide *)
adamc@109 388 Fixpoint filist (n : nat) : Set :=
adamc@109 389 match n with
adamc@109 390 | O => unit
adamc@109 391 | S n' => A * filist n'
adamc@109 392 end%type.
adamc@109 393
adamc@109 394 (** We say that a list of length 0 has no contents, and a list of length [S n'] is a pair of a data value and a list of length [n']. *)
adamc@109 395
adamc@215 396 Fixpoint ffin (n : nat) : Set :=
adamc@109 397 match n with
adamc@109 398 | O => Empty_set
adamc@215 399 | S n' => option (ffin n')
adamc@109 400 end.
adamc@109 401
adam@406 402 (** We express that there are no index values when [n = O], by defining such indices as type [Empty_set]; and we express that, at [n = S n'], there is a choice between picking the first element of the list (represented as [None]) or choosing a later element (represented by [Some idx], where [idx] is an index into the list tail). For instance, the three values of type [ffin 3] are [None], [Some None], and [Some (Some None)]. *)
adamc@109 403
adamc@215 404 Fixpoint fget (n : nat) : filist n -> ffin n -> A :=
adamc@215 405 match n with
adamc@109 406 | O => fun _ idx => match idx with end
adamc@109 407 | S n' => fun ls idx =>
adamc@109 408 match idx with
adamc@109 409 | None => fst ls
adamc@109 410 | Some idx' => fget n' (snd ls) idx'
adamc@109 411 end
adamc@109 412 end.
adamc@109 413
adamc@215 414 (** Our new [get] implementation needs only one dependent [match], and its annotation is inferred for us. Our choices of data structure implementations lead to just the right typing behavior for this new definition to work out. *)
adamc@113 415 (* end thide *)
adamc@215 416
adamc@109 417 End filist.
adamc@109 418
adamc@109 419 (** Heterogeneous lists are a little trickier to define with recursion, but we then reap similar benefits in simplicity of use. *)
adamc@109 420
adamc@113 421 (* EX: Come up with an alternate [hlist] definition that makes it easier to write [hget]. *)
adamc@113 422
adamc@109 423 Section fhlist.
adamc@109 424 Variable A : Type.
adamc@109 425 Variable B : A -> Type.
adamc@109 426
adamc@113 427 (* begin thide *)
adamc@109 428 Fixpoint fhlist (ls : list A) : Type :=
adamc@109 429 match ls with
adamc@109 430 | nil => unit
adamc@109 431 | x :: ls' => B x * fhlist ls'
adamc@109 432 end%type.
adamc@109 433
adam@342 434 (** The definition of [fhlist] follows the definition of [filist], with the added wrinkle of dependently typed data elements. *)
adamc@109 435
adamc@109 436 Variable elm : A.
adamc@109 437
adamc@109 438 Fixpoint fmember (ls : list A) : Type :=
adamc@109 439 match ls with
adamc@109 440 | nil => Empty_set
adamc@109 441 | x :: ls' => (x = elm) + fmember ls'
adamc@109 442 end%type.
adamc@109 443
adam@426 444 (** The definition of [fmember] follows the definition of [ffin]. Empty lists have no members, and member types for nonempty lists are built by adding one new option to the type of members of the list tail. While for [ffin] we needed no new information associated with the option that we add, here we need to know that the head of the list equals the element we are searching for. We express that with a sum type whose left branch is the appropriate equality proposition. Since we define [fmember] to live in [Type], we can insert [Prop] types as needed, because [Prop] is a subtype of [Type].
adamc@109 445
adamc@109 446 We know all of the tricks needed to write a first attempt at a [get] function for [fhlist]s.
adamc@109 447
adamc@109 448 [[
adamc@109 449 Fixpoint fhget (ls : list A) : fhlist ls -> fmember ls -> B elm :=
adamc@215 450 match ls with
adamc@109 451 | nil => fun _ idx => match idx with end
adamc@109 452 | _ :: ls' => fun mls idx =>
adamc@109 453 match idx with
adamc@109 454 | inl _ => fst mls
adamc@109 455 | inr idx' => fhget ls' (snd mls) idx'
adamc@109 456 end
adamc@109 457 end.
adamc@109 458
adamc@205 459 ]]
adamc@205 460
adamc@109 461 Only one problem remains. The expression [fst mls] is not known to have the proper type. To demonstrate that it does, we need to use the proof available in the [inl] case of the inner [match]. *)
adamc@109 462
adamc@109 463 Fixpoint fhget (ls : list A) : fhlist ls -> fmember ls -> B elm :=
adamc@215 464 match ls with
adamc@109 465 | nil => fun _ idx => match idx with end
adamc@109 466 | _ :: ls' => fun mls idx =>
adamc@109 467 match idx with
adamc@109 468 | inl pf => match pf with
adam@426 469 | eq_refl => fst mls
adamc@109 470 end
adamc@109 471 | inr idx' => fhget ls' (snd mls) idx'
adamc@109 472 end
adamc@109 473 end.
adamc@109 474
adamc@109 475 (** By pattern-matching on the equality proof [pf], we make that equality known to the type-checker. Exactly why this works can be seen by studying the definition of equality. *)
adamc@109 476
adam@426 477 (* begin hide *)
adam@437 478 (* begin thide *)
adam@437 479 Definition foo := @eq_refl.
adam@437 480 (* end thide *)
adam@426 481 (* end hide *)
adam@426 482
adamc@109 483 Print eq.
adamc@215 484 (** %\vspace{-.15in}% [[
adam@426 485 Inductive eq (A : Type) (x : A) : A -> Prop := eq_refl : x = x
adamc@215 486
adamc@109 487 ]]
adamc@109 488
adam@426 489 In a proposition [x = y], we see that [x] is a parameter and [y] is a regular argument. The type of the constructor [eq_refl] shows that [y] can only ever be instantiated to [x]. Thus, within a pattern-match with [eq_refl], occurrences of [y] can be replaced with occurrences of [x] for typing purposes. *)
adamc@113 490 (* end thide *)
adamc@215 491
adamc@109 492 End fhlist.
adamc@110 493
adamc@111 494 Implicit Arguments fhget [A B elm ls].
adamc@111 495
adamc@110 496
adamc@110 497 (** * Data Structures as Index Functions *)
adamc@110 498
adam@342 499 (** %\index{index function}%Indexed lists can be useful in defining other inductive types with constructors that take variable numbers of arguments. In this section, we consider parameterized trees with arbitrary branching factor. *)
adamc@110 500
adamc@110 501 Section tree.
adamc@110 502 Variable A : Set.
adamc@110 503
adamc@110 504 Inductive tree : Set :=
adamc@110 505 | Leaf : A -> tree
adamc@110 506 | Node : forall n, ilist tree n -> tree.
adamc@110 507 End tree.
adamc@110 508
adamc@110 509 (** Every [Node] of a [tree] has a natural number argument, which gives the number of child trees in the second argument, typed with [ilist]. We can define two operations on trees of naturals: summing their elements and incrementing their elements. It is useful to define a generic fold function on [ilist]s first. *)
adamc@110 510
adamc@110 511 Section ifoldr.
adamc@110 512 Variables A B : Set.
adamc@110 513 Variable f : A -> B -> B.
adamc@110 514 Variable i : B.
adamc@110 515
adamc@215 516 Fixpoint ifoldr n (ls : ilist A n) : B :=
adamc@110 517 match ls with
adamc@110 518 | Nil => i
adamc@110 519 | Cons _ x ls' => f x (ifoldr ls')
adamc@110 520 end.
adamc@110 521 End ifoldr.
adamc@110 522
adamc@110 523 Fixpoint sum (t : tree nat) : nat :=
adamc@110 524 match t with
adamc@110 525 | Leaf n => n
adamc@110 526 | Node _ ls => ifoldr (fun t' n => sum t' + n) O ls
adamc@110 527 end.
adamc@110 528
adamc@110 529 Fixpoint inc (t : tree nat) : tree nat :=
adamc@110 530 match t with
adamc@110 531 | Leaf n => Leaf (S n)
adamc@110 532 | Node _ ls => Node (imap inc ls)
adamc@110 533 end.
adamc@110 534
adamc@110 535 (** Now we might like to prove that [inc] does not decrease a tree's [sum]. *)
adamc@110 536
adamc@110 537 Theorem sum_inc : forall t, sum (inc t) >= sum t.
adamc@113 538 (* begin thide *)
adamc@110 539 induction t; crush.
adamc@110 540 (** [[
adamc@110 541 n : nat
adamc@110 542 i : ilist (tree nat) n
adamc@110 543 ============================
adamc@110 544 ifoldr (fun (t' : tree nat) (n0 : nat) => sum t' + n0) 0 (imap inc i) >=
adamc@110 545 ifoldr (fun (t' : tree nat) (n0 : nat) => sum t' + n0) 0 i
adamc@215 546
adamc@110 547 ]]
adamc@110 548
adam@342 549 We are left with a single subgoal which does not seem provable directly. This is the same problem that we met in Chapter 3 with other %\index{nested inductive type}%nested inductive types. *)
adamc@110 550
adamc@110 551 Check tree_ind.
adamc@215 552 (** %\vspace{-.15in}% [[
adamc@215 553 tree_ind
adamc@110 554 : forall (A : Set) (P : tree A -> Prop),
adamc@110 555 (forall a : A, P (Leaf a)) ->
adamc@110 556 (forall (n : nat) (i : ilist (tree A) n), P (Node i)) ->
adamc@110 557 forall t : tree A, P t
adamc@215 558
adamc@110 559 ]]
adamc@110 560
adam@342 561 The automatically generated induction principle is too weak. For the [Node] case, it gives us no inductive hypothesis. We could write our own induction principle, as we did in Chapter 3, but there is an easier way, if we are willing to alter the definition of [tree]. *)
adamc@215 562
adamc@110 563 Abort.
adamc@110 564
adamc@110 565 Reset tree.
adamc@110 566
adamc@110 567 (** First, let us try using our recursive definition of [ilist]s instead of the inductive version. *)
adamc@110 568
adamc@110 569 Section tree.
adamc@110 570 Variable A : Set.
adamc@110 571
adamc@215 572 (** %\vspace{-.15in}% [[
adamc@110 573 Inductive tree : Set :=
adamc@110 574 | Leaf : A -> tree
adamc@110 575 | Node : forall n, filist tree n -> tree.
adam@342 576 ]]
adamc@110 577
adam@342 578 <<
adamc@110 579 Error: Non strictly positive occurrence of "tree" in
adamc@110 580 "forall n : nat, filist tree n -> tree"
adam@342 581 >>
adamc@110 582
adam@342 583 The special-case rule for nested datatypes only works with nested uses of other inductive types, which could be replaced with uses of new mutually inductive types. We defined [filist] recursively, so it may not be used for nested recursion.
adamc@110 584
adam@398 585 Our final solution uses yet another of the inductive definition techniques introduced in Chapter 3, %\index{reflexive inductive type}%reflexive types. Instead of merely using [fin] to get elements out of [ilist], we can _define_ [ilist] in terms of [fin]. For the reasons outlined above, it turns out to be easier to work with [ffin] in place of [fin]. *)
adamc@110 586
adamc@110 587 Inductive tree : Set :=
adamc@110 588 | Leaf : A -> tree
adamc@215 589 | Node : forall n, (ffin n -> tree) -> tree.
adamc@110 590
adamc@215 591 (** A [Node] is indexed by a natural number [n], and the node's [n] children are represented as a function from [ffin n] to trees, which is isomorphic to the [ilist]-based representation that we used above. *)
adamc@215 592
adamc@110 593 End tree.
adamc@110 594
adamc@110 595 Implicit Arguments Node [A n].
adamc@110 596
adamc@215 597 (** We can redefine [sum] and [inc] for our new [tree] type. Again, it is useful to define a generic fold function first. This time, it takes in a function whose range is some [ffin] type, and it folds another function over the results of calling the first function at every possible [ffin] value. *)
adamc@110 598
adamc@110 599 Section rifoldr.
adamc@110 600 Variables A B : Set.
adamc@110 601 Variable f : A -> B -> B.
adamc@110 602 Variable i : B.
adamc@110 603
adamc@215 604 Fixpoint rifoldr (n : nat) : (ffin n -> A) -> B :=
adamc@215 605 match n with
adamc@110 606 | O => fun _ => i
adamc@110 607 | S n' => fun get => f (get None) (rifoldr n' (fun idx => get (Some idx)))
adamc@110 608 end.
adamc@110 609 End rifoldr.
adamc@110 610
adamc@110 611 Implicit Arguments rifoldr [A B n].
adamc@110 612
adamc@110 613 Fixpoint sum (t : tree nat) : nat :=
adamc@110 614 match t with
adamc@110 615 | Leaf n => n
adamc@110 616 | Node _ f => rifoldr plus O (fun idx => sum (f idx))
adamc@110 617 end.
adamc@110 618
adamc@110 619 Fixpoint inc (t : tree nat) : tree nat :=
adamc@110 620 match t with
adamc@110 621 | Leaf n => Leaf (S n)
adamc@110 622 | Node _ f => Node (fun idx => inc (f idx))
adamc@110 623 end.
adamc@110 624
adam@398 625 (** Now we are ready to prove the theorem where we got stuck before. We will not need to define any new induction principle, but it _will_ be helpful to prove some lemmas. *)
adamc@110 626
adamc@110 627 Lemma plus_ge : forall x1 y1 x2 y2,
adamc@110 628 x1 >= x2
adamc@110 629 -> y1 >= y2
adamc@110 630 -> x1 + y1 >= x2 + y2.
adamc@110 631 crush.
adamc@110 632 Qed.
adamc@110 633
adamc@215 634 Lemma sum_inc' : forall n (f1 f2 : ffin n -> nat),
adamc@110 635 (forall idx, f1 idx >= f2 idx)
adamc@110 636 -> rifoldr plus 0 f1 >= rifoldr plus 0 f2.
adamc@110 637 Hint Resolve plus_ge.
adamc@110 638
adamc@110 639 induction n; crush.
adamc@110 640 Qed.
adamc@110 641
adamc@110 642 Theorem sum_inc : forall t, sum (inc t) >= sum t.
adamc@110 643 Hint Resolve sum_inc'.
adamc@110 644
adamc@110 645 induction t; crush.
adamc@110 646 Qed.
adamc@110 647
adamc@113 648 (* end thide *)
adamc@113 649
adamc@110 650 (** Even if Coq would generate complete induction principles automatically for nested inductive definitions like the one we started with, there would still be advantages to using this style of reflexive encoding. We see one of those advantages in the definition of [inc], where we did not need to use any kind of auxiliary function. In general, reflexive encodings often admit direct implementations of operations that would require recursion if performed with more traditional inductive data structures. *)
adamc@111 651
adamc@111 652 (** ** Another Interpreter Example *)
adamc@111 653
adam@426 654 (** We develop another example of variable-arity constructors, in the form of optimization of a small expression language with a construct like Scheme's <<cond>>. Each of our conditional expressions takes a list of pairs of boolean tests and bodies. The value of the conditional comes from the body of the first test in the list to evaluate to [true]. To simplify the %\index{interpreters}%interpreter we will write, we force each conditional to include a final, default case. *)
adamc@112 655
adamc@112 656 Inductive type' : Type := Nat | Bool.
adamc@111 657
adamc@111 658 Inductive exp' : type' -> Type :=
adamc@112 659 | NConst : nat -> exp' Nat
adamc@112 660 | Plus : exp' Nat -> exp' Nat -> exp' Nat
adamc@112 661 | Eq : exp' Nat -> exp' Nat -> exp' Bool
adamc@111 662
adamc@112 663 | BConst : bool -> exp' Bool
adamc@113 664 (* begin thide *)
adamc@215 665 | Cond : forall n t, (ffin n -> exp' Bool)
adamc@215 666 -> (ffin n -> exp' t) -> exp' t -> exp' t.
adamc@113 667 (* end thide *)
adamc@111 668
adam@284 669 (** A [Cond] is parameterized by a natural [n], which tells us how many cases this conditional has. The test expressions are represented with a function of type [ffin n -> exp' Bool], and the bodies are represented with a function of type [ffin n -> exp' t], where [t] is the overall type. The final [exp' t] argument is the default case. For example, here is an expression that successively checks whether [2 + 2 = 5] (returning 0 if so) or if [1 + 1 = 2] (returning 1 if so), returning 2 otherwise. *)
adamc@112 670
adam@284 671 Example ex1 := Cond 2
adam@284 672 (fun f => match f with
adam@284 673 | None => Eq (Plus (NConst 2) (NConst 2)) (NConst 5)
adam@284 674 | Some None => Eq (Plus (NConst 1) (NConst 1)) (NConst 2)
adam@284 675 | Some (Some v) => match v with end
adam@284 676 end)
adam@284 677 (fun f => match f with
adam@284 678 | None => NConst 0
adam@284 679 | Some None => NConst 1
adam@284 680 | Some (Some v) => match v with end
adam@284 681 end)
adam@284 682 (NConst 2).
adam@284 683
adam@284 684 (** We start implementing our interpreter with a standard type denotation function. *)
adamc@112 685
adamc@111 686 Definition type'Denote (t : type') : Set :=
adamc@111 687 match t with
adamc@112 688 | Nat => nat
adamc@112 689 | Bool => bool
adamc@111 690 end.
adamc@111 691
adamc@112 692 (** To implement the expression interpreter, it is useful to have the following function that implements the functionality of [Cond] without involving any syntax. *)
adamc@112 693
adamc@113 694 (* begin thide *)
adamc@111 695 Section cond.
adamc@111 696 Variable A : Set.
adamc@111 697 Variable default : A.
adamc@111 698
adamc@215 699 Fixpoint cond (n : nat) : (ffin n -> bool) -> (ffin n -> A) -> A :=
adamc@215 700 match n with
adamc@111 701 | O => fun _ _ => default
adamc@111 702 | S n' => fun tests bodies =>
adamc@111 703 if tests None
adamc@111 704 then bodies None
adamc@111 705 else cond n'
adamc@111 706 (fun idx => tests (Some idx))
adamc@111 707 (fun idx => bodies (Some idx))
adamc@111 708 end.
adamc@111 709 End cond.
adamc@111 710
adamc@111 711 Implicit Arguments cond [A n].
adamc@113 712 (* end thide *)
adamc@111 713
adamc@112 714 (** Now the expression interpreter is straightforward to write. *)
adamc@112 715
adamc@215 716 Fixpoint exp'Denote t (e : exp' t) : type'Denote t :=
adamc@215 717 match e with
adamc@215 718 | NConst n => n
adamc@215 719 | Plus e1 e2 => exp'Denote e1 + exp'Denote e2
adamc@111 720 | Eq e1 e2 =>
adamc@111 721 if eq_nat_dec (exp'Denote e1) (exp'Denote e2) then true else false
adamc@111 722
adamc@215 723 | BConst b => b
adamc@111 724 | Cond _ _ tests bodies default =>
adamc@113 725 (* begin thide *)
adamc@111 726 cond
adamc@111 727 (exp'Denote default)
adamc@111 728 (fun idx => exp'Denote (tests idx))
adamc@111 729 (fun idx => exp'Denote (bodies idx))
adamc@113 730 (* end thide *)
adamc@111 731 end.
adamc@111 732
adamc@112 733 (** We will implement a constant-folding function that optimizes conditionals, removing cases with known-[false] tests and cases that come after known-[true] tests. A function [cfoldCond] implements the heart of this logic. The convoy pattern is used again near the end of the implementation. *)
adamc@112 734
adamc@113 735 (* begin thide *)
adamc@111 736 Section cfoldCond.
adamc@111 737 Variable t : type'.
adamc@111 738 Variable default : exp' t.
adamc@111 739
adamc@112 740 Fixpoint cfoldCond (n : nat)
adamc@215 741 : (ffin n -> exp' Bool) -> (ffin n -> exp' t) -> exp' t :=
adamc@215 742 match n with
adamc@111 743 | O => fun _ _ => default
adamc@111 744 | S n' => fun tests bodies =>
adamc@204 745 match tests None return _ with
adamc@111 746 | BConst true => bodies None
adamc@111 747 | BConst false => cfoldCond n'
adamc@111 748 (fun idx => tests (Some idx))
adamc@111 749 (fun idx => bodies (Some idx))
adamc@111 750 | _ =>
adamc@111 751 let e := cfoldCond n'
adamc@111 752 (fun idx => tests (Some idx))
adamc@111 753 (fun idx => bodies (Some idx)) in
adamc@112 754 match e in exp' t return exp' t -> exp' t with
adamc@112 755 | Cond n _ tests' bodies' default' => fun body =>
adamc@111 756 Cond
adamc@111 757 (S n)
adamc@111 758 (fun idx => match idx with
adamc@112 759 | None => tests None
adamc@111 760 | Some idx => tests' idx
adamc@111 761 end)
adamc@111 762 (fun idx => match idx with
adamc@111 763 | None => body
adamc@111 764 | Some idx => bodies' idx
adamc@111 765 end)
adamc@111 766 default'
adamc@112 767 | e => fun body =>
adamc@111 768 Cond
adamc@111 769 1
adamc@112 770 (fun _ => tests None)
adamc@111 771 (fun _ => body)
adamc@111 772 e
adamc@112 773 end (bodies None)
adamc@111 774 end
adamc@111 775 end.
adamc@111 776 End cfoldCond.
adamc@111 777
adamc@111 778 Implicit Arguments cfoldCond [t n].
adamc@113 779 (* end thide *)
adamc@111 780
adamc@112 781 (** Like for the interpreters, most of the action was in this helper function, and [cfold] itself is easy to write. *)
adamc@112 782
adamc@215 783 Fixpoint cfold t (e : exp' t) : exp' t :=
adamc@215 784 match e with
adamc@111 785 | NConst n => NConst n
adamc@111 786 | Plus e1 e2 =>
adamc@111 787 let e1' := cfold e1 in
adamc@111 788 let e2' := cfold e2 in
adam@417 789 match e1', e2' return exp' Nat with
adamc@111 790 | NConst n1, NConst n2 => NConst (n1 + n2)
adamc@111 791 | _, _ => Plus e1' e2'
adamc@111 792 end
adamc@111 793 | Eq e1 e2 =>
adamc@111 794 let e1' := cfold e1 in
adamc@111 795 let e2' := cfold e2 in
adam@417 796 match e1', e2' return exp' Bool with
adamc@111 797 | NConst n1, NConst n2 => BConst (if eq_nat_dec n1 n2 then true else false)
adamc@111 798 | _, _ => Eq e1' e2'
adamc@111 799 end
adamc@111 800
adamc@111 801 | BConst b => BConst b
adamc@111 802 | Cond _ _ tests bodies default =>
adamc@113 803 (* begin thide *)
adamc@111 804 cfoldCond
adamc@111 805 (cfold default)
adamc@111 806 (fun idx => cfold (tests idx))
adamc@111 807 (fun idx => cfold (bodies idx))
adamc@113 808 (* end thide *)
adamc@111 809 end.
adamc@111 810
adamc@113 811 (* begin thide *)
adam@342 812 (** To prove our final correctness theorem, it is useful to know that [cfoldCond] preserves expression meanings. This lemma formalizes that property. The proof is a standard mostly automated one, with the only wrinkle being a guided instantiation of the quantifiers in the induction hypothesis. *)
adamc@112 813
adamc@111 814 Lemma cfoldCond_correct : forall t (default : exp' t)
adamc@215 815 n (tests : ffin n -> exp' Bool) (bodies : ffin n -> exp' t),
adamc@111 816 exp'Denote (cfoldCond default tests bodies)
adamc@111 817 = exp'Denote (Cond n tests bodies default).
adamc@111 818 induction n; crush;
adamc@111 819 match goal with
adamc@111 820 | [ IHn : forall tests bodies, _, tests : _ -> _, bodies : _ -> _ |- _ ] =>
adam@294 821 specialize (IHn (fun idx => tests (Some idx)) (fun idx => bodies (Some idx)))
adamc@111 822 end;
adamc@111 823 repeat (match goal with
adam@406 824 | [ |- context[match ?E with NConst _ => _ | _ => _ end] ] => dep_destruct E
adamc@111 825 | [ |- context[if ?B then _ else _] ] => destruct B
adamc@111 826 end; crush).
adamc@111 827 Qed.
adamc@111 828
adam@398 829 (** It is also useful to know that the result of a call to [cond] is not changed by substituting new tests and bodies functions, so long as the new functions have the same input-output behavior as the old. It turns out that, in Coq, it is not possible to prove in general that functions related in this way are equal. We treat this issue with our discussion of axioms in a later chapter. For now, it suffices to prove that the particular function [cond] is _extensional_; that is, it is unaffected by substitution of functions with input-output equivalents. *)
adamc@112 830
adamc@215 831 Lemma cond_ext : forall (A : Set) (default : A) n (tests tests' : ffin n -> bool)
adamc@215 832 (bodies bodies' : ffin n -> A),
adamc@111 833 (forall idx, tests idx = tests' idx)
adamc@111 834 -> (forall idx, bodies idx = bodies' idx)
adamc@111 835 -> cond default tests bodies
adamc@111 836 = cond default tests' bodies'.
adamc@111 837 induction n; crush;
adamc@111 838 match goal with
adamc@111 839 | [ |- context[if ?E then _ else _] ] => destruct E
adamc@111 840 end; crush.
adamc@111 841 Qed.
adamc@111 842
adam@426 843 (** Now the final theorem is easy to prove. *)
adamc@113 844 (* end thide *)
adamc@112 845
adamc@111 846 Theorem cfold_correct : forall t (e : exp' t),
adamc@111 847 exp'Denote (cfold e) = exp'Denote e.
adamc@113 848 (* begin thide *)
adam@375 849 Hint Rewrite cfoldCond_correct.
adamc@111 850 Hint Resolve cond_ext.
adamc@111 851
adamc@111 852 induction e; crush;
adamc@111 853 repeat (match goal with
adamc@111 854 | [ |- context[cfold ?E] ] => dep_destruct (cfold E)
adamc@111 855 end; crush).
adamc@111 856 Qed.
adamc@113 857 (* end thide *)
adamc@115 858
adam@426 859 (** We add our two lemmas as hints and perform standard automation with pattern-matching of subterms to destruct. *)
adamc@115 860
adamc@215 861 (** * Choosing Between Representations *)
adamc@215 862
adamc@215 863 (** It is not always clear which of these representation techniques to apply in a particular situation, but I will try to summarize the pros and cons of each.
adamc@215 864
adamc@215 865 Inductive types are often the most pleasant to work with, after someone has spent the time implementing some basic library functions for them, using fancy [match] annotations. Many aspects of Coq's logic and tactic support are specialized to deal with inductive types, and you may miss out if you use alternate encodings.
adamc@215 866
adam@426 867 Recursive types usually involve much less initial effort, but they can be less convenient to use with proof automation. For instance, the [simpl] tactic (which is among the ingredients in [crush]) will sometimes be overzealous in simplifying uses of functions over recursive types. Consider a call [get l f], where variable [l] has type [filist A (S n)]. The type of [l] would be simplified to an explicit pair type. In a proof involving many recursive types, this kind of unhelpful "simplification" can lead to rapid bloat in the sizes of subgoals. Even worse, it can prevent syntactic pattern-matching, like in cases where [filist] is expected but a pair type is found in the "simplified" version. The same problem applies to applications of recursive functions to values in recursive types: the recursive function call may "simplify" when the top-level structure of the type index but not the recursive value is known, because such functions are generally defined by recursion on the index, not the value.
adamc@215 868
adam@426 869 Another disadvantage of recursive types is that they only apply to type families whose indices determine their "skeletons." This is not true for all data structures; a good counterexample comes from the richly typed programming language syntax types we have used several times so far. The fact that a piece of syntax has type [Nat] tells us nothing about the tree structure of that syntax.
adamc@215 870
adam@426 871 Finally, Coq type inference can be more helpful in constructing values in inductive types. Application of a particular constructor of that type tells Coq what to expect from the arguments, while, for instance, forming a generic pair does not make clear an intention to interpret the value as belonging to a particular recursive type. This downside can be mitigated to an extent by writing "constructor" functions for a recursive type, mirroring the definition of the corresponding inductive type.
adam@342 872
adam@342 873 Reflexive encodings of data types are seen relatively rarely. As our examples demonstrated, manipulating index values manually can lead to hard-to-read code. A normal inductive type is generally easier to work with, once someone has gone through the trouble of implementing an induction principle manually with the techniques we studied in Chapter 3. For small developments, avoiding that kind of coding can justify the use of reflexive data structures. There are also some useful instances of %\index{co-inductive types}%co-inductive definitions with nested data structures (e.g., lists of values in the co-inductive type) that can only be deconstructed effectively with reflexive encoding of the nested structures. *)