Mercurial > cpdt > repo

annotate src/Subset.v @ 242:5a32784e30f3

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Prose for Modules section
author Adam Chlipala <adamc@hcoop.net>
date Wed, 09 Dec 2009 13:07:31 -0500
parents c4b1c0de7af9
children aa3c054afce0
rev   line source
adamc@213 1 (* Copyright (c) 2008-2009, Adam Chlipala
adamc@70 2 *
adamc@70 3 * This work is licensed under a
adamc@70 4 * Creative Commons Attribution-Noncommercial-No Derivative Works 3.0
adamc@70 5 * Unported License.
adamc@70 6 * The license text is available at:
adamc@70 7 * http://creativecommons.org/licenses/by-nc-nd/3.0/
adamc@70 8 *)
adamc@70 9
adamc@70 10 (* begin hide *)
adamc@70 11 Require Import List.
adamc@70 12
adamc@70 13 Require Import Tactics.
adamc@70 14
adamc@70 15 Set Implicit Arguments.
adamc@70 16 (* end hide *)
adamc@70 17
adamc@70 18
adamc@74 19 (** %\part{Programming with Dependent Types}
adamc@74 20
adamc@74 21 \chapter{Subset Types and Variations}% *)
adamc@70 22
adamc@70 23 (** So far, we have seen many examples of what we might call "classical program verification." We write programs, write their specifications, and then prove that the programs satisfy their specifications. The programs that we have written in Coq have been normal functional programs that we could just as well have written in Haskell or ML. In this chapter, we start investigating uses of %\textit{%#<i>#dependent types#</i>#%}% to integrate programming, specification, and proving into a single phase. *)
adamc@70 24
adamc@70 25
adamc@70 26 (** * Introducing Subset Types *)
adamc@70 27
adamc@70 28 (** Let us consider several ways of implementing the natural number predecessor function. We start by displaying the definition from the standard library: *)
adamc@70 29
adamc@70 30 Print pred.
adamc@212 31 (** %\vspace{-.15in}% [[
adamc@70 32 pred = fun n : nat => match n with
adamc@70 33 | 0 => 0
adamc@70 34 | S u => u
adamc@70 35 end
adamc@70 36 : nat -> nat
adamc@212 37
adamc@212 38 ]]
adamc@70 39
adamc@212 40 We can use a new command, [Extraction], to produce an OCaml version of this function. *)
adamc@70 41
adamc@70 42 Extraction pred.
adamc@70 43
adamc@70 44 (** %\begin{verbatim}
adamc@70 45 (** val pred : nat -> nat **)
adamc@70 46
adamc@70 47 let pred = function
adamc@70 48 | O -> O
adamc@70 49 | S u -> u
adamc@70 50 \end{verbatim}%
adamc@70 51
adamc@70 52 #<pre>
adamc@70 53 (** val pred : nat -> nat **)
adamc@70 54
adamc@70 55 let pred = function
adamc@70 56 | O -> O
adamc@70 57 | S u -> u
adamc@70 58 </pre># *)
adamc@70 59
adamc@70 60 (** Returning 0 as the predecessor of 0 can come across as somewhat of a hack. In some situations, we might like to be sure that we never try to take the predecessor of 0. We can enforce this by giving [pred] a stronger, dependent type. *)
adamc@70 61
adamc@70 62 Lemma zgtz : 0 > 0 -> False.
adamc@70 63 crush.
adamc@70 64 Qed.
adamc@70 65
adamc@70 66 Definition pred_strong1 (n : nat) : n > 0 -> nat :=
adamc@212 67 match n with
adamc@70 68 | O => fun pf : 0 > 0 => match zgtz pf with end
adamc@70 69 | S n' => fun _ => n'
adamc@70 70 end.
adamc@70 71
adamc@70 72 (** We expand the type of [pred] to include a %\textit{%#<i>#proof#</i>#%}% that its argument [n] is greater than 0. When [n] is 0, we use the proof to derive a contradiction, which we can use to build a value of any type via a vacuous pattern match. When [n] is a successor, we have no need for the proof and just return the answer. The proof argument can be said to have a %\textit{%#<i>#dependent#</i>#%}% type, because its type depends on the %\textit{%#<i>#value#</i>#%}% of the argument [n].
adamc@70 73
adamc@212 74 One aspects in particular of the definition of [pred_strong1] that may be surprising. We took advantage of [Definition]'s syntactic sugar for defining function arguments in the case of [n], but we bound the proofs later with explicit [fun] expressions. Let us see what happens if we write this function in the way that at first seems most natural.
adamc@70 75
adamc@212 76 [[
adamc@70 77 Definition pred_strong1' (n : nat) (pf : n > 0) : nat :=
adamc@70 78 match n with
adamc@70 79 | O => match zgtz pf with end
adamc@70 80 | S n' => n'
adamc@70 81 end.
adamc@70 82
adamc@70 83 Error: In environment
adamc@70 84 n : nat
adamc@70 85 pf : n > 0
adamc@70 86 The term "pf" has type "n > 0" while it is expected to have type
adamc@70 87 "0 > 0"
adamc@212 88
adamc@70 89 ]]
adamc@70 90
adamc@212 91 The term [zgtz pf] fails to type-check. Somehow the type checker has failed to take into account information that follows from which [match] branch that term appears in. The problem is that, by default, [match] does not let us use such implied information. To get refined typing, we must always rely on [match] annotations, either written explicitly or inferred.
adamc@70 92
adamc@70 93 In this case, we must use a [return] annotation to declare the relationship between the %\textit{%#<i>#value#</i>#%}% of the [match] discriminee and the %\textit{%#<i>#type#</i>#%}% of the result. There is no annotation that lets us declare a relationship between the discriminee and the type of a variable that is already in scope; hence, we delay the binding of [pf], so that we can use the [return] annotation to express the needed relationship.
adamc@70 94
adamc@212 95 We are lucky that Coq's heuristics infer the [return] clause (specifically, [return n > 0 -> nat]) for us in this case. In general, however, the inference problem is undecidable. The known undecidable problem of %\textit{%#<i>#higher-order unification#</i>#%}% reduces to the [match] type inference problem. Over time, Coq is enhanced with more and more heuristics to get around this problem, but there must always exist [match]es whose types Coq cannot infer without annotations.
adamc@70 96
adamc@70 97 Let us now take a look at the OCaml code Coq generates for [pred_strong1]. *)
adamc@70 98
adamc@70 99 Extraction pred_strong1.
adamc@70 100
adamc@70 101 (** %\begin{verbatim}
adamc@70 102 (** val pred_strong1 : nat -> nat **)
adamc@70 103
adamc@70 104 let pred_strong1 = function
adamc@70 105 | O -> assert false (* absurd case *)
adamc@70 106 | S n' -> n'
adamc@70 107 \end{verbatim}%
adamc@70 108
adamc@70 109 #<pre>
adamc@70 110 (** val pred_strong1 : nat -> nat **)
adamc@70 111
adamc@70 112 let pred_strong1 = function
adamc@70 113 | O -> assert false (* absurd case *)
adamc@70 114 | S n' -> n'
adamc@70 115 </pre># *)
adamc@70 116
adamc@70 117 (** The proof argument has disappeared! We get exactly the OCaml code we would have written manually. This is our first demonstration of the main technically interesting feature of Coq program extraction: program components of type [Prop] are erased systematically.
adamc@70 118
adamc@70 119 We can reimplement our dependently-typed [pred] based on %\textit{%#<i>#subset types#</i>#%}%, defined in the standard library with the type family [sig]. *)
adamc@70 120
adamc@70 121 Print sig.
adamc@212 122 (** %\vspace{-.15in}% [[
adamc@70 123 Inductive sig (A : Type) (P : A -> Prop) : Type :=
adamc@70 124 exist : forall x : A, P x -> sig P
adamc@70 125 For sig: Argument A is implicit
adamc@70 126 For exist: Argument A is implicit
adamc@212 127
adamc@70 128 ]]
adamc@70 129
adamc@70 130 [sig] is a Curry-Howard twin of [ex], except that [sig] is in [Type], while [ex] is in [Prop]. That means that [sig] values can survive extraction, while [ex] proofs will always be erased. The actual details of extraction of [sig]s are more subtle, as we will see shortly.
adamc@70 131
adamc@70 132 We rewrite [pred_strong1], using some syntactic sugar for subset types. *)
adamc@70 133
adamc@70 134 Locate "{ _ : _ | _ }".
adamc@212 135 (** %\vspace{-.15in}% [[
adamc@70 136 Notation Scope
adamc@70 137 "{ x : A | P }" := sig (fun x : A => P)
adamc@70 138 : type_scope
adamc@70 139 (default interpretation)
adamc@70 140 ]] *)
adamc@70 141
adamc@70 142 Definition pred_strong2 (s : {n : nat | n > 0}) : nat :=
adamc@70 143 match s with
adamc@70 144 | exist O pf => match zgtz pf with end
adamc@70 145 | exist (S n') _ => n'
adamc@70 146 end.
adamc@70 147
adamc@70 148 Extraction pred_strong2.
adamc@70 149
adamc@70 150 (** %\begin{verbatim}
adamc@70 151 (** val pred_strong2 : nat -> nat **)
adamc@70 152
adamc@70 153 let pred_strong2 = function
adamc@70 154 | O -> assert false (* absurd case *)
adamc@70 155 | S n' -> n'
adamc@70 156 \end{verbatim}%
adamc@70 157
adamc@70 158 #<pre>
adamc@70 159 (** val pred_strong2 : nat -> nat **)
adamc@70 160
adamc@70 161 let pred_strong2 = function
adamc@70 162 | O -> assert false (* absurd case *)
adamc@70 163 | S n' -> n'
adamc@70 164 </pre>#
adamc@70 165
adamc@70 166 We arrive at the same OCaml code as was extracted from [pred_strong1], which may seem surprising at first. The reason is that a value of [sig] is a pair of two pieces, a value and a proof about it. Extraction erases the proof, which reduces the constructor [exist] of [sig] to taking just a single argument. An optimization eliminates uses of datatypes with single constructors taking single arguments, and we arrive back where we started.
adamc@70 167
adamc@70 168 We can continue on in the process of refining [pred]'s type. Let us change its result type to capture that the output is really the predecessor of the input. *)
adamc@70 169
adamc@70 170 Definition pred_strong3 (s : {n : nat | n > 0}) : {m : nat | proj1_sig s = S m} :=
adamc@70 171 match s return {m : nat | proj1_sig s = S m} with
adamc@70 172 | exist 0 pf => match zgtz pf with end
adamc@212 173 | exist (S n') pf => exist _ n' (refl_equal _)
adamc@70 174 end.
adamc@70 175
adamc@212 176 (** The function [proj1_sig] extracts the base value from a subset type. Besides the use of that function, the only other new thing is the use of the [exist] constructor to build a new [sig] value, and the details of how to do that follow from the output of our earlier [Print] command. It also turns out that we need to include an explicit [return] clause here, since Coq's heuristics are not smart enough to propagate the result type that we wrote earlier.
adamc@70 177
adamc@70 178 By now, the reader is probably ready to believe that the new [pred_strong] leads to the same OCaml code as we have seen several times so far, and Coq does not disappoint. *)
adamc@70 179
adamc@70 180 Extraction pred_strong3.
adamc@70 181
adamc@70 182 (** %\begin{verbatim}
adamc@70 183 (** val pred_strong3 : nat -> nat **)
adamc@70 184
adamc@70 185 let pred_strong3 = function
adamc@70 186 | O -> assert false (* absurd case *)
adamc@70 187 | S n' -> n'
adamc@70 188 \end{verbatim}%
adamc@70 189
adamc@70 190 #<pre>
adamc@70 191 (** val pred_strong3 : nat -> nat **)
adamc@70 192
adamc@70 193 let pred_strong3 = function
adamc@70 194 | O -> assert false (* absurd case *)
adamc@70 195 | S n' -> n'
adamc@70 196 </pre>#
adamc@70 197
adamc@70 198 We have managed to reach a type that is, in a formal sense, the most expressive possible for [pred]. Any other implementation of the same type must have the same input-output behavior. However, there is still room for improvement in making this kind of code easier to write. Here is a version that takes advantage of tactic-based theorem proving. We switch back to passing a separate proof argument instead of using a subset type for the function's input, because this leads to cleaner code. *)
adamc@70 199
adamc@70 200 Definition pred_strong4 (n : nat) : n > 0 -> {m : nat | n = S m}.
adamc@70 201 refine (fun n =>
adamc@212 202 match n with
adamc@70 203 | O => fun _ => False_rec _ _
adamc@70 204 | S n' => fun _ => exist _ n' _
adamc@70 205 end).
adamc@212 206
adamc@77 207 (* begin thide *)
adamc@70 208 (** We build [pred_strong4] using tactic-based proving, beginning with a [Definition] command that ends in a period before a definition is given. Such a command enters the interactive proving mode, with the type given for the new identifier as our proof goal. We do most of the work with the [refine] tactic, to which we pass a partial "proof" of the type we are trying to prove. There may be some pieces left to fill in, indicated by underscores. Any underscore that Coq cannot reconstruct with type inference is added as a proof subgoal. In this case, we have two subgoals:
adamc@70 209
adamc@70 210 [[
adamc@70 211 2 subgoals
adamc@70 212
adamc@70 213 n : nat
adamc@70 214 _ : 0 > 0
adamc@70 215 ============================
adamc@70 216 False
adamc@70 217
adamc@70 218 subgoal 2 is:
adamc@70 219 S n' = S n'
adamc@212 220
adamc@70 221 ]]
adamc@70 222
adamc@70 223 We can see that the first subgoal comes from the second underscore passed to [False_rec], and the second subgoal comes from the second underscore passed to [exist]. In the first case, we see that, though we bound the proof variable with an underscore, it is still available in our proof context. It is hard to refer to underscore-named variables in manual proofs, but automation makes short work of them. Both subgoals are easy to discharge that way, so let us back up and ask to prove all subgoals automatically. *)
adamc@70 224
adamc@70 225 Undo.
adamc@70 226 refine (fun n =>
adamc@212 227 match n with
adamc@70 228 | O => fun _ => False_rec _ _
adamc@70 229 | S n' => fun _ => exist _ n' _
adamc@70 230 end); crush.
adamc@77 231 (* end thide *)
adamc@70 232 Defined.
adamc@70 233
adamc@76 234 (** We end the "proof" with [Defined] instead of [Qed], so that the definition we constructed remains visible. This contrasts to the case of ending a proof with [Qed], where the details of the proof are hidden afterward. Let us see what our proof script constructed. *)
adamc@70 235
adamc@70 236 Print pred_strong4.
adamc@212 237 (** %\vspace{-.15in}% [[
adamc@70 238 pred_strong4 =
adamc@70 239 fun n : nat =>
adamc@70 240 match n as n0 return (n0 > 0 -> {m : nat | n0 = S m}) with
adamc@70 241 | 0 =>
adamc@70 242 fun _ : 0 > 0 =>
adamc@70 243 False_rec {m : nat | 0 = S m}
adamc@70 244 (Bool.diff_false_true
adamc@70 245 (Bool.absurd_eq_true false
adamc@70 246 (Bool.diff_false_true
adamc@70 247 (Bool.absurd_eq_true false (pred_strong4_subproof n _)))))
adamc@70 248 | S n' =>
adamc@70 249 fun _ : S n' > 0 =>
adamc@70 250 exist (fun m : nat => S n' = S m) n' (refl_equal (S n'))
adamc@70 251 end
adamc@70 252 : forall n : nat, n > 0 -> {m : nat | n = S m}
adamc@212 253
adamc@70 254 ]]
adamc@70 255
adamc@70 256 We see the code we entered, with some proofs filled in. The first proof obligation, the second argument to [False_rec], is filled in with a nasty-looking proof term that we can be glad we did not enter by hand. The second proof obligation is a simple reflexivity proof.
adamc@70 257
adamc@70 258 We are almost done with the ideal implementation of dependent predecessor. We can use Coq's syntax extension facility to arrive at code with almost no complexity beyond a Haskell or ML program with a complete specification in a comment. *)
adamc@70 259
adamc@70 260 Notation "!" := (False_rec _ _).
adamc@70 261 Notation "[ e ]" := (exist _ e _).
adamc@70 262
adamc@70 263 Definition pred_strong5 (n : nat) : n > 0 -> {m : nat | n = S m}.
adamc@70 264 refine (fun n =>
adamc@212 265 match n with
adamc@70 266 | O => fun _ => !
adamc@70 267 | S n' => fun _ => [n']
adamc@70 268 end); crush.
adamc@70 269 Defined.
adamc@71 270
adamc@212 271 (** One other alternative is worth demonstrating. Recent Coq versions include a facility called [Program] that streamlines this style of definition. Here is a complete implementation using [Program]. *)
adamc@212 272
adamc@212 273 Obligation Tactic := crush.
adamc@212 274
adamc@212 275 Program Definition pred_strong6 (n : nat) (_ : n > 0) : {m : nat | n = S m} :=
adamc@212 276 match n with
adamc@212 277 | O => _
adamc@212 278 | S n' => n'
adamc@212 279 end.
adamc@212 280
adamc@212 281 (** Printing the resulting definition of [pred_strong6] yields a term very similar to what we built with [refine]. [Program] can save time in writing programs that use subset types. Nonetheless, [refine] is often just as effective, and [refine] gives you more control over the form the final term takes, which can be useful when you want to prove additional theorems about your definition. [Program] will sometimes insert type casts that can complicate theorem-proving. *)
adamc@212 282
adamc@71 283
adamc@71 284 (** * Decidable Proposition Types *)
adamc@71 285
adamc@71 286 (** There is another type in the standard library which captures the idea of program values that indicate which of two propositions is true. *)
adamc@71 287
adamc@71 288 Print sumbool.
adamc@212 289 (** %\vspace{-.15in}% [[
adamc@71 290 Inductive sumbool (A : Prop) (B : Prop) : Set :=
adamc@71 291 left : A -> {A} + {B} | right : B -> {A} + {B}
adamc@71 292 For left: Argument A is implicit
adamc@71 293 For right: Argument B is implicit
adamc@212 294
adamc@212 295 ]]
adamc@71 296
adamc@212 297 We can define some notations to make working with [sumbool] more convenient. *)
adamc@71 298
adamc@71 299 Notation "'Yes'" := (left _ _).
adamc@71 300 Notation "'No'" := (right _ _).
adamc@71 301 Notation "'Reduce' x" := (if x then Yes else No) (at level 50).
adamc@71 302
adamc@71 303 (** The [Reduce] notation is notable because it demonstrates how [if] is overloaded in Coq. The [if] form actually works when the test expression has any two-constructor inductive type. Moreover, in the [then] and [else] branches, the appropriate constructor arguments are bound. This is important when working with [sumbool]s, when we want to have the proof stored in the test expression available when proving the proof obligations generated in the appropriate branch.
adamc@71 304
adamc@71 305 Now we can write [eq_nat_dec], which compares two natural numbers, returning either a proof of their equality or a proof of their inequality. *)
adamc@71 306
adamc@71 307 Definition eq_nat_dec (n m : nat) : {n = m} + {n <> m}.
adamc@212 308 refine (fix f (n m : nat) : {n = m} + {n <> m} :=
adamc@212 309 match n, m with
adamc@71 310 | O, O => Yes
adamc@71 311 | S n', S m' => Reduce (f n' m')
adamc@71 312 | _, _ => No
adamc@71 313 end); congruence.
adamc@71 314 Defined.
adamc@71 315
adamc@71 316 (** Our definition extracts to reasonable OCaml code. *)
adamc@71 317
adamc@71 318 Extraction eq_nat_dec.
adamc@71 319
adamc@71 320 (** %\begin{verbatim}
adamc@71 321 (** val eq_nat_dec : nat -> nat -> sumbool **)
adamc@71 322
adamc@71 323 let rec eq_nat_dec n m =
adamc@71 324 match n with
adamc@71 325 | O -> (match m with
adamc@71 326 | O -> Left
adamc@71 327 | S n0 -> Right)
adamc@71 328 | S n' -> (match m with
adamc@71 329 | O -> Right
adamc@71 330 | S m' -> eq_nat_dec n' m')
adamc@71 331 \end{verbatim}%
adamc@71 332
adamc@71 333 #<pre>
adamc@71 334 (** val eq_nat_dec : nat -> nat -> sumbool **)
adamc@71 335
adamc@71 336 let rec eq_nat_dec n m =
adamc@71 337 match n with
adamc@71 338 | O -> (match m with
adamc@71 339 | O -> Left
adamc@71 340 | S n0 -> Right)
adamc@71 341 | S n' -> (match m with
adamc@71 342 | O -> Right
adamc@71 343 | S m' -> eq_nat_dec n' m')
adamc@71 344 </pre>#
adamc@71 345
adamc@71 346 Proving this kind of decidable equality result is so common that Coq comes with a tactic for automating it. *)
adamc@71 347
adamc@71 348 Definition eq_nat_dec' (n m : nat) : {n = m} + {n <> m}.
adamc@71 349 decide equality.
adamc@71 350 Defined.
adamc@71 351
adamc@71 352 (** Curious readers can verify that the [decide equality] version extracts to the same OCaml code as our more manual version does. That OCaml code had one undesirable property, which is that it uses %\texttt{%#<tt>#Left#</tt>#%}% and %\texttt{%#<tt>#Right#</tt>#%}% constructors instead of the boolean values built into OCaml. We can fix this, by using Coq's facility for mapping Coq inductive types to OCaml variant types. *)
adamc@71 353
adamc@71 354 Extract Inductive sumbool => "bool" ["true" "false"].
adamc@71 355 Extraction eq_nat_dec'.
adamc@71 356
adamc@71 357 (** %\begin{verbatim}
adamc@71 358 (** val eq_nat_dec' : nat -> nat -> bool **)
adamc@71 359
adamc@71 360 let rec eq_nat_dec' n m0 =
adamc@71 361 match n with
adamc@71 362 | O -> (match m0 with
adamc@71 363 | O -> true
adamc@71 364 | S n0 -> false)
adamc@71 365 | S n0 -> (match m0 with
adamc@71 366 | O -> false
adamc@71 367 | S n1 -> eq_nat_dec' n0 n1)
adamc@71 368 \end{verbatim}%
adamc@71 369
adamc@71 370 #<pre>
adamc@71 371 (** val eq_nat_dec' : nat -> nat -> bool **)
adamc@71 372
adamc@71 373 let rec eq_nat_dec' n m0 =
adamc@71 374 match n with
adamc@71 375 | O -> (match m0 with
adamc@71 376 | O -> true
adamc@71 377 | S n0 -> false)
adamc@71 378 | S n0 -> (match m0 with
adamc@71 379 | O -> false
adamc@71 380 | S n1 -> eq_nat_dec' n0 n1)
adamc@71 381 </pre># *)
adamc@72 382
adamc@72 383 (** %\smallskip%
adamc@72 384
adamc@72 385 We can build "smart" versions of the usual boolean operators and put them to good use in certified programming. For instance, here is a [sumbool] version of boolean "or." *)
adamc@72 386
adamc@77 387 (* begin thide *)
adamc@204 388 Notation "x || y" := (if x then Yes else Reduce y).
adamc@72 389
adamc@72 390 (** Let us use it for building a function that decides list membership. We need to assume the existence of an equality decision procedure for the type of list elements. *)
adamc@72 391
adamc@72 392 Section In_dec.
adamc@72 393 Variable A : Set.
adamc@72 394 Variable A_eq_dec : forall x y : A, {x = y} + {x <> y}.
adamc@72 395
adamc@72 396 (** The final function is easy to write using the techniques we have developed so far. *)
adamc@72 397
adamc@212 398 Definition In_dec : forall (x : A) (ls : list A), {In x ls} + {~ In x ls}.
adamc@212 399 refine (fix f (x : A) (ls : list A) : {In x ls} + {~ In x ls} :=
adamc@212 400 match ls with
adamc@72 401 | nil => No
adamc@72 402 | x' :: ls' => A_eq_dec x x' || f x ls'
adamc@72 403 end); crush.
adamc@72 404 Qed.
adamc@72 405 End In_dec.
adamc@72 406
adamc@72 407 (** [In_dec] has a reasonable extraction to OCaml. *)
adamc@72 408
adamc@72 409 Extraction In_dec.
adamc@77 410 (* end thide *)
adamc@72 411
adamc@72 412 (** %\begin{verbatim}
adamc@72 413 (** val in_dec : ('a1 -> 'a1 -> bool) -> 'a1 -> 'a1 list -> bool **)
adamc@72 414
adamc@72 415 let rec in_dec a_eq_dec x = function
adamc@72 416 | Nil -> false
adamc@72 417 | Cons (x', ls') ->
adamc@72 418 (match a_eq_dec x x' with
adamc@72 419 | true -> true
adamc@72 420 | false -> in_dec a_eq_dec x ls')
adamc@72 421 \end{verbatim}%
adamc@72 422
adamc@72 423 #<pre>
adamc@72 424 (** val in_dec : ('a1 -> 'a1 -> bool) -> 'a1 -> 'a1 list -> bool **)
adamc@72 425
adamc@72 426 let rec in_dec a_eq_dec x = function
adamc@72 427 | Nil -> false
adamc@72 428 | Cons (x', ls') ->
adamc@72 429 (match a_eq_dec x x' with
adamc@72 430 | true -> true
adamc@72 431 | false -> in_dec a_eq_dec x ls')
adamc@72 432 </pre># *)
adamc@72 433
adamc@72 434
adamc@72 435 (** * Partial Subset Types *)
adamc@72 436
adamc@73 437 (** Our final implementation of dependent predecessor used a very specific argument type to ensure that execution could always complete normally. Sometimes we want to allow execution to fail, and we want a more principled way of signaling that than returning a default value, as [pred] does for [0]. One approach is to define this type family [maybe], which is a version of [sig] that allows obligation-free failure. *)
adamc@73 438
adamc@89 439 Inductive maybe (A : Set) (P : A -> Prop) : Set :=
adamc@72 440 | Unknown : maybe P
adamc@72 441 | Found : forall x : A, P x -> maybe P.
adamc@72 442
adamc@73 443 (** We can define some new notations, analogous to those we defined for subset types. *)
adamc@73 444
adamc@72 445 Notation "{{ x | P }}" := (maybe (fun x => P)).
adamc@72 446 Notation "??" := (Unknown _).
adamc@72 447 Notation "[[ x ]]" := (Found _ x _).
adamc@72 448
adamc@73 449 (** Now our next version of [pred] is trivial to write. *)
adamc@73 450
adamc@212 451 Definition pred_strong7 (n : nat) : {{m | n = S m}}.
adamc@73 452 refine (fun n =>
adamc@212 453 match n with
adamc@73 454 | O => ??
adamc@73 455 | S n' => [[n']]
adamc@73 456 end); trivial.
adamc@73 457 Defined.
adamc@73 458
adamc@212 459 (** Because we used [maybe], one valid implementation of the type we gave [pred_strong7] would return [??] in every case. We can strengthen the type to rule out such vacuous implementations, and the type family [sumor] from the standard library provides the easiest starting point. For type [A] and proposition [B], [A + {B}] desugars to [sumor A B], whose values are either values of [A] or proofs of [B]. *)
adamc@73 460
adamc@73 461 Print sumor.
adamc@212 462 (** %\vspace{-.15in}% [[
adamc@73 463 Inductive sumor (A : Type) (B : Prop) : Type :=
adamc@73 464 inleft : A -> A + {B} | inright : B -> A + {B}
adamc@73 465 For inleft: Argument A is implicit
adamc@73 466 For inright: Argument B is implicit
adamc@73 467 ]] *)
adamc@73 468
adamc@73 469 (** We add notations for easy use of the [sumor] constructors. The second notation is specialized to [sumor]s whose [A] parameters are instantiated with regular subset types, since this is how we will use [sumor] below. *)
adamc@73 470
adamc@73 471 Notation "!!" := (inright _ _).
adamc@73 472 Notation "[[[ x ]]]" := (inleft _ [x]).
adamc@73 473
adamc@73 474 (** Now we are ready to give the final version of possibly-failing predecessor. The [sumor]-based type that we use is maximally expressive; any implementation of the type has the same input-output behavior. *)
adamc@73 475
adamc@212 476 Definition pred_strong8 (n : nat) : {m : nat | n = S m} + {n = 0}.
adamc@73 477 refine (fun n =>
adamc@212 478 match n with
adamc@73 479 | O => !!
adamc@73 480 | S n' => [[[n']]]
adamc@73 481 end); trivial.
adamc@73 482 Defined.
adamc@73 483
adamc@73 484
adamc@73 485 (** * Monadic Notations *)
adamc@73 486
adamc@73 487 (** We can treat [maybe] like a monad, in the same way that the Haskell [Maybe] type is interpreted as a failure monad. Our [maybe] has the wrong type to be a literal monad, but a "bind"-like notation will still be helpful. *)
adamc@73 488
adamc@72 489 Notation "x <- e1 ; e2" := (match e1 with
adamc@72 490 | Unknown => ??
adamc@72 491 | Found x _ => e2
adamc@72 492 end)
adamc@72 493 (right associativity, at level 60).
adamc@72 494
adamc@73 495 (** The meaning of [x <- e1; e2] is: First run [e1]. If it fails to find an answer, then announce failure for our derived computation, too. If [e1] %\textit{%#<i>#does#</i>#%}% find an answer, pass that answer on to [e2] to find the final result. The variable [x] can be considered bound in [e2].
adamc@73 496
adamc@73 497 This notation is very helpful for composing richly-typed procedures. For instance, here is a very simple implementation of a function to take the predecessors of two naturals at once. *)
adamc@73 498
adamc@73 499 Definition doublePred (n1 n2 : nat) : {{p | n1 = S (fst p) /\ n2 = S (snd p)}}.
adamc@73 500 refine (fun n1 n2 =>
adamc@212 501 m1 <- pred_strong7 n1;
adamc@212 502 m2 <- pred_strong7 n2;
adamc@73 503 [[(m1, m2)]]); tauto.
adamc@73 504 Defined.
adamc@73 505
adamc@73 506 (** We can build a [sumor] version of the "bind" notation and use it to write a similarly straightforward version of this function. *)
adamc@73 507
adamc@73 508 (** printing <-- $\longleftarrow$ *)
adamc@73 509
adamc@73 510 Notation "x <-- e1 ; e2" := (match e1 with
adamc@73 511 | inright _ => !!
adamc@73 512 | inleft (exist x _) => e2
adamc@73 513 end)
adamc@73 514 (right associativity, at level 60).
adamc@73 515
adamc@73 516 (** printing * $\times$ *)
adamc@73 517
adamc@212 518 Definition doublePred' (n1 n2 : nat)
adamc@212 519 : {p : nat * nat | n1 = S (fst p) /\ n2 = S (snd p)}
adamc@73 520 + {n1 = 0 \/ n2 = 0}.
adamc@73 521 refine (fun n1 n2 =>
adamc@212 522 m1 <-- pred_strong8 n1;
adamc@212 523 m2 <-- pred_strong8 n2;
adamc@73 524 [[[(m1, m2)]]]); tauto.
adamc@73 525 Defined.
adamc@72 526
adamc@72 527
adamc@72 528 (** * A Type-Checking Example *)
adamc@72 529
adamc@75 530 (** We can apply these specification types to build a certified type-checker for a simple expression language. *)
adamc@75 531
adamc@72 532 Inductive exp : Set :=
adamc@72 533 | Nat : nat -> exp
adamc@72 534 | Plus : exp -> exp -> exp
adamc@72 535 | Bool : bool -> exp
adamc@72 536 | And : exp -> exp -> exp.
adamc@72 537
adamc@75 538 (** We define a simple language of types and its typing rules, in the style introduced in Chapter 4. *)
adamc@75 539
adamc@72 540 Inductive type : Set := TNat | TBool.
adamc@72 541
adamc@72 542 Inductive hasType : exp -> type -> Prop :=
adamc@72 543 | HtNat : forall n,
adamc@72 544 hasType (Nat n) TNat
adamc@72 545 | HtPlus : forall e1 e2,
adamc@72 546 hasType e1 TNat
adamc@72 547 -> hasType e2 TNat
adamc@72 548 -> hasType (Plus e1 e2) TNat
adamc@72 549 | HtBool : forall b,
adamc@72 550 hasType (Bool b) TBool
adamc@72 551 | HtAnd : forall e1 e2,
adamc@72 552 hasType e1 TBool
adamc@72 553 -> hasType e2 TBool
adamc@72 554 -> hasType (And e1 e2) TBool.
adamc@72 555
adamc@75 556 (** It will be helpful to have a function for comparing two types. We build one using [decide equality]. *)
adamc@75 557
adamc@77 558 (* begin thide *)
adamc@75 559 Definition eq_type_dec : forall t1 t2 : type, {t1 = t2} + {t1 <> t2}.
adamc@72 560 decide equality.
adamc@72 561 Defined.
adamc@72 562
adamc@212 563 (** Another notation complements the monadic notation for [maybe] that we defined earlier. Sometimes we want to include "assertions" in our procedures. That is, we want to run a decision procedure and fail if it fails; otherwise, we want to continue, with the proof that it produced made available to us. This infix notation captures that idea, for a procedure that returns an arbitrary two-constructor type. *)
adamc@75 564
adamc@73 565 Notation "e1 ;; e2" := (if e1 then e2 else ??)
adamc@73 566 (right associativity, at level 60).
adamc@73 567
adamc@75 568 (** With that notation defined, we can implement a [typeCheck] function, whose code is only more complex than what we would write in ML because it needs to include some extra type annotations. Every [[[e]]] expression adds a [hasType] proof obligation, and [crush] makes short work of them when we add [hasType]'s constructors as hints. *)
adamc@77 569 (* end thide *)
adamc@75 570
adamc@72 571 Definition typeCheck (e : exp) : {{t | hasType e t}}.
adamc@77 572 (* begin thide *)
adamc@72 573 Hint Constructors hasType.
adamc@72 574
adamc@72 575 refine (fix F (e : exp) : {{t | hasType e t}} :=
adamc@212 576 match e with
adamc@72 577 | Nat _ => [[TNat]]
adamc@72 578 | Plus e1 e2 =>
adamc@72 579 t1 <- F e1;
adamc@72 580 t2 <- F e2;
adamc@72 581 eq_type_dec t1 TNat;;
adamc@72 582 eq_type_dec t2 TNat;;
adamc@72 583 [[TNat]]
adamc@72 584 | Bool _ => [[TBool]]
adamc@72 585 | And e1 e2 =>
adamc@72 586 t1 <- F e1;
adamc@72 587 t2 <- F e2;
adamc@72 588 eq_type_dec t1 TBool;;
adamc@72 589 eq_type_dec t2 TBool;;
adamc@72 590 [[TBool]]
adamc@72 591 end); crush.
adamc@77 592 (* end thide *)
adamc@72 593 Defined.
adamc@72 594
adamc@75 595 (** Despite manipulating proofs, our type checker is easy to run. *)
adamc@75 596
adamc@72 597 Eval simpl in typeCheck (Nat 0).
adamc@212 598 (** %\vspace{-.15in}% [[
adamc@75 599 = [[TNat]]
adamc@75 600 : {{t | hasType (Nat 0) t}}
adamc@75 601 ]] *)
adamc@75 602
adamc@72 603 Eval simpl in typeCheck (Plus (Nat 1) (Nat 2)).
adamc@212 604 (** %\vspace{-.15in}% [[
adamc@75 605 = [[TNat]]
adamc@75 606 : {{t | hasType (Plus (Nat 1) (Nat 2)) t}}
adamc@75 607 ]] *)
adamc@75 608
adamc@72 609 Eval simpl in typeCheck (Plus (Nat 1) (Bool false)).
adamc@212 610 (** %\vspace{-.15in}% [[
adamc@75 611 = ??
adamc@75 612 : {{t | hasType (Plus (Nat 1) (Bool false)) t}}
adamc@75 613 ]] *)
adamc@75 614
adamc@75 615 (** The type-checker also extracts to some reasonable OCaml code. *)
adamc@75 616
adamc@75 617 Extraction typeCheck.
adamc@75 618
adamc@75 619 (** %\begin{verbatim}
adamc@75 620 (** val typeCheck : exp -> type0 maybe **)
adamc@75 621
adamc@75 622 let rec typeCheck = function
adamc@75 623 | Nat n -> Found TNat
adamc@75 624 | Plus (e1, e2) ->
adamc@75 625 (match typeCheck e1 with
adamc@75 626 | Unknown -> Unknown
adamc@75 627 | Found t1 ->
adamc@75 628 (match typeCheck e2 with
adamc@75 629 | Unknown -> Unknown
adamc@75 630 | Found t2 ->
adamc@75 631 (match eq_type_dec t1 TNat with
adamc@75 632 | true ->
adamc@75 633 (match eq_type_dec t2 TNat with
adamc@75 634 | true -> Found TNat
adamc@75 635 | false -> Unknown)
adamc@75 636 | false -> Unknown)))
adamc@75 637 | Bool b -> Found TBool
adamc@75 638 | And (e1, e2) ->
adamc@75 639 (match typeCheck e1 with
adamc@75 640 | Unknown -> Unknown
adamc@75 641 | Found t1 ->
adamc@75 642 (match typeCheck e2 with
adamc@75 643 | Unknown -> Unknown
adamc@75 644 | Found t2 ->
adamc@75 645 (match eq_type_dec t1 TBool with
adamc@75 646 | true ->
adamc@75 647 (match eq_type_dec t2 TBool with
adamc@75 648 | true -> Found TBool
adamc@75 649 | false -> Unknown)
adamc@75 650 | false -> Unknown)))
adamc@75 651 \end{verbatim}%
adamc@75 652
adamc@75 653 #<pre>
adamc@75 654 (** val typeCheck : exp -> type0 maybe **)
adamc@75 655
adamc@75 656 let rec typeCheck = function
adamc@75 657 | Nat n -> Found TNat
adamc@75 658 | Plus (e1, e2) ->
adamc@75 659 (match typeCheck e1 with
adamc@75 660 | Unknown -> Unknown
adamc@75 661 | Found t1 ->
adamc@75 662 (match typeCheck e2 with
adamc@75 663 | Unknown -> Unknown
adamc@75 664 | Found t2 ->
adamc@75 665 (match eq_type_dec t1 TNat with
adamc@75 666 | true ->
adamc@75 667 (match eq_type_dec t2 TNat with
adamc@75 668 | true -> Found TNat
adamc@75 669 | false -> Unknown)
adamc@75 670 | false -> Unknown)))
adamc@75 671 | Bool b -> Found TBool
adamc@75 672 | And (e1, e2) ->
adamc@75 673 (match typeCheck e1 with
adamc@75 674 | Unknown -> Unknown
adamc@75 675 | Found t1 ->
adamc@75 676 (match typeCheck e2 with
adamc@75 677 | Unknown -> Unknown
adamc@75 678 | Found t2 ->
adamc@75 679 (match eq_type_dec t1 TBool with
adamc@75 680 | true ->
adamc@75 681 (match eq_type_dec t2 TBool with
adamc@75 682 | true -> Found TBool
adamc@75 683 | false -> Unknown)
adamc@75 684 | false -> Unknown)))
adamc@75 685 </pre># *)
adamc@75 686
adamc@75 687 (** %\smallskip%
adamc@75 688
adamc@75 689 We can adapt this implementation to use [sumor], so that we know our type-checker only fails on ill-typed inputs. First, we define an analogue to the "assertion" notation. *)
adamc@73 690
adamc@77 691 (* begin thide *)
adamc@73 692 Notation "e1 ;;; e2" := (if e1 then e2 else !!)
adamc@73 693 (right associativity, at level 60).
adamc@73 694
adamc@75 695 (** Next, we prove a helpful lemma, which states that a given expression can have at most one type. *)
adamc@75 696
adamc@75 697 Lemma hasType_det : forall e t1,
adamc@73 698 hasType e t1
adamc@73 699 -> forall t2,
adamc@73 700 hasType e t2
adamc@73 701 -> t1 = t2.
adamc@73 702 induction 1; inversion 1; crush.
adamc@73 703 Qed.
adamc@73 704
adamc@75 705 (** Now we can define the type-checker. Its type expresses that it only fails on untypable expressions. *)
adamc@75 706
adamc@77 707 (* end thide *)
adamc@212 708 Definition typeCheck' (e : exp) : {t : type | hasType e t} + {forall t, ~ hasType e t}.
adamc@77 709 (* begin thide *)
adamc@73 710 Hint Constructors hasType.
adamc@75 711 (** We register all of the typing rules as hints. *)
adamc@75 712
adamc@73 713 Hint Resolve hasType_det.
adamc@75 714 (** [hasType_det] will also be useful for proving proof obligations with contradictory contexts. Since its statement includes [forall]-bound variables that do not appear in its conclusion, only [eauto] will apply this hint. *)
adamc@73 715
adamc@75 716 (** Finally, the implementation of [typeCheck] can be transcribed literally, simply switching notations as needed. *)
adamc@212 717
adamc@212 718 refine (fix F (e : exp) : {t : type | hasType e t} + {forall t, ~ hasType e t} :=
adamc@212 719 match e with
adamc@73 720 | Nat _ => [[[TNat]]]
adamc@73 721 | Plus e1 e2 =>
adamc@73 722 t1 <-- F e1;
adamc@73 723 t2 <-- F e2;
adamc@73 724 eq_type_dec t1 TNat;;;
adamc@73 725 eq_type_dec t2 TNat;;;
adamc@73 726 [[[TNat]]]
adamc@73 727 | Bool _ => [[[TBool]]]
adamc@73 728 | And e1 e2 =>
adamc@73 729 t1 <-- F e1;
adamc@73 730 t2 <-- F e2;
adamc@73 731 eq_type_dec t1 TBool;;;
adamc@73 732 eq_type_dec t2 TBool;;;
adamc@73 733 [[[TBool]]]
adamc@73 734 end); clear F; crush' tt hasType; eauto.
adamc@75 735
adamc@75 736 (** We clear [F], the local name for the recursive function, to avoid strange proofs that refer to recursive calls that we never make. The [crush] variant [crush'] helps us by performing automatic inversion on instances of the predicates specified in its second argument. Once we throw in [eauto] to apply [hasType_det] for us, we have discharged all the subgoals. *)
adamc@77 737 (* end thide *)
adamc@212 738
adamc@212 739
adamc@73 740 Defined.
adamc@73 741
adamc@75 742 (** The short implementation here hides just how time-saving automation is. Every use of one of the notations adds a proof obligation, giving us 12 in total. Most of these obligations require multiple inversions and either uses of [hasType_det] or applications of [hasType] rules.
adamc@75 743
adamc@75 744 The results of simplifying calls to [typeCheck'] look deceptively similar to the results for [typeCheck], but now the types of the results provide more information. *)
adamc@75 745
adamc@73 746 Eval simpl in typeCheck' (Nat 0).
adamc@212 747 (** %\vspace{-.15in}% [[
adamc@75 748 = [[[TNat]]]
adamc@75 749 : {t : type | hasType (Nat 0) t} +
adamc@75 750 {(forall t : type, ~ hasType (Nat 0) t)}
adamc@75 751 ]] *)
adamc@75 752
adamc@73 753 Eval simpl in typeCheck' (Plus (Nat 1) (Nat 2)).
adamc@212 754 (** %\vspace{-.15in}% [[
adamc@75 755 = [[[TNat]]]
adamc@75 756 : {t : type | hasType (Plus (Nat 1) (Nat 2)) t} +
adamc@75 757 {(forall t : type, ~ hasType (Plus (Nat 1) (Nat 2)) t)}
adamc@75 758 ]] *)
adamc@75 759
adamc@73 760 Eval simpl in typeCheck' (Plus (Nat 1) (Bool false)).
adamc@212 761 (** %\vspace{-.15in}% [[
adamc@75 762 = !!
adamc@75 763 : {t : type | hasType (Plus (Nat 1) (Bool false)) t} +
adamc@75 764 {(forall t : type, ~ hasType (Plus (Nat 1) (Bool false)) t)}
adamc@75 765 ]] *)
adamc@82 766
adamc@82 767
adamc@82 768 (** * Exercises *)
adamc@82 769
adamc@82 770 (** All of the notations defined in this chapter, plus some extras, are available for import from the module [MoreSpecif] of the book source.
adamc@82 771
adamc@82 772 %\begin{enumerate}%#<ol>#
adamc@82 773 %\item%#<li># Write a function of type [forall n m : nat, {n <= m} + {n > m}]. That is, this function decides whether one natural is less than another, and its dependent type guarantees that its results are accurate.#</li>#
adamc@82 774
adamc@82 775 %\item%#<li># %\begin{enumerate}%#<ol>#
adamc@82 776 %\item%#<li># Define [var], a type of propositional variables, as a synonym for [nat].#</li>#
adamc@82 777 %\item%#<li># Define an inductive type [prop] of propositional logic formulas, consisting of variables, negation, and binary conjunction and disjunction.#</li>#
adamc@82 778 %\item%#<li># Define a function [propDenote] from variable truth assignments and [prop]s to [Prop], based on the usual meanings of the connectives. Represent truth assignments as functions from [var] to [bool].#</li>#
adamc@82 779 %\item%#<li># Define a function [bool_true_dec] that checks whether a boolean is true, with a maximally expressive dependent type. That is, the function should have type [forall b, {b = true} + {b = true -> False}]. #</li>#
adamc@212 780 %\item%#<li># Define a function [decide] that determines whether a particular [prop] is true under a particular truth assignment. That is, the function should have type [forall (truth : var -> bool) (p : prop), {propDenote truth p} + {~ propDenote truth p}]. This function is probably easiest to write in the usual tactical style, instead of programming with [refine]. [bool_true_dec] may come in handy as a hint.#</li>#
adamc@212 781 %\item%#<li># Define a function [negate] that returns a simplified version of the negation of a [prop]. That is, the function should have type [forall p : prop, {p' : prop | forall truth, propDenote truth p <-> ~ propDenote truth p'}]. To simplify a variable, just negate it. Simplify a negation by returning its argument. Simplify conjunctions and disjunctions using De Morgan's laws, negating the arguments recursively and switching the kind of connective. [decide] may be useful in some of the proof obligations, even if you do not use it in the computational part of [negate]'s definition. Lemmas like [decide] allow us to compensate for the lack of a general Law of the Excluded Middle in CIC.#</li>#
adamc@82 782 #</ol>#%\end{enumerate}% #</li>#
adamc@82 783
adamc@212 784 %\item%#<li># Implement the DPLL satisfiability decision procedure for boolean formulas in conjunctive normal form, with a dependent type that guarantees its correctness. An example of a reasonable type for this function would be [forall f : formula, {truth : tvals | formulaTrue truth f} + {forall truth, ~ formulaTrue truth f}]. Implement at least "the basic backtracking algorithm" as defined here:
adamc@82 785 %\begin{center}\url{http://en.wikipedia.org/wiki/DPLL_algorithm}\end{center}%
adamc@82 786 #<blockquote><a href="http://en.wikipedia.org/wiki/DPLL_algorithm">http://en.wikipedia.org/wiki/DPLL_algorithm</a></blockquote>#
adamc@82 787 It might also be instructive to implement the unit propagation and pure literal elimination optimizations described there or some other optimizations that have been used in modern SAT solvers.#</li>#
adamc@82 788
adamc@82 789 #</ol>#%\end{enumerate}% *)