adamc@62: (* Copyright (c) 2008, Adam Chlipala
adamc@62: *
adamc@62: * This work is licensed under a
adamc@62: * Creative Commons Attribution-Noncommercial-No Derivative Works 3.0
adamc@62: * Unported License.
adamc@62: * The license text is available at:
adamc@62: * http://creativecommons.org/licenses/by-nc-nd/3.0/
adamc@62: *)
adamc@62:
adamc@62: (* begin hide *)
adamc@62: Require Import List.
adamc@62:
adamc@62: Require Import Tactics.
adamc@62:
adamc@62: Set Implicit Arguments.
adamc@62: (* end hide *)
adamc@62:
adamc@62:
adamc@62: (** %\chapter{Infinite Data and Proofs}% *)
adamc@62:
adamc@62: (** In lazy functional programming languages like Haskell, infinite data structures are everywhere. Infinite lists and more exotic datatypes provide convenient abstractions for communication between parts of a program. Achieving similar convenience without infinite lazy structures would, in many cases, require acrobatic inversions of control flow.
adamc@62:
adamc@62: Laziness is easy to implement in Haskell, where all the definitions in a program may be thought of as mutually recursive. In such an unconstrained setting, it is easy to implement an infinite loop when you really meant to build an infinite list, where any finite prefix of the list should be forceable in finite time. Haskell programmers learn how to avoid such slip-ups. In Coq, such a laissez-faire policy is not good enough.
adamc@62:
adamc@62: We spent some time in the last chapter discussing the Curry-Howard isomorphism, where proofs are identified with functional programs. In such a setting, infinite loops, intended or otherwise, are disastrous. If Coq allowed the full breadth of definitions that Haskell did, we could code up an infinite loop and use it to prove any proposition vacuously. That is, the addition of general recursion would make CIC %\textit{%##inconsistent##%}%.
adamc@62:
adamc@62: There are also algorithmic considerations that make universal termination very desirable. We have seen how tactics like [reflexivity] compare terms up to equivalence under computational rules. Calls to recursive, pattern-matching functions are simplified automatically, with no need for explicit proof steps. It would be very hard to hold onto that kind of benefit if it became possible to write non-terminating programs; we would be running smack into the halting problem.
adamc@62:
adamc@62: One solution is to use types to contain the possibility of non-termination. For instance, we can create a "non-termination monad," inside which we must write all of our general-recursive programs. In later chapters, we will spend some time on this idea and its applications. For now, we will just say that it is a heavyweight solution, and so we would like to avoid it whenever possible.
adamc@62:
adamc@62: Luckily, Coq has special support for a class of lazy data structures that happens to contain most examples found in Haskell. That mechanism, %\textit{%##co-inductive types##%}%, is the subject of this chapter. *)
adamc@62:
adamc@62:
adamc@62: (** * Computing with Infinite Data *)
adamc@62:
adamc@62: (** Let us begin with the most basic type of infinite data, %\textit{%##streams##%}%, or lazy lists. *)
adamc@62:
adamc@62: Section stream.
adamc@62: Variable A : Set.
adamc@62:
adamc@62: CoInductive stream : Set :=
adamc@62: | Cons : A -> stream -> stream.
adamc@62: End stream.
adamc@62:
adamc@62: (** The definition is surprisingly simple. Starting from the definition of [list], we just need to change the keyword [Inductive] to [CoInductive]. We could have left a [Nil] constructor in our definition, but we will leave it out to force all of our streams to be infinite.
adamc@62:
adamc@62: How do we write down a stream constant? Obviously simple application of constructors is not good enough, since we could only denote finite objects that way. Rather, whereas recursive definitions were necessary to %\textit{%##use##%}% values of recursive inductive types effectively, here we find that we need %\textit{%##co-recursive definitions##%}% to %\textit{%##build##%}% values of co-inductive types effectively.
adamc@62:
adamc@62: We can define a stream consisting only of zeroes. *)
adamc@62:
adamc@62: CoFixpoint zeroes : stream nat := Cons 0 zeroes.
adamc@62:
adamc@62: (** We can also define a stream that alternates between [true] and [false]. *)
adamc@62:
adamc@62: CoFixpoint trues : stream bool := Cons true falses
adamc@62: with falses : stream bool := Cons false trues.
adamc@62:
adamc@62: (** Co-inductive values are fair game as arguments to recursive functions, and we can use that fact to write a function to take a finite approximation of a stream. *)
adamc@62:
adamc@62: Fixpoint approx A (s : stream A) (n : nat) {struct n} : list A :=
adamc@62: match n with
adamc@62: | O => nil
adamc@62: | S n' =>
adamc@62: match s with
adamc@62: | Cons h t => h :: approx t n'
adamc@62: end
adamc@62: end.
adamc@62:
adamc@62: Eval simpl in approx zeroes 10.
adamc@62: (** [[
adamc@62:
adamc@62: = 0 :: 0 :: 0 :: 0 :: 0 :: 0 :: 0 :: 0 :: 0 :: 0 :: nil
adamc@62: : list nat
adamc@62: ]] *)
adamc@62: Eval simpl in approx trues 10.
adamc@62: (** [[
adamc@62:
adamc@62: = true
adamc@62: :: false
adamc@62: :: true
adamc@62: :: false
adamc@62: :: true :: false :: true :: false :: true :: false :: nil
adamc@62: : list bool
adamc@62: ]] *)
adamc@62:
adamc@68: (* begin thide *)
adamc@62: (** So far, it looks like co-inductive types might be a magic bullet, allowing us to import all of the Haskeller's usual tricks. However, there are important restrictions that are dual to the restrictions on the use of inductive types. Fixpoints %\textit{%##consume##%}% values of inductive types, with restrictions on which %\textit{%##arguments##%}% may be passed in recursive calls. Dually, co-fixpoints %\textit{%##produce##%}% values of co-inductive types, with restrictions on what may be done with the %\textit{%##results##%}% of co-recursive calls.
adamc@62:
adamc@62: The restriction for co-inductive types shows up as the %\textit{%##guardedness condition##%}%, and it can be broken into two parts. First, consider this stream definition, which would be legal in Haskell.
adamc@62:
adamc@62: [[
adamc@68: (* end thide *)
adamc@62: CoFixpoint looper : stream nat := looper.
adamc@68: (* begin thide *)
adamc@62: [[
adamc@62: Error:
adamc@62: Recursive definition of looper is ill-formed.
adamc@62: In environment
adamc@62: looper : stream nat
adamc@62:
adamc@62: unguarded recursive call in "looper"
adamc@62: *)
adamc@68: (* end thide *)
adamc@62:
adamc@62: (** The rule we have run afoul of here is that %\textit{%##every co-recursive call must be guarded by a constructor##%}%; that is, every co-recursive call must be a direct argument to a constructor of the co-inductive type we are generating. It is a good thing that this rule is enforced. If the definition of [looper] were accepted, our [approx] function would run forever when passed [looper], and we would have fallen into inconsistency.
adamc@62:
adamc@62: The second rule of guardedness is easiest to see by first introducing a more complicated, but legal, co-fixpoint. *)
adamc@62:
adamc@62: Section map.
adamc@62: Variables A B : Set.
adamc@62: Variable f : A -> B.
adamc@62:
adamc@62: CoFixpoint map (s : stream A) : stream B :=
adamc@62: match s with
adamc@62: | Cons h t => Cons (f h) (map t)
adamc@62: end.
adamc@62: End map.
adamc@62:
adamc@62: (** This code is a literal copy of that for the list [map] function, with the [Nil] case removed and [Fixpoint] changed to [CoFixpoint]. Many other standard functions on lazy data structures can be implemented just as easily. Some, like [filter], cannot be implemented. Since the predicate passed to [filter] may reject every element of the stream, we cannot satisfy even the first guardedness condition.
adamc@62:
adamc@62: The second condition is subtler. To illustrate it, we start off with another co-recursive function definition that %\textit{%##is##%}% legal. The function [interleaves] takes two streams and produces a new stream that alternates between their elements. *)
adamc@62:
adamc@62: Section interleave.
adamc@62: Variable A : Set.
adamc@62:
adamc@62: CoFixpoint interleave (s1 s2 : stream A) : stream A :=
adamc@62: match s1, s2 with
adamc@62: | Cons h1 t1, Cons h2 t2 => Cons h1 (Cons h2 (interleave t1 t2))
adamc@62: end.
adamc@62: End interleave.
adamc@62:
adamc@62: (** Now say we want to write a weird stuttering version of [map] that repeats elements in a particular way, based on interleaving. *)
adamc@62:
adamc@62: Section map'.
adamc@62: Variables A B : Set.
adamc@62: Variable f : A -> B.
adamc@62:
adamc@68: (* begin thide *)
adamc@62: (** [[
adamc@68: (* end thide *)
adamc@62:
adamc@62: CoFixpoint map' (s : stream A) : stream B :=
adamc@62: match s with
adamc@62: | Cons h t => interleave (Cons (f h) (map' s)) (Cons (f h) (map' s))
adamc@68: end.
adamc@68: (* begin thide *)
adamc@68: *)
adamc@62:
adamc@62: (** We get another error message about an unguarded recursive call. This is because we are violating the second guardedness condition, which says that, not only must co-recursive calls be arguments to constructors, there must also %\textit{%##not be anything but [match]es and calls to constructors of the same co-inductive type##%}% wrapped around these immediate uses of co-recursive calls. The actual implemented rule for guardedness is a little more lenient than what we have just stated, but you can count on the illegality of any exception that would enhance the expressive power of co-recursion.
adamc@62:
adamc@62: Why enforce a rule like this? Imagine that, instead of [interleave], we had called some other, less well-behaved function on streams. Perhaps this other function might be defined mutually with [map']. It might deconstruct its first argument, retrieving [map' s] from within [Cons (f h) (map' s)]. Next it might try a [match] on this retrieved value, which amounts to deconstructing [map' s]. To figure out how this [match] turns out, we need to know the top-level structure of [map' s], but this is exactly what we started out trying to determine! We run into a loop in the evaluation process, and we have reached a witness of inconsistency if we are evaluating [approx (map' s) 1] for any [s]. *)
adamc@68: (* end thide *)
adamc@62: End map'.
adamc@62:
adamc@63:
adamc@63: (** * Infinite Proofs *)
adamc@63:
adamc@63: (** Let us say we want to give two different definitions of a stream of all ones, and then we want to prove that they are equivalent. *)
adamc@63:
adamc@63: CoFixpoint ones : stream nat := Cons 1 ones.
adamc@63: Definition ones' := map S zeroes.
adamc@63:
adamc@63: (** The obvious statement of the equality is this: *)
adamc@63:
adamc@63: Theorem ones_eq : ones = ones'.
adamc@63:
adamc@63: (** However, faced with the initial subgoal, it is not at all clear how this theorem can be proved. In fact, it is unprovable. The [eq] predicate that we use is fundamentally limited to equalities that can be demonstrated by finite, syntactic arguments. To prove this equivalence, we will need to introduce a new relation. *)
adamc@68: (* begin thide *)
adamc@63: Abort.
adamc@63:
adamc@63: (** Co-inductive datatypes make sense by analogy from Haskell. What we need now is a %\textit{%##co-inductive proposition##%}%. That is, we want to define a proposition whose proofs may be infinite, subject to the guardedness condition. The idea of infinite proofs does not show up in usual mathematics, but it can be very useful (unsurprisingly) for reasoning about infinite data structures. Besides examples from Haskell, infinite data and proofs will also turn out to be useful for modelling inherently infinite mathematical objects, like program executions.
adamc@63:
adamc@63: We are ready for our first co-inductive predicate. *)
adamc@63:
adamc@63: Section stream_eq.
adamc@63: Variable A : Set.
adamc@63:
adamc@63: CoInductive stream_eq : stream A -> stream A -> Prop :=
adamc@63: | Stream_eq : forall h t1 t2,
adamc@63: stream_eq t1 t2
adamc@63: -> stream_eq (Cons h t1) (Cons h t2).
adamc@63: End stream_eq.
adamc@63:
adamc@63: (** We say that two streams are equal if and only if they have the same heads and their tails are equal. We use the normal finite-syntactic equality for the heads, and we refer to our new equality recursively for the tails.
adamc@63:
adamc@63: We can try restating the theorem with [stream_eq]. *)
adamc@63:
adamc@63: Theorem ones_eq : stream_eq ones ones'.
adamc@63: (** Coq does not support tactical co-inductive proofs as well as it supports tactical inductive proofs. The usual starting point is the [cofix] tactic, which asks to structure this proof as a co-fixpoint. *)
adamc@63: cofix.
adamc@63: (** [[
adamc@63:
adamc@63: ones_eq : stream_eq ones ones'
adamc@63: ============================
adamc@63: stream_eq ones ones'
adamc@63: ]] *)
adamc@63:
adamc@63: (** It looks like this proof might be easier than we expected! *)
adamc@63:
adamc@63: assumption.
adamc@63: (** [[
adamc@63:
adamc@63: Proof completed. *)
adamc@63:
adamc@63: (** Unfortunately, we are due for some disappointment in our victory lap. *)
adamc@63:
adamc@63: (** [[
adamc@63: Qed.
adamc@63:
adamc@63: Error:
adamc@63: Recursive definition of ones_eq is ill-formed.
adamc@63:
adamc@63: In environment
adamc@63: ones_eq : stream_eq ones ones'
adamc@63:
adamc@63: unguarded recursive call in "ones_eq" *)
adamc@63:
adamc@63: (** Via the Curry-Howard correspondence, the same guardedness condition applies to our co-inductive proofs as to our co-inductive data structures. We should be grateful that this proof is rejected, because, if it were not, the same proof structure could be used to prove any co-inductive theorem vacuously, by direct appeal to itself!
adamc@63:
adamc@63: Thinking about how Coq would generate a proof term from the proof script above, we see that the problem is that we are violating the first part of the guardedness condition. During our proofs, Coq can help us check whether we have yet gone wrong in this way. We can run the command [Guarded] in any context to see if it is possible to finish the proof in a way that will yield a properly guarded proof term.
adamc@63:
adamc@63: [[
adamc@63: Guarded.
adamc@63:
adamc@63: Running [Guarded] here gives us the same error message that we got when we tried to run [Qed]. In larger proofs, [Guarded] can be helpful in detecting problems %\textit{%##before##%}% we think we are ready to run [Qed].
adamc@63:
adamc@63: We need to start the co-induction by applying one of [stream_eq]'s constructors. To do that, we need to know that both arguments to the predicate are [Cons]es. Informally, this is trivial, but [simpl] is not able to help us. *)
adamc@63:
adamc@63: Undo.
adamc@63: simpl.
adamc@63: (** [[
adamc@63:
adamc@63: ones_eq : stream_eq ones ones'
adamc@63: ============================
adamc@63: stream_eq ones ones'
adamc@63: ]] *)
adamc@63:
adamc@63: (** It turns out that we are best served by proving an auxiliary lemma. *)
adamc@63: Abort.
adamc@63:
adamc@63: (** First, we need to define a function that seems pointless on first glance. *)
adamc@63:
adamc@63: Definition frob A (s : stream A) : stream A :=
adamc@63: match s with
adamc@63: | Cons h t => Cons h t
adamc@63: end.
adamc@63:
adamc@63: (** Next, we need to prove a theorem that seems equally pointless. *)
adamc@63:
adamc@63: Theorem frob_eq : forall A (s : stream A), s = frob s.
adamc@63: destruct s; reflexivity.
adamc@63: Qed.
adamc@63:
adamc@63: (** But, miraculously, this theorem turns out to be just what we needed. *)
adamc@63:
adamc@63: Theorem ones_eq : stream_eq ones ones'.
adamc@63: cofix.
adamc@63:
adamc@63: (** We can use the theorem to rewrite the two streams. *)
adamc@63: rewrite (frob_eq ones).
adamc@63: rewrite (frob_eq ones').
adamc@63: (** [[
adamc@63:
adamc@63: ones_eq : stream_eq ones ones'
adamc@63: ============================
adamc@63: stream_eq (frob ones) (frob ones')
adamc@63: ]] *)
adamc@63:
adamc@63: (** Now [simpl] is able to reduce the streams. *)
adamc@63:
adamc@63: simpl.
adamc@63: (** [[
adamc@63:
adamc@63: ones_eq : stream_eq ones ones'
adamc@63: ============================
adamc@63: stream_eq (Cons 1 ones)
adamc@63: (Cons 1
adamc@63: ((cofix map (s : stream nat) : stream nat :=
adamc@63: match s with
adamc@63: | Cons h t => Cons (S h) (map t)
adamc@63: end) zeroes))
adamc@63: ]] *)
adamc@63:
adamc@63: (** Since we have exposed the [Cons] structure of each stream, we can apply the constructor of [stream_eq]. *)
adamc@63:
adamc@63: constructor.
adamc@63: (** [[
adamc@63:
adamc@63: ones_eq : stream_eq ones ones'
adamc@63: ============================
adamc@63: stream_eq ones
adamc@63: ((cofix map (s : stream nat) : stream nat :=
adamc@63: match s with
adamc@63: | Cons h t => Cons (S h) (map t)
adamc@63: end) zeroes)
adamc@63: ]] *)
adamc@63:
adamc@63: (** Now, modulo unfolding of the definition of [map], we have matched our assumption. *)
adamc@63: assumption.
adamc@63: Qed.
adamc@63:
adamc@63: (** Why did this silly-looking trick help? The answer has to do with the constraints placed on Coq's evaluation rules by the need for termination. The [cofix]-related restriction that foiled our first attempt at using [simpl] is dual to a restriction for [fix]. In particular, an application of an anonymous [fix] only reduces when the top-level structure of the recursive argument is known. Otherwise, we would be unfolding the recursive definition ad infinitum.
adamc@63:
adamc@63: Fixpoints only reduce when enough is known about the %\textit{%##definitions##%}% of their arguments. Dually, co-fixpoints only reduce when enough is known about %\textit{%##how their results will be used##%}%. In particular, a [cofix] is only expanded when it is the discriminee of a [match]. Rewriting with our superficially silly lemma wrapped new [match]es around the two [cofix]es, triggering reduction.
adamc@63:
adamc@63: If [cofix]es reduced haphazardly, it would be easy to run into infinite loops in evaluation, since we are, after all, building infinite objects.
adamc@63:
adamc@63: One common source of difficulty with co-inductive proofs is bad interaction with standard Coq automation machinery. If we try to prove [ones_eq'] with automation, like we have in previous inductive proofs, we get an invalid proof. *)
adamc@63:
adamc@63: Theorem ones_eq' : stream_eq ones ones'.
adamc@63: cofix; crush.
adamc@63: (** [[
adamc@63:
adamc@63: Guarded. *)
adamc@63: Abort.
adamc@68: (* end thide *)
adamc@63:
adamc@63: (** The standard [auto] machinery sees that our goal matches an assumption and so applies that assumption, even though this violates guardedness. One usually starts a proof like this by [destruct]ing some parameter and running a custom tactic to figure out the first proof rule to apply for each case. Alternatively, there are tricks that can be played with "hiding" the co-inductive hypothesis. We will see examples of effective co-inductive proving in later chapters. *)
adamc@64:
adamc@64:
adamc@64: (** * Simple Modeling of Non-Terminating Programs *)
adamc@64:
adamc@67: (** We close the chapter with a quick motivating example for more complex uses of co-inductive types. We will define a co-inductive semantics for a simple assembly language and use that semantics to prove that an optimization function is sound. We start by defining types of registers, program labels, and instructions. *)
adamc@64:
adamc@64: Inductive reg : Set := R1 | R2.
adamc@64: Definition label := nat.
adamc@64:
adamc@64: Inductive instrs : Set :=
adamc@64: | Const : reg -> nat -> instrs -> instrs
adamc@64: | Add : reg -> reg -> reg -> instrs -> instrs
adamc@64: | Halt : reg -> instrs
adamc@64: | Jeq : reg -> reg -> label -> instrs -> instrs.
adamc@64:
adamc@67: (** [Const] stores a constant in a register; [Add] stores in the first register the sum of the values in the second two; [Halt] ends the program, returning the value of its register argument; and [Jeq] jumps to a label if the values in two registers are equal. Each instruction but [Halt] takes an [instrs], which can be read as "list of instructions," as the normal continuation of control flow.
adamc@67:
adamc@67: We can define a program as a list of lists of instructions, where labels will be interpreted as indexing into such a list. *)
adamc@67:
adamc@64: Definition program := list instrs.
adamc@64:
adamc@67: (** We define a polymorphic map type for register keys, with its associated operations. *)
adamc@64: Section regmap.
adamc@64: Variable A : Set.
adamc@64:
adamc@64: Record regmap : Set := Regmap {
adamc@64: VR1 : A;
adamc@64: VR2 : A
adamc@64: }.
adamc@64:
adamc@67: Definition empty (v : A) : regmap := Regmap v v.
adamc@64: Definition get (rm : regmap) (r : reg) : A :=
adamc@64: match r with
adamc@64: | R1 => VR1 rm
adamc@64: | R2 => VR2 rm
adamc@64: end.
adamc@64: Definition set (rm : regmap) (r : reg) (v : A) : regmap :=
adamc@64: match r with
adamc@64: | R1 => Regmap v (VR2 rm)
adamc@64: | R2 => Regmap (VR1 rm) v
adamc@64: end.
adamc@64: End regmap.
adamc@64:
adamc@67: (** Now comes the interesting part. We define a co-inductive semantics for programs. The definition itself is not surprising. We could change [CoInductive] to [Inductive] and arrive at a valid semantics that only covers terminating program executions. Using [CoInductive] admits infinite derivations for infinite executions. *)
adamc@67:
adamc@64: Section run.
adamc@64: Variable prog : program.
adamc@64:
adamc@64: CoInductive run : regmap nat -> instrs -> nat -> Prop :=
adamc@64: | RConst : forall rm r n is v,
adamc@64: run (set rm r n) is v
adamc@64: -> run rm (Const r n is) v
adamc@64: | RAdd : forall rm r r1 r2 is v,
adamc@64: run (set rm r (get rm r1 + get rm r2)) is v
adamc@64: -> run rm (Add r r1 r2 is) v
adamc@64: | RHalt : forall rm r,
adamc@64: run rm (Halt r) (get rm r)
adamc@64: | RJeq_eq : forall rm r1 r2 l is is' v,
adamc@64: get rm r1 = get rm r2
adamc@64: -> nth_error prog l = Some is'
adamc@64: -> run rm is' v
adamc@64: -> run rm (Jeq r1 r2 l is) v
adamc@64: | RJeq_neq : forall rm r1 r2 l is v,
adamc@64: get rm r1 <> get rm r2
adamc@64: -> run rm is v
adamc@64: -> run rm (Jeq r1 r2 l is) v.
adamc@64: End run.
adamc@64:
adamc@67: (** We can write a function which tracks known register values to attempt to constant fold a sequence of instructions. We track register values with a [regmap (option nat)], where a mapping to [None] indicates no information, and a mapping to [Some n] indicates that the corresponding register is known to have value [n]. *)
adamc@67:
adamc@64: Fixpoint constFold (rm : regmap (option nat)) (is : instrs) {struct is} : instrs :=
adamc@64: match is with
adamc@64: | Const r n is => Const r n (constFold (set rm r (Some n)) is)
adamc@64: | Add r r1 r2 is =>
adamc@64: match get rm r1, get rm r2 with
adamc@67: | Some n1, Some n2 =>
adamc@67: Const r (n1 + n2) (constFold (set rm r (Some (n1 + n2))) is)
adamc@64: | _, _ => Add r r1 r2 (constFold (set rm r None) is)
adamc@64: end
adamc@64: | Halt _ => is
adamc@64: | Jeq r1 r2 l is => Jeq r1 r2 l (constFold rm is)
adamc@64: end.
adamc@64:
adamc@67: (** We characterize when the two types of register maps we are using agree with each other. *)
adamc@67:
adamc@64: Definition regmapCompat (rm : regmap nat) (rm' : regmap (option nat)) :=
adamc@64: forall r, match get rm' r with
adamc@64: | None => True
adamc@64: | Some v => get rm r = v
adamc@64: end.
adamc@64:
adamc@67: (** We prove two lemmas about how register map modifications affect compatibility. A tactic [compat] abstracts the common structure of the two proofs. *)
adamc@67:
adamc@67: (** remove printing * *)
adamc@64: Ltac compat := unfold regmapCompat in *; crush;
adamc@64: match goal with
adamc@64: | [ |- match get _ ?R with Some _ => _ | None => _ end ] => destruct R; crush
adamc@64: end.
adamc@64:
adamc@64: Lemma regmapCompat_set_None : forall rm rm' r n,
adamc@64: regmapCompat rm rm'
adamc@64: -> regmapCompat (set rm r n) (set rm' r None).
adamc@64: destruct r; compat.
adamc@64: Qed.
adamc@64:
adamc@64: Lemma regmapCompat_set_Some : forall rm rm' r n,
adamc@64: regmapCompat rm rm'
adamc@64: -> regmapCompat (set rm r n) (set rm' r (Some n)).
adamc@64: destruct r; compat.
adamc@64: Qed.
adamc@64:
adamc@67: (** Finally, we can prove the main theorem. *)
adamc@64:
adamc@64: Section constFold_ok.
adamc@64: Variable prog : program.
adamc@64:
adamc@64: Theorem constFold_ok : forall rm is v,
adamc@64: run prog rm is v
adamc@64: -> forall rm', regmapCompat rm rm'
adamc@64: -> run prog rm (constFold rm' is) v.
adamc@64: Hint Resolve regmapCompat_set_None regmapCompat_set_Some.
adamc@64: Hint Constructors run.
adamc@64:
adamc@65: cofix;
adamc@65: destruct 1; crush; eauto;
adamc@65: repeat match goal with
adamc@67: | [ H : regmapCompat _ _
adamc@67: |- run _ _ (match get ?RM ?R with
adamc@67: | Some _ => _
adamc@67: | None => _
adamc@67: end) _ ] =>
adamc@65: generalize (H R); destruct (get RM R); crush
adamc@65: end.
adamc@64: Qed.
adamc@64: End constFold_ok.
adamc@64:
adamc@67: (** If we print the proof term that was generated, we can verify that the proof is structured as a [cofix], with each co-recursive call properly guarded. *)
adamc@67:
adamc@64: Print constFold_ok.
adamc@81:
adamc@81:
adamc@81: (** * Exercises *)
adamc@81:
adamc@81: (** %\begin{enumerate}%##
adamc@81:
adamc@81: %\item%#- # %\begin{enumerate}%#
#
adamc@81: %\item%#- # Define a co-inductive type of infinite trees carrying data of a fixed parameter type. Each node should contain a data value and two child trees.#
#
adamc@81: %\item%#- # Define a function [everywhere] for building a tree with the same data value at every node.#
#
adamc@81: %\item%#- # Define a function [map] for building an output tree out of two input trees by traversing them in parallel and applying a two-argument function to their corresponding data values.#
#
adamc@81: %\item%#- # Define a stream [falses] where every node has the value [false].#
#
adamc@81: %\item%#- # Define a stream [true_false] where the root node has value [true], its children have value [false], all nodes at the next have the value [true], and so on, alternating boolean values from level to level.#
#
adamc@81: %\item%#- # Prove that [true_falses] is equal to the result of mapping the boolean "or" function [orb] over [true_false] and [falses]. You can make [orb] available with [Require Import Bool.]. You may find the lemma [orb_false_r] from the same module helpful. Your proof here should not be about the standard equality [=], but rather about some new equality relation that you define.#
#
adamc@81: #
#%\end{enumerate}% # #
adamc@81:
adamc@81: #
#%\end{enumerate}% *)