Mercurial > cpdt > repo

annotate src/Match.v @ 206:3f4576f15130

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Revising for 8.2 through first big example
author Adam Chlipala <adamc@hcoop.net>
date Fri, 06 Nov 2009 16:44:06 -0500
parents f05514cc6c0d
children 15501145d696
rev   line source
adamc@132 1 (* Copyright (c) 2008, Adam Chlipala
adamc@132 2 *
adamc@132 3 * This work is licensed under a
adamc@132 4 * Creative Commons Attribution-Noncommercial-No Derivative Works 3.0
adamc@132 5 * Unported License.
adamc@132 6 * The license text is available at:
adamc@132 7 * http://creativecommons.org/licenses/by-nc-nd/3.0/
adamc@132 8 *)
adamc@132 9
adamc@132 10 (* begin hide *)
adamc@132 11 Require Import List.
adamc@132 12
adamc@132 13 Require Import Tactics.
adamc@132 14
adamc@132 15 Set Implicit Arguments.
adamc@132 16 (* end hide *)
adamc@132 17
adamc@132 18
adamc@132 19 (** %\part{Proof Engineering}
adamc@132 20
adamc@132 21 \chapter{Proof Search in Ltac}% *)
adamc@132 22
adamc@132 23 (** We have seen many examples of proof automation so far. This chapter aims to give a principled presentation of the features of Ltac, focusing in particular on the Ltac [match] construct, which supports a novel approach to backtracking search. First, though, we will run through some useful automation tactics that are built into Coq. They are described in detail in the manual, so we only outline what is possible. *)
adamc@132 24
adamc@132 25 (** * Some Built-In Automation Tactics *)
adamc@132 26
adamc@132 27 (** A number of tactics are called repeatedly by [crush]. [intuition] simplifies propositional structure of goals. [congruence] applies the rules of equality and congruence closure, plus properties of constructors of inductive types. The [omega] tactic provides a complete decision procedure for a theory that is called quantifier-free linear arithmetic or Presburger arithmetic, depending on whom you ask. That is, [omega] proves any goal that follows from looking only at parts of that goal that can be interpreted as propositional formulas whose atomic formulas are basic comparison operations on natural numbers or integers.
adamc@132 28
adamc@132 29 The [ring] tactic solves goals by appealing to the axioms of rings or semi-rings (as in algebra), depending on the type involved. Coq developments may declare new types to be parts of rings and semi-rings by proving the associated axioms. There is a simlar tactic [field] for simplifying values in fields by conversion to fractions over rings. Both [ring] and [field] can only solve goals that are equalities. The [fourier] tactic uses Fourier's method to prove inequalities over real numbers, which are axiomatized in the Coq standard library.
adamc@132 30
adamc@133 31 The %\textit{%#<i>#setoid#</i>#%}% facility makes it possible to register new equivalence relations to be understood by tactics like [rewrite]. For instance, [Prop] is registered as a setoid with the equivalence relation "if and only if." The ability to register new setoids can be very useful in proofs of a kind common in math, where all reasoning is done after "modding out by a relation." *)
adamc@132 32
adamc@132 33
adamc@133 34 (** * Hint Databases *)
adamc@132 35
adamc@133 36 (** Another class of built-in tactics includes [auto], [eauto], and [autorewrite]. These are based on %\textit{%#<i>#hint databases#</i>#%}%, which we have seen extended in many examples so far. These tactics are important, because, in Ltac programming, we cannot create "global variables" whose values can be extended seamlessly by different modules in different source files. We have seen the advantages of hints so far, where [crush] can be defined once and for all, while still automatically applying the hints we add throughout developments.
adamc@133 37
adamc@133 38 The basic hints for [auto] and [eauto] are [Hint Immediate lemma], asking to try solving a goal immediately by applying the premise-free lemma; [Resolve lemma], which does the same but may add new premises that are themselves to be subjects of proof search; [Constructor type], which acts like [Resolve] applied to every constructor of an inductive type; and [Unfold ident], which tries unfolding [ident] when it appears at the head of a proof goal. Each of these [Hint] commands may be used with a suffix, as in [Hint Resolve lemma : my_db]. This adds the hint only to the specified database, so that it would only be used by, for instance, [auto with my_db]. An additional argument to [auto] specifies the maximum depth of proof trees to search in depth-first order, as in [auto 8] or [auto 8 with my_db]. The default depth is 5.
adamc@133 39
adamc@133 40 All of these [Hint] commands can be issued alternatively with a more primitive hint kind, [Extern]. A few examples should do best to explain how [Hint Extern] works. *)
adamc@133 41
adamc@133 42 Theorem bool_neq : true <> false.
adamc@141 43 (* begin thide *)
adamc@133 44 auto.
adamc@133 45 (** [crush] would have discharged this goal, but the default hint database for [auto] contains no hint that applies. *)
adamc@133 46 Abort.
adamc@133 47
adamc@133 48 (** It is hard to come up with a [bool]-specific hint that is not just a restatement of the theorem we mean to prove. Luckily, a simpler form suffices. *)
adamc@133 49
adamc@133 50 Hint Extern 1 (_ <> _) => congruence.
adamc@133 51
adamc@133 52 Theorem bool_neq : true <> false.
adamc@133 53 auto.
adamc@133 54 Qed.
adamc@141 55 (* end thide *)
adamc@133 56
adamc@133 57 (** Our hint says: "whenever the conclusion matches the pattern [_ <> _], try applying [congruence]." The [1] is a cost for this rule. During proof search, whenever multiple rules apply, rules are tried in increasing cost order, so it pays to assign high costs to relatively expensive [Extern] hints.
adamc@133 58
adamc@133 59 [Extern] hints may be implemented with the full Ltac language. This example shows a case where a hint uses a [match]. *)
adamc@133 60
adamc@133 61 Section forall_and.
adamc@133 62 Variable A : Set.
adamc@133 63 Variables P Q : A -> Prop.
adamc@133 64
adamc@133 65 Hypothesis both : forall x, P x /\ Q x.
adamc@133 66
adamc@133 67 Theorem forall_and : forall z, P z.
adamc@141 68 (* begin thide *)
adamc@133 69 crush.
adamc@133 70 (** [crush] makes no progress beyond what [intros] would have accomplished. [auto] will not apply the hypothesis [both] to prove the goal, because the conclusion of [both] does not unify with the conclusion of the goal. However, we can teach [auto] to handle this kind of goal. *)
adamc@133 71
adamc@133 72 Hint Extern 1 (P ?X) =>
adamc@133 73 match goal with
adamc@133 74 | [ H : forall x, P x /\ _ |- _ ] => apply (proj1 (H X))
adamc@133 75 end.
adamc@133 76
adamc@133 77 auto.
adamc@133 78 Qed.
adamc@141 79 (* end thide *)
adamc@133 80
adamc@133 81 (** We see that an [Extern] pattern may bind unification variables that we use in the associated tactic. [proj1] is a function from the standard library for extracting a proof of [R] from a proof of [R /\ S]. *)
adamc@133 82 End forall_and.
adamc@133 83
adamc@133 84 (** After our success on this example, we might get more ambitious and seek to generalize the hint to all possible predicates [P].
adamc@133 85
adamc@133 86 [[
adamc@133 87 Hint Extern 1 (?P ?X) =>
adamc@133 88 match goal with
adamc@133 89 | [ H : forall x, ?P x /\ _ |- _ ] => apply (proj1 (H X))
adamc@133 90 end.
adamc@133 91
adamc@205 92 ]]
adamc@205 93
adamc@134 94 [[
adamc@133 95 User error: Bound head variable
adamc@134 96 ]]
adamc@133 97
adamc@134 98 Coq's [auto] hint databases work as tables mapping %\textit{%#<i>#head symbols#</i>#%}% to lists of tactics to try. Because of this, the constant head of an [Extern] pattern must be determinable statically. In our first [Extern] hint, the head symbol was [not], since [x <> y] desugars to [not (eq x y)]; and, in the second example, the head symbol was [P].
adamc@133 99
adamc@134 100 This restriction on [Extern] hints is the main limitation of the [auto] mechanism, preventing us from using it for general context simplifications that are not keyed off of the form of the conclusion. This is perhaps just as well, since we can often code more efficient tactics with specialized Ltac programs, and we will see how in later sections of the chapter.
adamc@134 101
adamc@134 102 We have used [Hint Rewrite] in many examples so far. [crush] uses these hints by calling [autorewrite]. Our rewrite hints have taken the form [Hint Rewrite lemma : cpdt], adding them to the [cpdt] rewrite database. This is because, in contrast to [auto], [autorewrite] has no default database. Thus, we set the convention that [crush] uses the [cpdt] database.
adamc@134 103
adamc@134 104 This example shows a direct use of [autorewrite]. *)
adamc@134 105
adamc@134 106 Section autorewrite.
adamc@134 107 Variable A : Set.
adamc@134 108 Variable f : A -> A.
adamc@134 109
adamc@134 110 Hypothesis f_f : forall x, f (f x) = f x.
adamc@134 111
adamc@134 112 Hint Rewrite f_f : my_db.
adamc@134 113
adamc@134 114 Lemma f_f_f : forall x, f (f (f x)) = f x.
adamc@134 115 intros; autorewrite with my_db; reflexivity.
adamc@134 116 Qed.
adamc@134 117
adamc@134 118 (** There are a few ways in which [autorewrite] can lead to trouble when insufficient care is taken in choosing hints. First, the set of hints may define a nonterminating rewrite system, in which case invocations to [autorewrite] may not terminate. Second, we may add hints that "lead [autorewrite] down the wrong path." For instance: *)
adamc@134 119
adamc@134 120 Section garden_path.
adamc@134 121 Variable g : A -> A.
adamc@134 122 Hypothesis f_g : forall x, f x = g x.
adamc@134 123 Hint Rewrite f_g : my_db.
adamc@134 124
adamc@134 125 Lemma f_f_f' : forall x, f (f (f x)) = f x.
adamc@134 126 intros; autorewrite with my_db.
adamc@134 127 (** [[
adamc@134 128
adamc@134 129 ============================
adamc@134 130 g (g (g x)) = g x
adamc@134 131 ]] *)
adamc@134 132 Abort.
adamc@134 133
adamc@134 134 (** Our new hint was used to rewrite the goal into a form where the old hint could no longer be applied. This "non-monotonicity" of rewrite hints contrasts with the situation for [auto], where new hints may slow down proof search but can never "break" old proofs. *)
adamc@134 135
adamc@134 136 Reset garden_path.
adamc@134 137
adamc@134 138 (** [autorewrite] works with quantified equalities that include additional premises, but we must be careful to avoid similar incorrect rewritings. *)
adamc@134 139
adamc@134 140 Section garden_path.
adamc@134 141 Variable P : A -> Prop.
adamc@134 142 Variable g : A -> A.
adamc@134 143 Hypothesis f_g : forall x, P x -> f x = g x.
adamc@134 144 Hint Rewrite f_g : my_db.
adamc@134 145
adamc@134 146 Lemma f_f_f' : forall x, f (f (f x)) = f x.
adamc@134 147 intros; autorewrite with my_db.
adamc@134 148 (** [[
adamc@134 149
adamc@134 150 ============================
adamc@134 151 g (g (g x)) = g x
adamc@134 152
adamc@134 153 subgoal 2 is:
adamc@134 154 P x
adamc@134 155 subgoal 3 is:
adamc@134 156 P (f x)
adamc@134 157 subgoal 4 is:
adamc@134 158 P (f x)
adamc@134 159 ]] *)
adamc@134 160 Abort.
adamc@134 161
adamc@134 162 (** The inappropriate rule fired the same three times as before, even though we know we will not be able to prove the premises. *)
adamc@134 163
adamc@134 164 Reset garden_path.
adamc@134 165
adamc@134 166 (** Our final, successful, attempt uses an extra argument to [Hint Rewrite] that specifies a tactic to apply to generated premises. *)
adamc@134 167
adamc@134 168 Section garden_path.
adamc@134 169 Variable P : A -> Prop.
adamc@134 170 Variable g : A -> A.
adamc@134 171 Hypothesis f_g : forall x, P x -> f x = g x.
adamc@141 172 (* begin thide *)
adamc@134 173 Hint Rewrite f_g using assumption : my_db.
adamc@141 174 (* end thide *)
adamc@134 175
adamc@134 176 Lemma f_f_f' : forall x, f (f (f x)) = f x.
adamc@141 177 (* begin thide *)
adamc@134 178 intros; autorewrite with my_db; reflexivity.
adamc@134 179 Qed.
adamc@141 180 (* end thide *)
adamc@134 181
adamc@134 182 (** [autorewrite] will still use [f_g] when the generated premise is among our assumptions. *)
adamc@134 183
adamc@134 184 Lemma f_f_f_g : forall x, P x -> f (f x) = g x.
adamc@141 185 (* begin thide *)
adamc@134 186 intros; autorewrite with my_db; reflexivity.
adamc@141 187 (* end thide *)
adamc@134 188 Qed.
adamc@134 189 End garden_path.
adamc@134 190
adamc@134 191 (** It can also be useful to use the [autorewrite with db in *] form, which does rewriting in hypotheses, as well as in the conclusion. *)
adamc@134 192
adamc@134 193 Lemma in_star : forall x y, f (f (f (f x))) = f (f y)
adamc@134 194 -> f x = f (f (f y)).
adamc@141 195 (* begin thide *)
adamc@134 196 intros; autorewrite with my_db in *; assumption.
adamc@141 197 (* end thide *)
adamc@134 198 Qed.
adamc@134 199
adamc@134 200 End autorewrite.
adamc@135 201
adamc@135 202
adamc@135 203 (** * Ltac Programming Basics *)
adamc@135 204
adamc@135 205 (** We have already seen many examples of Ltac programs. In the rest of this chapter, we attempt to give a more principled introduction to the important features and design patterns.
adamc@135 206
adamc@135 207 One common use for [match] tactics is identification of subjects for case analysis, as we see in this tactic definition. *)
adamc@135 208
adamc@141 209 (* begin thide *)
adamc@135 210 Ltac find_if :=
adamc@135 211 match goal with
adamc@135 212 | [ |- if ?X then _ else _ ] => destruct X
adamc@135 213 end.
adamc@141 214 (* end thide *)
adamc@135 215
adamc@135 216 (** The tactic checks if the conclusion is an [if], [destruct]ing the test expression if so. Certain classes of theorem are trivial to prove automatically with such a tactic. *)
adamc@135 217
adamc@135 218 Theorem hmm : forall (a b c : bool),
adamc@135 219 if a
adamc@135 220 then if b
adamc@135 221 then True
adamc@135 222 else True
adamc@135 223 else if c
adamc@135 224 then True
adamc@135 225 else True.
adamc@141 226 (* begin thide *)
adamc@135 227 intros; repeat find_if; constructor.
adamc@135 228 Qed.
adamc@141 229 (* end thide *)
adamc@135 230
adamc@135 231 (** The [repeat] that we use here is called a %\textit{%#<i>#tactical#</i>#%}%, or tactic combinator. The behavior of [repeat t] is to loop through running [t], running [t] on all generated subgoals, running [t] on %\textit{%#<i>#their#</i>#%}% generated subgoals, and so on. When [t] fails at any point in this search tree, that particular subgoal is left to be handled by later tactics. Thus, it is important never to use [repeat] with a tactic that always succeeds.
adamc@135 232
adamc@135 233 Another very useful Ltac building block is %\textit{%#<i>#context patterns#</i>#%}%. *)
adamc@135 234
adamc@141 235 (* begin thide *)
adamc@135 236 Ltac find_if_inside :=
adamc@135 237 match goal with
adamc@135 238 | [ |- context[if ?X then _ else _] ] => destruct X
adamc@135 239 end.
adamc@141 240 (* end thide *)
adamc@135 241
adamc@135 242 (** The behavior of this tactic is to find any subterm of the conclusion that is an [if] and then [destruct] the test expression. This version subsumes [find_if]. *)
adamc@135 243
adamc@135 244 Theorem hmm' : forall (a b c : bool),
adamc@135 245 if a
adamc@135 246 then if b
adamc@135 247 then True
adamc@135 248 else True
adamc@135 249 else if c
adamc@135 250 then True
adamc@135 251 else True.
adamc@141 252 (* begin thide *)
adamc@135 253 intros; repeat find_if_inside; constructor.
adamc@135 254 Qed.
adamc@141 255 (* end thide *)
adamc@135 256
adamc@135 257 (** We can also use [find_if_inside] to prove goals that [find_if] does not simplify sufficiently. *)
adamc@135 258
adamc@141 259 Theorem hmm2 : forall (a b : bool),
adamc@135 260 (if a then 42 else 42) = (if b then 42 else 42).
adamc@141 261 (* begin thide *)
adamc@135 262 intros; repeat find_if_inside; reflexivity.
adamc@135 263 Qed.
adamc@141 264 (* end thide *)
adamc@135 265
adamc@135 266 (** Many decision procedures can be coded in Ltac via "[repeat match] loops." For instance, we can implement a subset of the functionality of [tauto]. *)
adamc@135 267
adamc@141 268 (* begin thide *)
adamc@135 269 Ltac my_tauto :=
adamc@135 270 repeat match goal with
adamc@135 271 | [ H : ?P |- ?P ] => exact H
adamc@135 272
adamc@135 273 | [ |- True ] => constructor
adamc@135 274 | [ |- _ /\ _ ] => constructor
adamc@135 275 | [ |- _ -> _ ] => intro
adamc@135 276
adamc@135 277 | [ H : False |- _ ] => destruct H
adamc@135 278 | [ H : _ /\ _ |- _ ] => destruct H
adamc@135 279 | [ H : _ \/ _ |- _ ] => destruct H
adamc@135 280
adamc@135 281 | [ H1 : ?P -> ?Q, H2 : ?P |- _ ] =>
adamc@135 282 let H := fresh "H" in
adamc@135 283 generalize (H1 H2); clear H1; intro H
adamc@135 284 end.
adamc@141 285 (* end thide *)
adamc@135 286
adamc@135 287 (** Since [match] patterns can share unification variables between hypothesis and conclusion patterns, it is easy to figure out when the conclusion matches a hypothesis. The [exact] tactic solves a goal completely when given a proof term of the proper type.
adamc@135 288
adamc@135 289 It is also trivial to implement the "introduction rules" for a few of the connectives. Implementing elimination rules is only a little more work, since we must bind a name for a hypothesis to [destruct].
adamc@135 290
adamc@135 291 The last rule implements modus ponens. The most interesting part is the use of the Ltac-level [let] with a [fresh] expression. [fresh] takes in a name base and returns a fresh hypothesis variable based on that name. We use the new name variable [H] as the name we assign to the result of modus ponens. The use of [generalize] changes our conclusion to be an implication from [Q]. We clear the original hypothesis and move [Q] into the context with name [H]. *)
adamc@135 292
adamc@135 293 Section propositional.
adamc@135 294 Variables P Q R : Prop.
adamc@135 295
adamc@138 296 Theorem propositional : (P \/ Q \/ False) /\ (P -> Q) -> True /\ Q.
adamc@141 297 (* begin thide *)
adamc@135 298 my_tauto.
adamc@135 299 Qed.
adamc@141 300 (* end thide *)
adamc@135 301 End propositional.
adamc@135 302
adamc@135 303 (** It was relatively easy to implement modus ponens, because we do not lose information by clearing every implication that we use. If we want to implement a similarly-complete procedure for quantifier instantiation, we need a way to ensure that a particular proposition is not already included among our hypotheses. To do that effectively, we first need to learn a bit more about the semantics of [match].
adamc@135 304
adamc@135 305 It is tempting to assume that [match] works like it does in ML. In fact, there are a few critical differences in its behavior. One is that we may include arbitrary expressions in patterns, instead of being restricted to variables and constructors. Another is that the same variable may appear multiple times, inducing an implicit equality constraint.
adamc@135 306
adamc@135 307 There is a related pair of two other differences that are much more important than the others. [match] has a %\textit{%#<i>#backtracking semantics for failure#</i>#%}%. In ML, pattern matching works by finding the first pattern to match and then executing its body. If the body raises an exception, then the overall match raises the same exception. In Coq, failures in case bodies instead trigger continued search through the list of cases.
adamc@135 308
adamc@135 309 For instance, this (unnecessarily verbose) proof script works: *)
adamc@135 310
adamc@135 311 Theorem m1 : True.
adamc@135 312 match goal with
adamc@135 313 | [ |- _ ] => intro
adamc@135 314 | [ |- True ] => constructor
adamc@135 315 end.
adamc@141 316 (* begin thide *)
adamc@135 317 Qed.
adamc@141 318 (* end thide *)
adamc@135 319
adamc@135 320 (** The first case matches trivially, but its body tactic fails, since the conclusion does not begin with a quantifier or implication. In a similar ML match, that would mean that the whole pattern-match fails. In Coq, we backtrack and try the next pattern, which also matches. Its body tactic succeeds, so the overall tactic succeeds as well.
adamc@135 321
adamc@135 322 The example shows how failure can move to a different pattern within a [match]. Failure can also trigger an attempt to find %\textit{%#<i>#a different way of matching a single pattern#</i>#%}%. Consider another example: *)
adamc@135 323
adamc@135 324 Theorem m2 : forall P Q R : Prop, P -> Q -> R -> Q.
adamc@135 325 intros; match goal with
adamc@135 326 | [ H : _ |- _ ] => pose H
adamc@135 327 end.
adamc@135 328 (** [[
adamc@135 329
adamc@135 330 r := H1 : R
adamc@135 331 ============================
adamc@135 332 Q
adamc@135 333 ]]
adamc@135 334
adamc@135 335 By applying [pose], a convenient debugging tool for "leaking information out of [match]es," we see that this [match] first tries binding [H] to [H1], which cannot be used to prove [Q]. Nonetheless, the following variation on the tactic succeeds at proving the goal: *)
adamc@135 336
adamc@141 337 (* begin thide *)
adamc@135 338 match goal with
adamc@135 339 | [ H : _ |- _ ] => exact H
adamc@135 340 end.
adamc@135 341 Qed.
adamc@141 342 (* end thide *)
adamc@135 343
adamc@135 344 (** The tactic first unifies [H] with [H1], as before, but [exact H] fails in that case, so the tactic engine searches for more possible values of [H]. Eventually, it arrives at the correct value, so that [exact H] and the overall tactic succeed. *)
adamc@135 345
adamc@135 346 (** Now we are equipped to implement a tactic for checking that a proposition is not among our hypotheses: *)
adamc@135 347
adamc@141 348 (* begin thide *)
adamc@135 349 Ltac notHyp P :=
adamc@135 350 match goal with
adamc@135 351 | [ _ : P |- _ ] => fail 1
adamc@135 352 | _ =>
adamc@135 353 match P with
adamc@135 354 | ?P1 /\ ?P2 => first [ notHyp P1 | notHyp P2 | fail 2 ]
adamc@135 355 | _ => idtac
adamc@135 356 end
adamc@135 357 end.
adamc@141 358 (* end thide *)
adamc@135 359
adamc@135 360 (** We use the equality checking that is built into pattern-matching to see if there is a hypothesis that matches the proposition exactly. If so, we use the [fail] tactic. Without arguments, [fail] signals normal tactic failure, as you might expect. When [fail] is passed an argument [n], [n] is used to count outwards through the enclosing cases of backtracking search. In this case, [fail 1] says "fail not just in this pattern-matching branch, but for the whole [match]." The second case will never be tried when the [fail 1] is reached.
adamc@135 361
adamc@135 362 This second case, used when [P] matches no hypothesis, checks if [P] is a conjunction. Other simplifications may have split conjunctions into their component formulas, so we need to check that at least one of those components is also not represented. To achieve this, we apply the [first] tactical, which takes a list of tactics and continues down the list until one of them does not fail. The [fail 2] at the end says to [fail] both the [first] and the [match] wrapped around it.
adamc@135 363
adamc@135 364 The body of the [?P1 /\ ?P2] case guarantees that, if it is reached, we either succeed completely or fail completely. Thus, if we reach the wildcard case, [P] is not a conjunction. We use [idtac], a tactic that would be silly to apply on its own, since its effect is to succeed at doing nothing. Nonetheless, [idtac] is a useful placeholder for cases like what we see here.
adamc@135 365
adamc@135 366 With the non-presence check implemented, it is easy to build a tactic that takes as input a proof term and adds its conclusion as a new hypothesis, only if that conclusion is not already present, failing otherwise. *)
adamc@135 367
adamc@141 368 (* begin thide *)
adamc@135 369 Ltac extend pf :=
adamc@135 370 let t := type of pf in
adamc@135 371 notHyp t; generalize pf; intro.
adamc@141 372 (* end thide *)
adamc@135 373
adamc@135 374 (** We see the useful [type of] operator of Ltac. This operator could not be implemented in Gallina, but it is easy to support in Ltac. We end up with [t] bound to the type of [pf]. We check that [t] is not already present. If so, we use a [generalize]/[intro] combo to add a new hypothesis proved by [pf].
adamc@135 375
adamc@135 376 With these tactics defined, we can write a tactic [completer] for adding to the context all consequences of a set of simple first-order formulas. *)
adamc@135 377
adamc@141 378 (* begin thide *)
adamc@135 379 Ltac completer :=
adamc@135 380 repeat match goal with
adamc@135 381 | [ |- _ /\ _ ] => constructor
adamc@135 382 | [ H : _ /\ _ |- _ ] => destruct H
adamc@135 383 | [ H : ?P -> ?Q, H' : ?P |- _ ] =>
adamc@135 384 generalize (H H'); clear H; intro H
adamc@135 385 | [ |- forall x, _ ] => intro
adamc@135 386
adamc@135 387 | [ H : forall x, ?P x -> _, H' : ?P ?X |- _ ] =>
adamc@135 388 extend (H X H')
adamc@135 389 end.
adamc@141 390 (* end thide *)
adamc@135 391
adamc@135 392 (** We use the same kind of conjunction and implication handling as previously. Note that, since [->] is the special non-dependent case of [forall], the fourth rule handles [intro] for implications, too.
adamc@135 393
adamc@135 394 In the fifth rule, when we find a [forall] fact [H] with a premise matching one of our hypotheses, we add the appropriate instantiation of [H]'s conclusion, if we have not already added it.
adamc@135 395
adamc@135 396 We can check that [completer] is working properly: *)
adamc@135 397
adamc@135 398 Section firstorder.
adamc@135 399 Variable A : Set.
adamc@135 400 Variables P Q R S : A -> Prop.
adamc@135 401
adamc@135 402 Hypothesis H1 : forall x, P x -> Q x /\ R x.
adamc@135 403 Hypothesis H2 : forall x, R x -> S x.
adamc@135 404
adamc@135 405 Theorem fo : forall x, P x -> S x.
adamc@141 406 (* begin thide *)
adamc@135 407 completer.
adamc@135 408 (** [[
adamc@135 409
adamc@135 410 x : A
adamc@135 411 H : P x
adamc@135 412 H0 : Q x
adamc@135 413 H3 : R x
adamc@135 414 H4 : S x
adamc@135 415 ============================
adamc@135 416 S x
adamc@135 417 ]] *)
adamc@135 418
adamc@135 419 assumption.
adamc@135 420 Qed.
adamc@141 421 (* end thide *)
adamc@135 422 End firstorder.
adamc@135 423
adamc@135 424 (** We narrowly avoided a subtle pitfall in our definition of [completer]. Let us try another definition that even seems preferable to the original, to the untrained eye. *)
adamc@135 425
adamc@141 426 (* begin thide *)
adamc@135 427 Ltac completer' :=
adamc@135 428 repeat match goal with
adamc@135 429 | [ |- _ /\ _ ] => constructor
adamc@135 430 | [ H : _ /\ _ |- _ ] => destruct H
adamc@135 431 | [ H : ?P -> _, H' : ?P |- _ ] =>
adamc@135 432 generalize (H H'); clear H; intro H
adamc@135 433 | [ |- forall x, _ ] => intro
adamc@135 434
adamc@135 435 | [ H : forall x, ?P x -> _, H' : ?P ?X |- _ ] =>
adamc@135 436 extend (H X H')
adamc@135 437 end.
adamc@141 438 (* end thide *)
adamc@135 439
adamc@135 440 (** The only difference is in the modus ponens rule, where we have replaced an unused unification variable [?Q] with a wildcard. Let us try our example again with this version: *)
adamc@135 441
adamc@135 442 Section firstorder'.
adamc@135 443 Variable A : Set.
adamc@135 444 Variables P Q R S : A -> Prop.
adamc@135 445
adamc@135 446 Hypothesis H1 : forall x, P x -> Q x /\ R x.
adamc@135 447 Hypothesis H2 : forall x, R x -> S x.
adamc@135 448
adamc@135 449 Theorem fo' : forall x, P x -> S x.
adamc@141 450 (* begin thide *)
adamc@135 451 (** [[
adamc@135 452
adamc@135 453 completer'.
adamc@135 454
adamc@205 455 ]]
adamc@205 456
adamc@135 457 Coq loops forever at this point. What went wrong? *)
adamc@135 458 Abort.
adamc@141 459 (* end thide *)
adamc@135 460 End firstorder'.
adamc@136 461
adamc@136 462 (** A few examples should illustrate the issue. Here we see a [match]-based proof that works fine: *)
adamc@136 463
adamc@136 464 Theorem t1 : forall x : nat, x = x.
adamc@136 465 match goal with
adamc@136 466 | [ |- forall x, _ ] => trivial
adamc@136 467 end.
adamc@141 468 (* begin thide *)
adamc@136 469 Qed.
adamc@141 470 (* end thide *)
adamc@136 471
adamc@136 472 (** This one fails. *)
adamc@136 473
adamc@141 474 (* begin thide *)
adamc@136 475 Theorem t1' : forall x : nat, x = x.
adamc@136 476 (** [[
adamc@136 477
adamc@136 478 match goal with
adamc@136 479 | [ |- forall x, ?P ] => trivial
adamc@136 480 end.
adamc@136 481
adamc@205 482 ]]
adamc@205 483
adamc@136 484 [[
adamc@136 485 User error: No matching clauses for match goal
adamc@136 486 ]] *)
adamc@136 487 Abort.
adamc@141 488 (* end thide *)
adamc@136 489
adamc@136 490 (** The problem is that unification variables may not contain locally-bound variables. In this case, [?P] would need to be bound to [x = x], which contains the local quantified variable [x]. By using a wildcard in the earlier version, we avoided this restriction.
adamc@136 491
adamc@136 492 The Coq 8.2 release includes a special pattern form for a unification variable with an explicit set of free variables. That unification variable is then bound to a function from the free variables to the "real" value. In Coq 8.1 and earlier, there is no such workaround.
adamc@136 493
adamc@136 494 No matter which version you use, it is important to be aware of this restriction. As we have alluded to, the restriction is the culprit behind the infinite-looping behavior of [completer']. We unintentionally match quantified facts with the modus ponens rule, circumventing the "already present" check and leading to different behavior. *)
adamc@137 495
adamc@137 496
adamc@137 497 (** * Functional Programming in Ltac *)
adamc@137 498
adamc@141 499 (* EX: Write a list length function in Ltac. *)
adamc@141 500
adamc@137 501 (** Ltac supports quite convenient functional programming, with a Lisp-with-syntax kind of flavor. However, there are a few syntactic conventions involved in getting programs to be accepted. The Ltac syntax is optimized for tactic-writing, so one has to deal with some inconveniences in writing more standard functional programs.
adamc@137 502
adamc@137 503 To illustrate, let us try to write a simple list length function. We start out writing it just like in Gallina, simply replacing [Fixpoint] (and its annotations) with [Ltac].
adamc@137 504
adamc@137 505 [[
adamc@137 506 Ltac length ls :=
adamc@137 507 match ls with
adamc@137 508 | nil => O
adamc@137 509 | _ :: ls' => S (length ls')
adamc@137 510 end.
adamc@137 511
adamc@205 512 ]]
adamc@205 513
adamc@137 514 [[
adamc@137 515 Error: The reference ls' was not found in the current environment
adamc@137 516 ]]
adamc@137 517
adamc@137 518 At this point, we hopefully remember that pattern variable names must be prefixed by question marks in Ltac.
adamc@137 519
adamc@137 520 [[
adamc@137 521 Ltac length ls :=
adamc@137 522 match ls with
adamc@137 523 | nil => O
adamc@137 524 | _ :: ?ls' => S (length ls')
adamc@137 525 end.
adamc@137 526
adamc@205 527 ]]
adamc@205 528
adamc@137 529 [[
adamc@137 530 Error: The reference S was not found in the current environment
adamc@137 531 ]]
adamc@137 532
adamc@137 533 The problem is that Ltac treats the expression [S (length ls')] as an invocation of a tactic [S] with argument [length ls']. We need to use a special annotation to "escape into" the Gallina parsing nonterminal. *)
adamc@137 534
adamc@141 535 (* begin thide *)
adamc@137 536 Ltac length ls :=
adamc@137 537 match ls with
adamc@137 538 | nil => O
adamc@137 539 | _ :: ?ls' => constr:(S (length ls'))
adamc@137 540 end.
adamc@137 541
adamc@137 542 (** This definition is accepted. It can be a little awkward to test Ltac definitions like this. Here is one method. *)
adamc@137 543
adamc@137 544 Goal False.
adamc@137 545 let n := length (1 :: 2 :: 3 :: nil) in
adamc@137 546 pose n.
adamc@137 547 (** [[
adamc@137 548
adamc@137 549 n := S (length (2 :: 3 :: nil)) : nat
adamc@137 550 ============================
adamc@137 551 False
adamc@137 552 ]]
adamc@137 553
adamc@137 554 [n] only has the length calculation unrolled one step. What has happened here is that, by escaping into the [constr] nonterminal, we referred to the [length] function of Gallina, rather than the [length] Ltac function that we are defining. *)Abort.
adamc@137 555
adamc@137 556 Reset length.
adamc@137 557
adamc@137 558 (** The thing to remember is that Gallina terms built by tactics must be bound explicitly via [let] or a similar technique, rather than inserting Ltac calls directly in other Gallina terms. *)
adamc@137 559
adamc@137 560 Ltac length ls :=
adamc@137 561 match ls with
adamc@137 562 | nil => O
adamc@137 563 | _ :: ?ls' =>
adamc@137 564 let ls'' := length ls' in
adamc@137 565 constr:(S ls'')
adamc@137 566 end.
adamc@137 567
adamc@137 568 Goal False.
adamc@137 569 let n := length (1 :: 2 :: 3 :: nil) in
adamc@137 570 pose n.
adamc@137 571 (** [[
adamc@137 572
adamc@137 573 n := 3 : nat
adamc@137 574 ============================
adamc@137 575 False
adamc@137 576 ]] *)
adamc@137 577 Abort.
adamc@141 578 (* end thide *)
adamc@141 579
adamc@141 580 (* EX: Write a list map function in Ltac. *)
adamc@137 581
adamc@137 582 (** We can also use anonymous function expressions and local function definitions in Ltac, as this example of a standard list [map] function shows. *)
adamc@137 583
adamc@141 584 (* begin thide *)
adamc@137 585 Ltac map T f :=
adamc@137 586 let rec map' ls :=
adamc@137 587 match ls with
adamc@137 588 | nil => constr:(@nil T)
adamc@137 589 | ?x :: ?ls' =>
adamc@137 590 let x' := f x in
adamc@137 591 let ls'' := map' ls' in
adamc@137 592 constr:(x' :: ls'')
adamc@137 593 end in
adamc@137 594 map'.
adamc@137 595
adamc@137 596 (** Ltac functions can have no implicit arguments. It may seem surprising that we need to pass [T], the carried type of the output list, explicitly. We cannot just use [type of f], because [f] is an Ltac term, not a Gallina term, and Ltac programs are dynamically typed. [f] could use very syntactic methods to decide to return differently typed terms for different inputs. We also could not replace [constr:(@nil T)] with [constr:nil], because we have no strongly-typed context to use to infer the parameter to [nil]. Luckily, we do have sufficient context within [constr:(x' :: ls'')].
adamc@137 597
adamc@137 598 Sometimes we need to employ the opposite direction of "nonterminal escape," when we want to pass a complicated tactic expression as an argument to another tactic, as we might want to do in invoking [map]. *)
adamc@137 599
adamc@137 600 Goal False.
adamc@137 601 let ls := map (nat * nat)%type ltac:(fun x => constr:(x, x)) (1 :: 2 :: 3 :: nil) in
adamc@137 602 pose ls.
adamc@137 603 (** [[
adamc@137 604
adamc@137 605 l := (1, 1) :: (2, 2) :: (3, 3) :: nil : list (nat * nat)
adamc@137 606 ============================
adamc@137 607 False
adamc@137 608 ]] *)
adamc@137 609 Abort.
adamc@141 610 (* end thide *)
adamc@137 611
adamc@138 612
adamc@139 613 (** * Recursive Proof Search *)
adamc@139 614
adamc@139 615 (** Deciding how to instantiate quantifiers is one of the hardest parts of automated first-order theorem proving. For a given problem, we can consider all possible bounded-length sequences of quantifier instantiations, applying only propositional reasoning at the end. This is probably a bad idea for almost all goals, but it makes for a nice example of recursive proof search procedures in Ltac.
adamc@139 616
adamc@139 617 We can consider the maximum "dependency chain" length for a first-order proof. We define the chain length for a hypothesis to be 0, and the chain length for an instantiation of a quantified fact to be one greater than the length for that fact. The tactic [inster n] is meant to try all possible proofs with chain length at most [n]. *)
adamc@139 618
adamc@141 619 (* begin thide *)
adamc@139 620 Ltac inster n :=
adamc@139 621 intuition;
adamc@139 622 match n with
adamc@139 623 | S ?n' =>
adamc@139 624 match goal with
adamc@139 625 | [ H : forall x : ?T, _, x : ?T |- _ ] => generalize (H x); inster n'
adamc@139 626 end
adamc@139 627 end.
adamc@141 628 (* end thide *)
adamc@139 629
adamc@139 630 (** [inster] begins by applying propositional simplification. Next, it checks if any chain length remains. If so, it tries all possible ways of instantiating quantified hypotheses with properly-typed local variables. It is critical to realize that, if the recursive call [inster n'] fails, then the [match goal] just seeks out another way of unifying its pattern against proof state. Thus, this small amount of code provides an elegant demonstration of how backtracking [match] enables exhaustive search.
adamc@139 631
adamc@139 632 We can verify the efficacy of [inster] with two short examples. The built-in [firstorder] tactic (with no extra arguments) is able to prove the first but not the second. *)
adamc@139 633
adamc@139 634 Section test_inster.
adamc@139 635 Variable A : Set.
adamc@139 636 Variables P Q : A -> Prop.
adamc@139 637 Variable f : A -> A.
adamc@139 638 Variable g : A -> A -> A.
adamc@139 639
adamc@139 640 Hypothesis H1 : forall x y, P (g x y) -> Q (f x).
adamc@139 641
adamc@139 642 Theorem test_inster : forall x y, P (g x y) -> Q (f x).
adamc@139 643 intros; inster 2.
adamc@139 644 Qed.
adamc@139 645
adamc@139 646 Hypothesis H3 : forall u v, P u /\ P v /\ u <> v -> P (g u v).
adamc@139 647 Hypothesis H4 : forall u, Q (f u) -> P u /\ P (f u).
adamc@139 648
adamc@139 649 Theorem test_inster2 : forall x y, x <> y -> P x -> Q (f y) -> Q (f x).
adamc@139 650 intros; inster 3.
adamc@139 651 Qed.
adamc@139 652 End test_inster.
adamc@139 653
adamc@140 654 (** The style employed in the definition of [inster] can seem very counterintuitive to functional programmers. Usually, functional programs accumulate state changes in explicit arguments to recursive functions. In Ltac, the state of the current subgoal is always implicit. Nonetheless, in contrast to general imperative programming, it is easy to undo any changes to this state, and indeed such "undoing" happens automatically at failures within [match]es. In this way, Ltac programming is similar to programming in Haskell with a stateful failure monad that supports a composition operator along the lines of the [first] tactical.
adamc@140 655
adamc@140 656 Functional programming purists may react indignantly to the suggestion of programming this way. Nonetheless, as with other kinds of "monadic programming," many problems are much simpler to solve with Ltac than they would be with explicit, pure proof manipulation in ML or Haskell. To demonstrate, we will write a basic simplification procedure for logical implications.
adamc@140 657
adamc@140 658 This procedure is inspired by one for separation logic, where conjuncts in formulas are thought of as "resources," such that we lose no completeness by "crossing out" equal conjuncts on the two sides of an implication. This process is complicated by the fact that, for reasons of modularity, our formulas can have arbitrary nested tree structure (branching at conjunctions) and may include existential quantifiers. It is helpful for the matching process to "go under" quantifiers and in fact decide how to instantiate existential quantifiers in the conclusion.
adamc@140 659
adamc@140 660 To distinguish the implications that our tactic handles from the implications that will show up as "plumbing" in various lemmas, we define a wrapper definition, a notation, and a tactic. *)
adamc@138 661
adamc@138 662 Definition imp (P1 P2 : Prop) := P1 -> P2.
adamc@140 663 Infix "-->" := imp (no associativity, at level 95).
adamc@140 664 Ltac imp := unfold imp; firstorder.
adamc@138 665
adamc@140 666 (** These lemmas about [imp] will be useful in the tactic that we will write. *)
adamc@138 667
adamc@138 668 Theorem and_True_prem : forall P Q,
adamc@138 669 (P /\ True --> Q)
adamc@138 670 -> (P --> Q).
adamc@138 671 imp.
adamc@138 672 Qed.
adamc@138 673
adamc@138 674 Theorem and_True_conc : forall P Q,
adamc@138 675 (P --> Q /\ True)
adamc@138 676 -> (P --> Q).
adamc@138 677 imp.
adamc@138 678 Qed.
adamc@138 679
adamc@138 680 Theorem assoc_prem1 : forall P Q R S,
adamc@138 681 (P /\ (Q /\ R) --> S)
adamc@138 682 -> ((P /\ Q) /\ R --> S).
adamc@138 683 imp.
adamc@138 684 Qed.
adamc@138 685
adamc@138 686 Theorem assoc_prem2 : forall P Q R S,
adamc@138 687 (Q /\ (P /\ R) --> S)
adamc@138 688 -> ((P /\ Q) /\ R --> S).
adamc@138 689 imp.
adamc@138 690 Qed.
adamc@138 691
adamc@138 692 Theorem comm_prem : forall P Q R,
adamc@138 693 (P /\ Q --> R)
adamc@138 694 -> (Q /\ P --> R).
adamc@138 695 imp.
adamc@138 696 Qed.
adamc@138 697
adamc@138 698 Theorem assoc_conc1 : forall P Q R S,
adamc@138 699 (S --> P /\ (Q /\ R))
adamc@138 700 -> (S --> (P /\ Q) /\ R).
adamc@138 701 imp.
adamc@138 702 Qed.
adamc@138 703
adamc@138 704 Theorem assoc_conc2 : forall P Q R S,
adamc@138 705 (S --> Q /\ (P /\ R))
adamc@138 706 -> (S --> (P /\ Q) /\ R).
adamc@138 707 imp.
adamc@138 708 Qed.
adamc@138 709
adamc@138 710 Theorem comm_conc : forall P Q R,
adamc@138 711 (R --> P /\ Q)
adamc@138 712 -> (R --> Q /\ P).
adamc@138 713 imp.
adamc@138 714 Qed.
adamc@138 715
adamc@140 716 (** The first order of business in crafting our [matcher] tactic will be auxiliary support for searching through formula trees. The [search_prem] tactic implements running its tactic argument [tac] on every subformula of an [imp] premise. As it traverses a tree, [search_prem] applies some of the above lemmas to rewrite the goal to bring different subformulas to the head of the goal. That is, for every subformula [P] of the implication premise, we want [P] to "have a turn," where the premise is rearranged into the form [P /\ Q] for some [Q]. The tactic [tac] should expect to see a goal in this form and focus its attention on the first conjunct of the premise. *)
adamc@140 717
adamc@141 718 (* begin thide *)
adamc@138 719 Ltac search_prem tac :=
adamc@138 720 let rec search P :=
adamc@138 721 tac
adamc@138 722 || (apply and_True_prem; tac)
adamc@138 723 || match P with
adamc@138 724 | ?P1 /\ ?P2 =>
adamc@138 725 (apply assoc_prem1; search P1)
adamc@138 726 || (apply assoc_prem2; search P2)
adamc@138 727 end
adamc@138 728 in match goal with
adamc@138 729 | [ |- ?P /\ _ --> _ ] => search P
adamc@138 730 | [ |- _ /\ ?P --> _ ] => apply comm_prem; search P
adamc@138 731 | [ |- _ --> _ ] => progress (tac || (apply and_True_prem; tac))
adamc@138 732 end.
adamc@138 733
adamc@140 734 (** To understand how [search_prem] works, we turn first to the final [match]. If the premise begins with a conjunction, we call the [search] procedure on each of the conjuncts, or only the first conjunct, if that already yields a case where [tac] does not fail. [search P] expects and maintains the invariant that the premise is of the form [P /\ Q] for some [Q]. We pass [P] explicitly as a kind of decreasing induction measure, to avoid looping forever when [tac] always fails. The second [match] case calls a commutativity lemma to realize this invariant, before passing control to [search]. The final [match] case tries applying [tac] directly and then, if that fails, changes the form of the goal by adding an extraneous [True] conjunct and calls [tac] again.
adamc@140 735
adamc@140 736 [search] itself tries the same tricks as in the last case of the final [match]. Additionally, if neither works, it checks if [P] is a conjunction. If so, it calls itself recursively on each conjunct, first applying associativity lemmas to maintain the goal-form invariant.
adamc@140 737
adamc@140 738 We will also want a dual function [search_conc], which does tree search through an [imp] conclusion. *)
adamc@140 739
adamc@138 740 Ltac search_conc tac :=
adamc@138 741 let rec search P :=
adamc@138 742 tac
adamc@138 743 || (apply and_True_conc; tac)
adamc@138 744 || match P with
adamc@138 745 | ?P1 /\ ?P2 =>
adamc@138 746 (apply assoc_conc1; search P1)
adamc@138 747 || (apply assoc_conc2; search P2)
adamc@138 748 end
adamc@138 749 in match goal with
adamc@138 750 | [ |- _ --> ?P /\ _ ] => search P
adamc@138 751 | [ |- _ --> _ /\ ?P ] => apply comm_conc; search P
adamc@138 752 | [ |- _ --> _ ] => progress (tac || (apply and_True_conc; tac))
adamc@138 753 end.
adamc@138 754
adamc@140 755 (** Now we can prove a number of lemmas that are suitable for application by our search tactics. A lemma that is meant to handle a premise should have the form [P /\ Q --> R] for some interesting [P], and a lemma that is meant to handle a conclusion should have the form [P --> Q /\ R] for some interesting [Q]. *)
adamc@140 756
adamc@138 757 Theorem False_prem : forall P Q,
adamc@138 758 False /\ P --> Q.
adamc@138 759 imp.
adamc@138 760 Qed.
adamc@138 761
adamc@138 762 Theorem True_conc : forall P Q : Prop,
adamc@138 763 (P --> Q)
adamc@138 764 -> (P --> True /\ Q).
adamc@138 765 imp.
adamc@138 766 Qed.
adamc@138 767
adamc@138 768 Theorem Match : forall P Q R : Prop,
adamc@138 769 (Q --> R)
adamc@138 770 -> (P /\ Q --> P /\ R).
adamc@138 771 imp.
adamc@138 772 Qed.
adamc@138 773
adamc@138 774 Theorem ex_prem : forall (T : Type) (P : T -> Prop) (Q R : Prop),
adamc@138 775 (forall x, P x /\ Q --> R)
adamc@138 776 -> (ex P /\ Q --> R).
adamc@138 777 imp.
adamc@138 778 Qed.
adamc@138 779
adamc@138 780 Theorem ex_conc : forall (T : Type) (P : T -> Prop) (Q R : Prop) x,
adamc@138 781 (Q --> P x /\ R)
adamc@138 782 -> (Q --> ex P /\ R).
adamc@138 783 imp.
adamc@138 784 Qed.
adamc@138 785
adamc@140 786 (** We will also want a "base case" lemma for finishing proofs where cancelation has removed every constituent of the conclusion. *)
adamc@140 787
adamc@138 788 Theorem imp_True : forall P,
adamc@138 789 P --> True.
adamc@138 790 imp.
adamc@138 791 Qed.
adamc@138 792
adamc@140 793 (** Our final [matcher] tactic is now straightforward. First, we [intros] all variables into scope. Then we attempt simple premise simplifications, finishing the proof upon finding [False] and eliminating any existential quantifiers that we find. After that, we search through the conclusion. We remove [True] conjuncts, remove existential quantifiers by introducing unification variables for their bound variables, and search for matching premises to cancel. Finally, when no more progress is made, we see if the goal has become trivial and can be solved by [imp_True]. *)
adamc@140 794
adamc@138 795 Ltac matcher :=
adamc@138 796 intros;
adamc@204 797 repeat search_prem ltac:(simple apply False_prem || (simple apply ex_prem; intro));
adamc@204 798 repeat search_conc ltac:(simple apply True_conc || simple eapply ex_conc
adamc@204 799 || search_prem ltac:(simple apply Match));
adamc@204 800 try simple apply imp_True.
adamc@141 801 (* end thide *)
adamc@140 802
adamc@140 803 (** Our tactic succeeds at proving a simple example. *)
adamc@138 804
adamc@138 805 Theorem t2 : forall P Q : Prop,
adamc@138 806 Q /\ (P /\ False) /\ P --> P /\ Q.
adamc@138 807 matcher.
adamc@138 808 Qed.
adamc@138 809
adamc@140 810 (** In the generated proof, we find a trace of the workings of the search tactics. *)
adamc@140 811
adamc@140 812 Print t2.
adamc@140 813 (** [[
adamc@140 814
adamc@140 815 t2 =
adamc@140 816 fun P Q : Prop =>
adamc@140 817 comm_prem (assoc_prem1 (assoc_prem2 (False_prem (P:=P /\ P /\ Q) (P /\ Q))))
adamc@140 818 : forall P Q : Prop, Q /\ (P /\ False) /\ P --> P /\ Q
adamc@140 819 ]] *)
adamc@140 820
adamc@140 821 (** We can also see that [matcher] is well-suited for cases where some human intervention is needed after the automation finishes. *)
adamc@140 822
adamc@138 823 Theorem t3 : forall P Q R : Prop,
adamc@138 824 P /\ Q --> Q /\ R /\ P.
adamc@138 825 matcher.
adamc@140 826 (** [[
adamc@140 827
adamc@140 828 ============================
adamc@140 829 True --> R
adamc@140 830 ]]
adamc@140 831
adamc@140 832 [matcher] canceled those conjuncts that it was able to cancel, leaving a simplified subgoal for us, much as [intuition] does. *)
adamc@138 833 Abort.
adamc@138 834
adamc@140 835 (** [matcher] even succeeds at guessing quantifier instantiations. It is the unification that occurs in uses of the [Match] lemma that does the real work here. *)
adamc@140 836
adamc@138 837 Theorem t4 : forall (P : nat -> Prop) Q, (exists x, P x /\ Q) --> Q /\ (exists x, P x).
adamc@138 838 matcher.
adamc@138 839 Qed.
adamc@138 840
adamc@140 841 Print t4.
adamc@140 842
adamc@140 843 (** [[
adamc@140 844
adamc@140 845 t4 =
adamc@140 846 fun (P : nat -> Prop) (Q : Prop) =>
adamc@140 847 and_True_prem
adamc@140 848 (ex_prem (P:=fun x : nat => P x /\ Q)
adamc@140 849 (fun x : nat =>
adamc@140 850 assoc_prem2
adamc@140 851 (Match (P:=Q)
adamc@140 852 (and_True_conc
adamc@140 853 (ex_conc (fun x0 : nat => P x0) x
adamc@140 854 (Match (P:=P x) (imp_True (P:=True))))))))
adamc@140 855 : forall (P : nat -> Prop) (Q : Prop),
adamc@140 856 (exists x : nat, P x /\ Q) --> Q /\ (exists x : nat, P x)
adamc@140 857 ]] *)