adam@298: (* Copyright (c) 2008-2011, Adam Chlipala
adamc@2:  * 
adamc@2:  * This work is licensed under a
adamc@2:  * Creative Commons Attribution-Noncommercial-No Derivative Works 3.0
adamc@2:  * Unported License.
adamc@2:  * The license text is available at:
adamc@2:  *   http://creativecommons.org/licenses/by-nc-nd/3.0/
adamc@2:  *)
adamc@2: 
adamc@3: (* begin hide *)
adam@312: Require Import Bool Arith List.
adamc@2: 
adam@314: Require Import CpdtTactics.
adamc@14: 
adamc@14: Set Implicit Arguments.
adamc@3: (* end hide *)
adamc@2: 
adamc@2: 
adamc@25: (** %\chapter{Some Quick Examples}% *)
adamc@25: 
adamc@25: 
adam@279: (** I will start off by jumping right in to a fully-worked set of examples, building certified compilers from increasingly complicated source languages to stack machines.  We will meet a few useful tactics and see how they can be used in manual proofs, and we will also see how easily these proofs can be automated instead.  This chapter is not meant to give full explanations of the features that are employed.  Rather, it is meant more as an advertisement of what is possible.  Later chapters will introduce all of the concepts in bottom-up fashion.
adam@279: 
adam@314: As always, you can step through the source file %\texttt{%#<tt>#StackMachine.v#</tt>#%}% for this chapter interactively in Proof General.  Alternatively, to get a feel for the whole lifecycle of creating a Coq development, you can enter the pieces of source code in this chapter in a new %\texttt{%#<tt>#.v#</tt>#%}% file in an Emacs buffer.  If you do the latter, include two lines
adam@314: 
adam@314: %\index{Vernacular commands!Require}%[Require Import Bool] #<span class="inlinecode"><span class="id" type="var">#%\coqdocconstructor{%Arith%}%#</span></span># #<span class="inlinecode"><span class="id" type="var">#%\coqdocconstructor{%List%}%#</span></span># [CpdtTactics.]
adam@314: 
adam@314: %\noindent{}%and
adam@314: 
adam@314: %\index{Vernacular commands!Set Implicit Arguments}%[Set Implicit] #<span class="inlinecode"><span class="id" type="keyword">#%\coqdockw{%Arguments%}%#</span></span>#[.]
adam@314: 
adam@314: %\noindent{}%at the start of the file, to match some code hidden in this rendering of the chapter source.  In general, similar commands will be hidden in the book rendering of each chapter's source code, so you will need to insert them in from-scratch replayings of the code that is presented.  To be more specific, every chapter begins with some imports of other modules, followed by [Set Implicit] #<span class="inlinecode"><span class="id" type="keyword">#%\coqdockw{%Arguments%}%#</span></span>#[.], where the latter affects the default behavior of definitions regarding type inference.
adam@307: *)
adamc@9: 
adamc@9: 
adamc@20: (** * Arithmetic Expressions Over Natural Numbers *)
adamc@2: 
adamc@40: (** We will begin with that staple of compiler textbooks, arithmetic expressions over a single type of numbers. *)
adamc@9: 
adamc@20: (** ** Source Language *)
adamc@9: 
adam@311: (** We begin with the syntax of the source language.%\index{Vernacular commands!Inductive}% *)
adamc@2: 
adamc@4: Inductive binop : Set := Plus | Times.
adamc@2: 
adam@311: (** Our first line of Coq code should be unsurprising to ML and Haskell programmers.  We define an %\index{algebraic datatypes}%algebraic datatype [binop] to stand for the binary operators of our source language.  There are just two wrinkles compared to ML and Haskell.  First, we use the keyword [Inductive], in place of %\texttt{%#<tt>#data#</tt>#%}%, %\texttt{%#<tt>#datatype#</tt>#%}%, or %\texttt{%#<tt>#type#</tt>#%}%.  This is not just a trivial surface syntax difference; inductive types in Coq are much more expressive than garden variety algebraic datatypes, essentially enabling us to encode all of mathematics, though we begin humbly in this chapter.  Second, there is the %\index{Gallina terms!Set}%[: Set] fragment, which declares that we are defining a datatype that should be thought of as a constituent of programs.  Later, we will see other options for defining datatypes in the universe of proofs or in an infinite hierarchy of universes, encompassing both programs and proofs, that is useful in higher-order constructions. *)
adamc@9: 
adamc@4: Inductive exp : Set :=
adamc@4: | Const : nat -> exp
adamc@4: | Binop : binop -> exp -> exp -> exp.
adamc@2: 
adamc@9: (** Now we define the type of arithmetic expressions.  We write that a constant may be built from one argument, a natural number; and a binary operation may be built from a choice of operator and two operand expressions.
adamc@9: 
adam@311: A note for readers following along in the PDF version: %\index{coqdoc}%coqdoc supports pretty-printing of tokens in LaTeX or HTML.  Where you see a right arrow character, the source contains the ASCII text %\texttt{%#<tt>#->#</tt>#%}%.  Other examples of this substitution appearing in this chapter are a double right arrow for %\texttt{%#<tt>#=>#</tt>#%}%, the inverted %`%#'#A' symbol for %\texttt{%#<tt>#forall#</tt>#%}%, and the Cartesian product %`%#'#X' for %\texttt{%#<tt>#*#</tt>#%}%.  When in doubt about the ASCII version of a symbol, you can consult the chapter source code.
adamc@9: 
adamc@9: %\medskip%
adamc@9: 
adam@311: Now we are ready to say what these programs mean.  We will do this by writing an %\index{interpreters}%interpreter that can be thought of as a trivial operational or denotational semantics.  (If you are not familiar with these semantic techniques, no need to worry; we will stick to %``%#"#common sense#"#%''% constructions.)%\index{Vernacular commands!Definition}% *)
adamc@9: 
adamc@4: Definition binopDenote (b : binop) : nat -> nat -> nat :=
adamc@4:   match b with
adamc@4:     | Plus => plus
adamc@4:     | Times => mult
adamc@4:   end.
adamc@2: 
adamc@9: (** The meaning of a binary operator is a binary function over naturals, defined with pattern-matching notation analogous to the %\texttt{%#<tt>#case#</tt>#%}% and %\texttt{%#<tt>#match#</tt>#%}% of ML and Haskell, and referring to the functions [plus] and [mult] from the Coq standard library.  The keyword [Definition] is Coq's all-purpose notation for binding a term of the programming language to a name, with some associated syntactic sugar, like the notation we see here for defining a function.  That sugar could be expanded to yield this definition:
adamc@9: 
adamc@9: [[
adamc@9: Definition binopDenote : binop -> nat -> nat -> nat := fun (b : binop) =>
adamc@9:   match b with
adamc@9:     | Plus => plus
adamc@9:     | Times => mult
adamc@9:   end.
adamc@9: 
adamc@205: ]]
adamc@205: 
adamc@9: In this example, we could also omit all of the type annotations, arriving at:
adamc@9: 
adamc@9: [[
adamc@9: Definition binopDenote := fun b =>
adamc@9:   match b with
adamc@9:     | Plus => plus
adamc@9:     | Times => mult
adamc@9:   end.
adamc@9: 
adamc@205: ]]
adamc@205: 
adam@314: Languages like Haskell and ML have a convenient %\index{principal types}\index{type inference}\emph{%#<i>#principal types#</i>#%}% property, which gives us strong guarantees about how effective type inference will be.  Unfortunately, Coq's type system is so expressive that any kind of %``%#"#complete#"#%''% type inference is impossible, and the task even seems to be hard heuristically in practice.  Nonetheless, Coq includes some very helpful heuristics, many of them copying the workings of Haskell and ML type-checkers for programs that fall in simple fragments of Coq's language.
adamc@9: 
adam@311: This is as good a time as any to mention the preponderance of different languages associated with Coq.  The theoretical foundation of Coq is a formal system called the %\index{Calculus of Inductive Constructions}\index{CIC|see{Calculus of Inductive Constructions}}\emph{%#<i>#Calculus of Inductive Constructions (CIC)#</i>#%}~\cite{CIC}%, which is an extension of the older %\index{Calculus of Constructions}\index{CoC|see{Calculus of Constructions}}\emph{%#<i>#Calculus of Constructions (CoC)#</i>#%}~\cite{CoC}%.  CIC is quite a spartan foundation, which is helpful for proving metatheory but not so helpful for real development.  Still, it is nice to know that it has been proved that CIC enjoys properties like %\index{strong normalization}\emph{%#<i>#strong normalization#</i>#%}~\cite{CIC}%, meaning that every program (and, more importantly, every proof term) terminates; and %\index{relative consistency}\emph{%#<i>#relative consistency#</i>#%}~\cite{SetsInTypes}% with systems like versions of %\index{Zermelo-Fraenkel set theory}%Zermelo-Fraenkel set theory, which roughly means that you can believe that Coq proofs mean that the corresponding propositions are %``%#"#really true,#"#%''% if you believe in set theory.
adamc@9: 
adam@311: Coq is actually based on an extension of CIC called %\index{Gallina}\emph{%#<i>#Gallina#</i>#%}%.  The text after the [:=] and before the period in the last code example is a term of Gallina.  Gallina adds many useful features that are not compiled internally to more primitive CIC features.  The important metatheorems about CIC have not been extended to the full breadth of these features, but most Coq users do not seem to lose much sleep over this omission.
adamc@9: 
adam@311: Next, there is %\index{Ltac}\emph{%#<i>#Ltac#</i>#%}%, Coq's domain-specific language for writing proofs and decision procedures. We will see some basic examples of Ltac later in this chapter, and much of this book is devoted to more involved Ltac examples.
adamc@9: 
adam@311: Finally, commands like [Inductive] and [Definition] are part of %\index{Vernacular commands}\emph{%#<i>#the Vernacular#</i>#%}%, which includes all sorts of useful queries and requests to the Coq system.  Every Coq source file is a series of vernacular commands, where many command forms take arguments that are Gallina or Ltac programs.  (Actually, Coq source files are more like %\emph{%#<i>#trees#</i>#%}% of vernacular commands, thanks to various nested scoping constructs.)
adamc@9: 
adamc@9: %\medskip%
adamc@9: 
adam@311: We can give a simple definition of the meaning of an expression:%\index{Vernacular commands!Fixpoint}% *)
adamc@9: 
adamc@4: Fixpoint expDenote (e : exp) : nat :=
adamc@4:   match e with
adamc@4:     | Const n => n
adamc@4:     | Binop b e1 e2 => (binopDenote b) (expDenote e1) (expDenote e2)
adamc@4:   end.
adamc@2: 
adamc@9: (** We declare explicitly that this is a recursive definition, using the keyword [Fixpoint].  The rest should be old hat for functional programmers. *)
adamc@2: 
adam@363: (** It is convenient to be able to test definitions before starting to prove things about them.  We can verify that our semantics is sensible by evaluating some sample uses, using the command %\index{Vernacular commands!Eval}%[Eval].  This command takes an argument expressing a %\index{reduction strategy}\emph{%#<i>#reduction strategy#</i>#%}%, or an %``%#"#order of evaluation.#"#%''%  Unlike with ML, which hardcodes an %\emph{%#<i>#eager#</i>#%}% reduction strategy, or Haskell, which hardcodes a %\emph{%#<i>#lazy#</i>#%}% strategy, in Coq we are free to choose between these and many other orders of evaluation, because all Coq programs terminate.  In fact, Coq silently checked %\index{termination checking}%termination of our [Fixpoint] definition above, using a simple heuristic based on monotonically decreasing size of arguments across recursive calls.  Specifically, recursive calls must be made on arguments that were pulled out of the original recursive argument with [match] expressions.  (In Chapter 7, we will see some ways of getting around this restriction, though simply removing the restriction would leave Coq useless as a theorem proving tool, for reasons we will start to learn about in the next chapter.)
adam@311: 
adam@311: To return to our test evaluations, we run the [Eval] command using the [simpl] evaluation strategy, whose definition is best postponed until we have learned more about Coq's foundations, but which usually gets the job done. *)
adamc@16: 
adamc@16: Eval simpl in expDenote (Const 42).
adamc@205: (** [= 42 : nat] *)
adamc@205: 
adamc@16: Eval simpl in expDenote (Binop Plus (Const 2) (Const 2)).
adamc@205: (** [= 4 : nat] *)
adamc@205: 
adamc@16: Eval simpl in expDenote (Binop Times (Binop Plus (Const 2) (Const 2)) (Const 7)).
adamc@205: (** [= 28 : nat] *)
adamc@9: 
adamc@20: (** ** Target Language *)
adamc@4: 
adamc@10: (** We will compile our source programs onto a simple stack machine, whose syntax is: *)
adamc@2: 
adamc@4: Inductive instr : Set :=
adam@311: | iConst : nat -> instr
adam@311: | iBinop : binop -> instr.
adamc@2: 
adamc@4: Definition prog := list instr.
adamc@4: Definition stack := list nat.
adamc@2: 
adamc@10: (** An instruction either pushes a constant onto the stack or pops two arguments, applies a binary operator to them, and pushes the result onto the stack.  A program is a list of instructions, and a stack is a list of natural numbers.
adamc@10: 
adam@311: We can give instructions meanings as functions from stacks to optional stacks, where running an instruction results in [None] in case of a stack underflow and results in [Some s'] when the result of execution is the new stack [s'].  %\index{Gallina operators!::}%The infix operator [::] is %``%#"#list cons#"#%''% from the Coq standard library.%\index{Gallina terms!option}% *)
adamc@10: 
adamc@4: Definition instrDenote (i : instr) (s : stack) : option stack :=
adamc@4:   match i with
adam@311:     | iConst n => Some (n :: s)
adam@311:     | iBinop b =>
adamc@4:       match s with
adamc@4:         | arg1 :: arg2 :: s' => Some ((binopDenote b) arg1 arg2 :: s')
adamc@4:         | _ => None
adamc@4:       end
adamc@4:   end.
adamc@2: 
adam@311: (** With [instrDenote] defined, it is easy to define a function [progDenote], which iterates application of [instrDenote] through a whole program. *)
adamc@206: 
adamc@206: Fixpoint progDenote (p : prog) (s : stack) : option stack :=
adamc@206:   match p with
adamc@206:     | nil => Some s
adamc@206:     | i :: p' =>
adamc@206:       match instrDenote i s with
adamc@206:         | None => None
adamc@206:         | Some s' => progDenote p' s'
adamc@206:       end
adamc@206:   end.
adamc@2: 
adamc@4: 
adamc@9: (** ** Translation *)
adamc@4: 
adam@311: (** Our compiler itself is now unsurprising.  The list concatenation operator %\index{Gallina operators!++}%[++] comes from the Coq standard library. *)
adamc@2: 
adamc@4: Fixpoint compile (e : exp) : prog :=
adamc@4:   match e with
adam@311:     | Const n => iConst n :: nil
adam@311:     | Binop b e1 e2 => compile e2 ++ compile e1 ++ iBinop b :: nil
adamc@4:   end.
adamc@2: 
adamc@2: 
adamc@16: (** Before we set about proving that this compiler is correct, we can try a few test runs, using our sample programs from earlier. *)
adamc@16: 
adamc@16: Eval simpl in compile (Const 42).
adam@311: (** [= iConst 42 :: nil : prog] *)
adamc@206: 
adamc@16: Eval simpl in compile (Binop Plus (Const 2) (Const 2)).
adam@311: (** [= iConst 2 :: iConst 2 :: iBinop Plus :: nil : prog] *)
adamc@206: 
adamc@16: Eval simpl in compile (Binop Times (Binop Plus (Const 2) (Const 2)) (Const 7)).
adam@311: (** [= iConst 7 :: iConst 2 :: iConst 2 :: iBinop Plus :: iBinop Times :: nil : prog] *)
adamc@16: 
adamc@40: (** We can also run our compiled programs and check that they give the right results. *)
adamc@16: 
adamc@16: Eval simpl in progDenote (compile (Const 42)) nil.
adamc@206: (** [= Some (42 :: nil) : option stack] *)
adamc@206: 
adamc@16: Eval simpl in progDenote (compile (Binop Plus (Const 2) (Const 2))) nil.
adamc@206: (** [= Some (4 :: nil) : option stack] *)
adamc@206: 
adam@311: Eval simpl in progDenote (compile (Binop Times (Binop Plus (Const 2) (Const 2))
adam@311:   (Const 7))) nil.
adamc@206: (** [= Some (28 :: nil) : option stack] *)
adamc@16: 
adamc@16: 
adamc@20: (** ** Translation Correctness *)
adamc@4: 
adam@311: (** We are ready to prove that our compiler is implemented correctly.  We can use a new vernacular command [Theorem] to start a correctness proof, in terms of the semantics we defined earlier:%\index{Vernacular commands!Theorem}% *)
adamc@11: 
adamc@26: Theorem compile_correct : forall e, progDenote (compile e) nil = Some (expDenote e :: nil).
adamc@11: (* begin hide *)
adamc@11: Abort.
adamc@11: (* end hide *)
adamc@22: (* begin thide *)
adamc@11: 
adam@311: (** Though a pencil-and-paper proof might clock out at this point, writing %``%#"#by a routine induction on [e],#"#%''% it turns out not to make sense to attack this proof directly.  We need to use the standard trick of %\index{strengthening the induction hypothesis}\emph{%#<i>#strengthening the induction hypothesis#</i>#%}%.  We do that by proving an auxiliary lemma, using the command [Lemma] that is a synonym for [Theorem], conventionally used for less important theorems that appear in the proofs of primary theorems.%\index{Vernacular commands!Lemma}% *)
adamc@2: 
adamc@206: Lemma compile_correct' : forall e p s,
adamc@206:   progDenote (compile e ++ p) s = progDenote p (expDenote e :: s).
adamc@11: 
adam@311: (** After the period in the [Lemma] command, we are in %\index{interactive proof-editing mode}\emph{%#<i>#the interactive proof-editing mode#</i>#%}%.  We find ourselves staring at this ominous screen of text:
adamc@11: 
adamc@11: [[
adamc@11: 1 subgoal
adamc@11:   
adamc@11:  ============================
adamc@15:   forall (e : exp) (p : list instr) (s : stack),
adamc@15:    progDenote (compile e ++ p) s = progDenote p (expDenote e :: s)  
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: Coq seems to be restating the lemma for us.  What we are seeing is a limited case of a more general protocol for describing where we are in a proof.  We are told that we have a single subgoal.  In general, during a proof, we can have many pending %\index{subgoals}%subgoals, each of which is a logical proposition to prove.  Subgoals can be proved in any order, but it usually works best to prove them in the order that Coq chooses.
adamc@11: 
adam@311: Next in the output, we see our single subgoal described in full detail.  There is a double-dashed line, above which would be our free variables and %\index{hypotheses}%hypotheses, if we had any.  Below the line is the %\index{conclusion}%conclusion, which, in general, is to be proved from the hypotheses.
adamc@11: 
adam@311: We manipulate the proof state by running commands called %\index{tactics}\emph{%#<i>#tactics#</i>#%}%.  Let us start out by running one of the most important tactics:%\index{tactics!induction}%
adamc@11: *)
adamc@11: 
adamc@4:   induction e.
adamc@2: 
adamc@11: (** We declare that this proof will proceed by induction on the structure of the expression [e].  This swaps out our initial subgoal for two new subgoals, one for each case of the inductive proof:
adamc@11: 
adam@311: %\vspace{.1in} \noindent 2 \coqdockw{subgoals}\vspace{-.1in}%#<tt>2 subgoals</tt>#
adam@311: 
adamc@11: [[
adamc@11:  n : nat
adamc@11:  ============================
adamc@11:  forall (s : stack) (p : list instr),
adamc@11:    progDenote (compile (Const n) ++ p) s =
adamc@11:    progDenote p (expDenote (Const n) :: s)
adamc@11: ]]
adam@311: %\noindent \coqdockw{subgoal} 2 \coqdockw{is}:%#<tt>subgoal 2 is</tt>#
adamc@11: [[
adamc@11:   forall (s : stack) (p : list instr),
adamc@11:     progDenote (compile (Binop b e1 e2) ++ p) s =
adamc@11:     progDenote p (expDenote (Binop b e1 e2) :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: The first and current subgoal is displayed with the double-dashed line below free variables and hypotheses, while later subgoals are only summarized with their conclusions.  We see an example of a %\index{free variable}%free variable in the first subgoal; [n] is a free variable of type [nat].  The conclusion is the original theorem statement where [e] has been replaced by [Const n].  In a similar manner, the second case has [e] replaced by a generalized invocation of the [Binop] expression constructor.  We can see that proving both cases corresponds to a standard proof by %\index{structural induction}%structural induction.
adamc@11: 
adam@311: We begin the first case with another very common tactic.%\index{tactics!intros}%
adamc@11: *)
adamc@11: 
adamc@4:   intros.
adamc@11: 
adamc@11: (** The current subgoal changes to:
adamc@11: [[
adamc@11: 
adamc@11:  n : nat
adamc@11:  s : stack
adamc@11:  p : list instr
adamc@11:  ============================
adamc@11:  progDenote (compile (Const n) ++ p) s =
adamc@11:  progDenote p (expDenote (Const n) :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adamc@11: We see that [intros] changes [forall]-bound variables at the beginning of a goal into free variables.
adamc@11: 
adam@311: To progress further, we need to use the definitions of some of the functions appearing in the goal.  The [unfold] tactic replaces an identifier with its definition.%\index{tactics!unfold}%
adamc@11: *)
adamc@11: 
adam@311: (* begin hide *)
adamc@4:   unfold compile.
adam@311: (* end hide *)
adam@311: (** %\coqdockw{unfold} \coqdocdefinition{compile}.%#<tt>unfold compile.</tt># *)
adamc@11: (** [[
adamc@11:  n : nat
adamc@11:  s : stack
adamc@11:  p : list instr
adamc@11:  ============================
adam@311:  progDenote ((iConst n :: nil) ++ p) s =
adamc@11:  progDenote p (expDenote (Const n) :: s)
adamc@206:  
adam@302: ]]
adam@302: *)
adamc@11: 
adam@311: (* begin hide *)
adamc@4:   unfold expDenote.
adam@311: (* end hide *)
adam@311: (** %\coqdockw{unfold} \coqdocdefinition{expDenote}.%#<tt>unfold expDenote.</tt># *)
adamc@11: (** [[
adamc@11:  n : nat
adamc@11:  s : stack
adamc@11:  p : list instr
adamc@11:  ============================
adam@311:  progDenote ((iConst n :: nil) ++ p) s = progDenote p (n :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: We only need to unfold the first occurrence of [progDenote] to prove the goal.  An [at] clause used with [unfold] specifies a particular occurrence of an identifier to unfold, where we count occurrences from left to right.%\index{tactics!unfold}% *)
adamc@11: 
adam@311: (* begin hide *)
adamc@11:   unfold progDenote at 1.
adam@311: (* end hide *)
adam@311: (** %\coqdockw{unfold} \coqdocdefinition{progDenote} \coqdoctac{at} 1.%#<tt>unfold progDenote at 1.</tt># *)
adamc@11: (** [[
adamc@11:  n : nat
adamc@11:  s : stack
adamc@11:  p : list instr
adamc@11:  ============================
adamc@11:   (fix progDenote (p0 : prog) (s0 : stack) {struct p0} : 
adamc@11:     option stack :=
adamc@11:       match p0 with
adamc@11:       | nil => Some s0
adamc@11:       | i :: p' =>
adamc@11:           match instrDenote i s0 with
adamc@11:           | Some s' => progDenote p' s'
adamc@11:           | None => None (A:=stack)
adamc@11:           end
adam@311:       end) ((iConst n :: nil) ++ p) s =
adamc@11:    progDenote p (n :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: This last [unfold] has left us with an anonymous fixpoint version of [progDenote], which will generally happen when unfolding recursive definitions.  Note that Coq has automatically renamed the [fix] arguments [p] and [s] to [p0] and [s0], to avoid clashes with our local free variables.  There is also a subterm %\coqdocconstructor{None} (\coqdocvar{A}:=\coqdocdefinition{stack})%#<tt>None (A:=stack)</tt>#, which has an annotation specifying that the type of the term ought to be [option A].  This is phrased as an explicit instantiation of a named type parameter [A] from the definition of [option].
adam@311: 
adam@311: Fortunately, in this case, we can eliminate the complications of anonymous recursion right away, since the structure of the argument ([iConst n :: nil) ++ p] is known, allowing us to simplify the internal pattern match with the [simpl] tactic, which applies the same reduction strategy that we used earlier with [Eval] (and whose details we still postpone).%\index{tactics!simpl}%
adamc@11: *)
adamc@11: 
adamc@4:   simpl.
adamc@11: (** [[
adamc@11:  n : nat
adamc@11:  s : stack
adamc@11:  p : list instr
adamc@11:  ============================
adamc@11:  (fix progDenote (p0 : prog) (s0 : stack) {struct p0} : 
adamc@11:   option stack :=
adamc@11:     match p0 with
adamc@11:     | nil => Some s0
adamc@11:     | i :: p' =>
adamc@11:         match instrDenote i s0 with
adamc@11:         | Some s' => progDenote p' s'
adamc@11:         | None => None (A:=stack)
adamc@11:         end
adamc@11:     end) p (n :: s) = progDenote p (n :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: Now we can unexpand the definition of [progDenote]:%\index{tactics!fold}%
adamc@11: *)
adamc@11: 
adam@311: (* begin hide *)
adamc@11:   fold progDenote.
adam@311: (* end hide *)
adam@311: (** %\coqdockw{fold} \coqdocdefinition{progDenote}.%#<tt>fold progDenote.</tt># *)
adamc@11: (** [[
adamc@11:  n : nat
adamc@11:  s : stack
adamc@11:  p : list instr
adamc@11:  ============================
adamc@11:  progDenote p (n :: s) = progDenote p (n :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: It looks like we are at the end of this case, since we have a trivial equality.  Indeed, a single tactic finishes us off:%\index{tactics!reflexivity}%
adamc@11: *)
adamc@11: 
adamc@4:   reflexivity.
adamc@2: 
adamc@11: (** On to the second inductive case:
adamc@11: 
adamc@11: [[
adamc@11:   b : binop
adamc@11:   e1 : exp
adamc@11:   IHe1 : forall (s : stack) (p : list instr),
adamc@11:          progDenote (compile e1 ++ p) s = progDenote p (expDenote e1 :: s)
adamc@11:   e2 : exp
adamc@11:   IHe2 : forall (s : stack) (p : list instr),
adamc@11:          progDenote (compile e2 ++ p) s = progDenote p (expDenote e2 :: s)
adamc@11:   ============================
adamc@11:    forall (s : stack) (p : list instr),
adamc@11:    progDenote (compile (Binop b e1 e2) ++ p) s =
adamc@11:    progDenote p (expDenote (Binop b e1 e2) :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: We see our first example of %\index{hypotheses}%hypotheses above the double-dashed line.  They are the inductive hypotheses [IHe1] and [IHe2] corresponding to the subterms [e1] and [e2], respectively.
adamc@11: 
adam@311: We start out the same way as before, introducing new free variables and unfolding and folding the appropriate definitions.  The seemingly frivolous [unfold]/%\coqdockw{fold}%#<tt>fold</tt># pairs are actually accomplishing useful work, because [unfold] will sometimes perform easy simplifications. %\index{tactics!intros}\index{tactics!unfold}\index{tactics!fold}% *)
adamc@11: 
adamc@4:   intros.
adam@311: (* begin hide *)
adamc@4:   unfold compile.
adamc@4:   fold compile.
adamc@4:   unfold expDenote.
adamc@4:   fold expDenote.
adam@311: (* end hide *)
adam@311: (** %\coqdockw{unfold} \coqdocdefinition{compile}.
adam@311: \coqdockw{fold} \coqdocdefinition{compile}.
adam@311: \coqdockw{unfold} \coqdocdefinition{expDenote}.
adam@311: \coqdockw{fold} \coqdocdefinition{expDenote}.%
adam@311:    #<tt>unfold compile. fold compile. unfold expDenote. fold expDenote.</tt># *)
adamc@11: 
adamc@44: (** Now we arrive at a point where the tactics we have seen so far are insufficient.  No further definition unfoldings get us anywhere, so we will need to try something different.
adamc@11: 
adamc@11: [[
adamc@11:   b : binop
adamc@11:   e1 : exp
adamc@11:   IHe1 : forall (s : stack) (p : list instr),
adamc@11:          progDenote (compile e1 ++ p) s = progDenote p (expDenote e1 :: s)
adamc@11:   e2 : exp
adamc@11:   IHe2 : forall (s : stack) (p : list instr),
adamc@11:          progDenote (compile e2 ++ p) s = progDenote p (expDenote e2 :: s)
adamc@11:   s : stack
adamc@11:   p : list instr
adamc@11:   ============================
adam@311:    progDenote ((compile e2 ++ compile e1 ++ iBinop b :: nil) ++ p) s =
adamc@11:    progDenote p (binopDenote b (expDenote e1) (expDenote e2) :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: What we need is the associative law of list concatenation, which is available as a theorem [app_assoc_reverse] in the standard library.%\index{Vernacular commands!Check}% *)
adamc@11: 
adam@311: Check app_assoc.
adam@311: 
adamc@11: (** [[
adam@311: app_assoc_reverse
adamc@11:      : forall (A : Type) (l m n : list A), (l ++ m) ++ n = l ++ m ++ n
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: If we did not already know the name of the theorem, we could use the %\index{Vernacular commands!SearchRewrite}\coqdockw{%#<tt>#SearchRewrite#</tt>#%}% command to find it, based on a pattern that we would like to rewrite: *)
adam@277: 
adam@311: (* begin hide *)
adam@277: SearchRewrite ((_ ++ _) ++ _).
adam@311: (* end hide *)
adam@311: (** %\coqdockw{%#<tt>#SearchRewrite#</tt>#%}% [((_ ++ _) ++ _).] *)
adam@277: (** [[
adam@311: app_assoc_reverse:
adam@311:   forall (A : Type) (l m n : list A), (l ++ m) ++ n = l ++ m ++ n
adam@311: ]]
adam@311: %\vspace{-.25in}%
adam@311: [[
adam@311: app_assoc: forall (A : Type) (l m n : list A), l ++ m ++ n = (l ++ m) ++ n
adam@277:  
adam@277: ]]
adam@277: 
adam@311: We use [app_assoc_reverse] to perform a rewrite: %\index{tactics!rewrite}% *)
adamc@11: 
adam@311:   rewrite app_assoc_reverse.
adamc@11: 
adamc@206: (** changing the conclusion to:
adamc@11: 
adamc@206: [[
adam@311:    progDenote (compile e2 ++ (compile e1 ++ iBinop b :: nil) ++ p) s =
adamc@11:    progDenote p (binopDenote b (expDenote e1) (expDenote e2) :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: Now we can notice that the lefthand side of the equality matches the lefthand side of the second inductive hypothesis, so we can rewrite with that hypothesis, too.%\index{tactics!rewrite}% *)
adamc@11: 
adamc@4:   rewrite IHe2.
adamc@11: (** [[
adam@311:    progDenote ((compile e1 ++ iBinop b :: nil) ++ p) (expDenote e2 :: s) =
adamc@11:    progDenote p (binopDenote b (expDenote e1) (expDenote e2) :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: The same process lets us apply the remaining hypothesis.%\index{tactics!rewrite}% *)
adamc@11: 
adam@311:   rewrite app_assoc_reverse.
adamc@4:   rewrite IHe1.
adamc@11: (** [[
adam@311:    progDenote ((iBinop b :: nil) ++ p) (expDenote e1 :: expDenote e2 :: s) =
adamc@11:    progDenote p (binopDenote b (expDenote e1) (expDenote e2) :: s)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: Now we can apply a similar sequence of tactics to the one that ended the proof of the first case.%\index{tactics!unfold}\index{tactics!simpl}\index{tactics!fold}\index{tactics!reflexivity}%
adamc@11: *)
adamc@11: 
adam@311: (* begin hide *)
adamc@11:   unfold progDenote at 1.
adamc@4:   simpl.
adamc@11:   fold progDenote.
adamc@4:   reflexivity.
adam@311: (* end hide *)
adam@311: (** %\coqdockw{unfold} \coqdocdefinition{progDenote} \coqdoctac{at} 1. \coqdockw{simpl}. \coqdockw{fold} \coqdocdefinition{progDenote}. \coqdockw{reflexivity}.%#<tt>unfold progDenote at 1. simpl. fold progDenote. reflexivity.</tt># *)
adamc@11: 
adam@311: (** And the proof is completed, as indicated by the message: *)
adamc@11: 
adam@311: (** %\coqdockw{Proof} \coqdockw{completed}.%#<tt>Proof completed.</tt># *)
adamc@11: 
adam@311: (** And there lies our first proof.  Already, even for simple theorems like this, the final proof script is unstructured and not very enlightening to readers.  If we extend this approach to more serious theorems, we arrive at the unreadable proof scripts that are the favorite complaints of opponents of tactic-based proving.  Fortunately, Coq has rich support for scripted automation, and we can take advantage of such a scripted tactic (defined elsewhere) to make short work of this lemma.  We abort the old proof attempt and start again.%\index{Vernacular commands!Abort}%
adamc@11: *)
adamc@11: 
adamc@4: Abort.
adamc@2: 
adam@311: (** %\index{tactics!induction}\index{tactics!crush}% *)
adam@311: 
adamc@26: Lemma compile_correct' : forall e s p, progDenote (compile e ++ p) s =
adamc@4:   progDenote p (expDenote e :: s).
adamc@4:   induction e; crush.
adamc@4: Qed.
adamc@2: 
adam@328: (** We need only to state the basic inductive proof scheme and call a tactic that automates the tedious reasoning in between.  In contrast to the period tactic terminator from our last proof, the %\index{tactics!semicolon}%semicolon tactic separator supports structured, compositional proofs.  The tactic [t1; t2] has the effect of running [t1] and then running [t2] on each remaining subgoal.  The semicolon is one of the most fundamental building blocks of effective proof automation.  The period terminator is very useful for exploratory proving, where you need to see intermediate proof states, but final proofs of any serious complexity should have just one period, terminating a single compound tactic that probably uses semicolons.
adamc@11: 
adamc@210: The [crush] tactic comes from the library associated with this book and is not part of the Coq standard library.  The book's library contains a number of other tactics that are especially helpful in highly-automated proofs.
adamc@210: 
adam@312: The %\index{Vernacular commands!Qed}%[Qed] command checks that the proof is finished and, if so, saves it.  The tactic commands we have written above are an example of a %\emph{%#<i>#proof script#</i>#%}%, or a series of Ltac programs; while [Qed] uses the result of the script to generate a %\emph{%#<i>#proof term#</i>#%}%, a well-typed term of Gallina.  To believe that a theorem is true, we only need to trust that the (relatively simple) checker for proof terms is correct; the use of proof scripts is immaterial.  Part I of this book will introduce the principles behind encoding all proofs as terms of Gallina.
adam@311: 
adam@311: The proof of our main theorem is now easy.  We prove it with four period-terminated tactics, though separating them with semicolons would work as well; the version here is easier to step through.%\index{tactics!intros}% *)
adamc@11: 
adamc@26: Theorem compile_correct : forall e, progDenote (compile e) nil = Some (expDenote e :: nil).
adamc@11:   intros.
adamc@11: (** [[
adamc@11:   e : exp
adamc@11:   ============================
adamc@11:    progDenote (compile e) nil = Some (expDenote e :: nil)
adamc@206:  
adamc@11: ]]
adamc@11: 
adamc@26: At this point, we want to massage the lefthand side to match the statement of [compile_correct'].  A theorem from the standard library is useful: *)
adamc@11: 
adamc@11: Check app_nil_end.
adamc@11: (** [[
adamc@11: app_nil_end
adamc@11:      : forall (A : Type) (l : list A), l = l ++ nil
adam@302: ]]
adam@311: %\index{tactics!rewrite}% *)
adamc@11: 
adamc@4:   rewrite (app_nil_end (compile e)).
adamc@11: 
adamc@11: (** This time, we explicitly specify the value of the variable [l] from the theorem statement, since multiple expressions of list type appear in the conclusion.  [rewrite] might choose the wrong place to rewrite if we did not specify which we want.
adamc@11: 
adamc@11: [[
adamc@11:   e : exp
adamc@11:   ============================
adamc@11:    progDenote (compile e ++ nil) nil = Some (expDenote e :: nil)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: Now we can apply the lemma.%\index{tactics!rewrite}% *)
adamc@11: 
adamc@26:   rewrite compile_correct'.
adamc@11: (** [[
adamc@11:   e : exp
adamc@11:   ============================
adamc@11:    progDenote nil (expDenote e :: nil) = Some (expDenote e :: nil)
adamc@206:  
adamc@11: ]]
adamc@11: 
adam@311: We are almost done.  The lefthand and righthand sides can be seen to match by simple symbolic evaluation.  That means we are in luck, because Coq identifies any pair of terms as equal whenever they normalize to the same result by symbolic evaluation.  By the definition of [progDenote], that is the case here, but we do not need to worry about such details.  A simple invocation of %\index{tactics!reflexivity}%[reflexivity] does the normalization and checks that the two results are syntactically equal.%\index{tactics!reflexivity}% *)
adamc@11: 
adamc@4:   reflexivity.
adamc@4: Qed.
adamc@22: (* end thide *)
adamc@14: 
adam@311: (** This proof can be shortened and made automated, but we leave that as an exercise for the reader. *)
adam@311: 
adamc@14: 
adamc@20: (** * Typed Expressions *)
adamc@14: 
adamc@14: (** In this section, we will build on the initial example by adding additional expression forms that depend on static typing of terms for safety. *)
adamc@14: 
adamc@20: (** ** Source Language *)
adamc@14: 
adamc@15: (** We define a trivial language of types to classify our expressions: *)
adamc@15: 
adamc@14: Inductive type : Set := Nat | Bool.
adamc@14: 
adam@277: (** Like most programming languages, Coq uses case-sensitive variable names, so that our user-defined type [type] is distinct from the [Type] keyword that we have already seen appear in the statement of a polymorphic theorem (and that we will meet in more detail later), and our constructor names [Nat] and [Bool] are distinct from the types [nat] and [bool] in the standard library.
adam@277: 
adam@277:    Now we define an expanded set of binary operators. *)
adamc@15: 
adamc@14: Inductive tbinop : type -> type -> type -> Set :=
adamc@14: | TPlus : tbinop Nat Nat Nat
adamc@14: | TTimes : tbinop Nat Nat Nat
adamc@14: | TEq : forall t, tbinop t t Bool
adamc@14: | TLt : tbinop Nat Nat Bool.
adamc@14: 
adam@307: (** The definition of [tbinop] is different from [binop] in an important way.  Where we declared that [binop] has type [Set], here we declare that [tbinop] has type [type -> type -> type -> Set].  We define [tbinop] as an %\emph{%#<i>#indexed type family#</i>#%}%.  Indexed inductive types are at the heart of Coq's expressive power; almost everything else of interest is defined in terms of them.
adamc@15: 
adam@312: The inuitive explanation of [tbinop] is that a [tbinop t1 t2 t] is a binary operator whose operands should have types [t1] and [t2], and whose result has type [t].  For instance, constructor [TLt] (for less-than comparison of numbers) is assigned type [tbinop Nat Nat Bool], meaning the operator's arguments are naturals and its result is boolean.  The type of [TEq] introduces a small bit of additional complication via polymorphism: we want to allow equality comparison of any two values of any type, as long as they have the %\emph{%#<i>#same#</i>#%}% type.
adam@312: 
adamc@15: ML and Haskell have indexed algebraic datatypes.  For instance, their list types are indexed by the type of data that the list carries.  However, compared to Coq, ML and Haskell 98 place two important restrictions on datatype definitions.
adamc@15: 
adam@312: First, the indices of the range of each data constructor must be type variables bound at the top level of the datatype definition.  There is no way to do what we did here, where we, for instance, say that [TPlus] is a constructor building a [tbinop] whose indices are all fixed at [Nat].  %\index{generalized algebraic datatypes}\index{GADTs|see{generalized algebraic datatypes}}\emph{%#<i>#Generalized algebraic datatypes (GADTs)#</i>#%}~\cite{GADT}% are a popular feature in %\index{GHC Haskell}%GHC Haskell and other languages that removes this first restriction.
adamc@15: 
adam@312: The second restriction is not lifted by GADTs.  In ML and Haskell, indices of types must be types and may not be %\emph{%#<i>#expressions#</i>#%}%.  In Coq, types may be indexed by arbitrary Gallina terms.  Type indices can live in the same universe as programs, and we can compute with them just like regular programs.  Haskell supports a hobbled form of computation in type indices based on %\index{Haskell}%multi-parameter type classes, and recent extensions like type functions bring Haskell programming even closer to %``%#"#real#"#%''% functional programming with types, but, without dependent typing, there must always be a gap between how one programs with types and how one programs normally.
adamc@15: *)
adamc@15: 
adam@312: (** We can define a similar type family for typed expressions, where a term of type [texp t] can be assigned object language type [t].  (It is conventional in the world of interactive theorem proving to call the language of the proof assistant the %\index{meta language}\emph{%#<i>#meta language#</i>#%}% and a language being formalized the %\index{object language}\emph{%#<i>#object language#</i>#%}%.) *)
adamc@15: 
adamc@14: Inductive texp : type -> Set :=
adamc@14: | TNConst : nat -> texp Nat
adamc@14: | TBConst : bool -> texp Bool
adam@312: | TBinop : forall t1 t2 t, tbinop t1 t2 t -> texp t1 -> texp t2 -> texp t.
adamc@14: 
adamc@15: (** Thanks to our use of dependent types, every well-typed [texp] represents a well-typed source expression, by construction.  This turns out to be very convenient for many things we might want to do with expressions.  For instance, it is easy to adapt our interpreter approach to defining semantics.  We start by defining a function mapping the types of our languages into Coq types: *)
adamc@15: 
adamc@14: Definition typeDenote (t : type) : Set :=
adamc@14:   match t with
adamc@14:     | Nat => nat
adamc@14:     | Bool => bool
adamc@14:   end.
adamc@14: 
adam@312: (** It can take a few moments to come to terms with the fact that [Set], the type of types of programs, is itself a first-class type, and that we can write functions that return [Set]s.  Past that wrinkle, the definition of [typeDenote] is trivial, relying on the [nat] and [bool] types from the Coq standard library.  We can interpret binary operators by relying on standard-library equality test functions [eqb] and [beq_nat] for booleans and naturals, respectively, along with a less-than test [leb]: *)
adamc@15: 
adamc@207: Definition tbinopDenote arg1 arg2 res (b : tbinop arg1 arg2 res)
adamc@207:   : typeDenote arg1 -> typeDenote arg2 -> typeDenote res :=
adamc@207:   match b with
adamc@207:     | TPlus => plus
adamc@207:     | TTimes => mult
adam@277:     | TEq Nat => beq_nat
adam@277:     | TEq Bool => eqb
adam@312:     | TLt => leb
adamc@207:   end.
adamc@207: 
adam@312: (** This function has just a few differences from the denotation functions we saw earlier.  First, [tbinop] is an indexed type, so its indices become additional arguments to [tbinopDenote].  Second, we need to perform a genuine %\index{dependent pattern matching}\emph{%#<i>#dependent pattern match#</i>#%}%, where the necessary %\emph{%#<i>#type#</i>#%}% of each case body depends on the %\emph{%#<i>#value#</i>#%}% that has been matched.  At this early stage, we will not go into detail on the many subtle aspects of Gallina that support dependent pattern-matching, but the subject is central to Part II of the book.
adam@312: 
adamc@15: The same tricks suffice to define an expression denotation function in an unsurprising way:
adamc@15: *)
adamc@15: 
adamc@207: Fixpoint texpDenote t (e : texp t) : typeDenote t :=
adamc@207:   match e with
adamc@14:     | TNConst n => n
adamc@14:     | TBConst b => b
adamc@14:     | TBinop _ _ _ b e1 e2 => (tbinopDenote b) (texpDenote e1) (texpDenote e2)
adamc@14:   end.
adamc@14: 
adamc@17: (** We can evaluate a few example programs to convince ourselves that this semantics is correct. *)
adamc@17: 
adamc@17: Eval simpl in texpDenote (TNConst 42).
adamc@207: (** [= 42 : typeDenote Nat] *)
adamc@207: 
adamc@17: Eval simpl in texpDenote (TBConst true).
adamc@207: (** [= true : typeDenote Bool] *)
adamc@207: 
adam@312: Eval simpl in texpDenote (TBinop TTimes (TBinop TPlus (TNConst 2) (TNConst 2))
adam@312:   (TNConst 7)).
adamc@207: (** [= 28 : typeDenote Nat] *)
adamc@207: 
adam@312: Eval simpl in texpDenote (TBinop (TEq Nat) (TBinop TPlus (TNConst 2) (TNConst 2))
adam@312:   (TNConst 7)).
adam@312: (** [= ] %\coqdocconstructor{%#<tt>#false#</tt>#%}% [ : typeDenote Bool] *)
adamc@207: 
adam@312: Eval simpl in texpDenote (TBinop TLt (TBinop TPlus (TNConst 2) (TNConst 2))
adam@312:   (TNConst 7)).
adamc@207: (** [= true : typeDenote Bool] *)
adamc@17: 
adamc@14: 
adamc@20: (** ** Target Language *)
adamc@14: 
adam@292: (** Now we want to define a suitable stack machine target for compilation.  In the example of the untyped language, stack machine programs could encounter stack underflows and %``%#"#get stuck.#"#%''%  This was unfortunate, since we had to deal with this complication even though we proved that our compiler never produced underflowing programs.  We could have used dependent types to force all stack machine programs to be underflow-free.
adamc@18: 
adamc@18: For our new languages, besides underflow, we also have the problem of stack slots with naturals instead of bools or vice versa.  This time, we will use indexed typed families to avoid the need to reason about potential failures.
adamc@18: 
adamc@18: We start by defining stack types, which classify sets of possible stacks. *)
adamc@18: 
adamc@14: Definition tstack := list type.
adamc@14: 
adamc@18: (** Any stack classified by a [tstack] must have exactly as many elements, and each stack element must have the type found in the same position of the stack type.
adamc@18: 
adamc@18: We can define instructions in terms of stack types, where every instruction's type tells us what initial stack type it expects and what final stack type it will produce. *)
adamc@18: 
adamc@14: Inductive tinstr : tstack -> tstack -> Set :=
adam@312: | TiNConst : forall s, nat -> tinstr s (Nat :: s)
adam@312: | TiBConst : forall s, bool -> tinstr s (Bool :: s)
adam@311: | TiBinop : forall arg1 arg2 res s,
adamc@14:   tbinop arg1 arg2 res
adamc@14:   -> tinstr (arg1 :: arg2 :: s) (res :: s).
adamc@14: 
adamc@18: (** Stack machine programs must be a similar inductive family, since, if we again used the [list] type family, we would not be able to guarantee that intermediate stack types match within a program. *)
adamc@18: 
adamc@14: Inductive tprog : tstack -> tstack -> Set :=
adamc@14: | TNil : forall s, tprog s s
adamc@14: | TCons : forall s1 s2 s3,
adamc@14:   tinstr s1 s2
adamc@14:   -> tprog s2 s3
adamc@14:   -> tprog s1 s3.
adamc@14: 
adamc@18: (** Now, to define the semantics of our new target language, we need a representation for stacks at runtime.  We will again take advantage of type information to define types of value stacks that, by construction, contain the right number and types of elements. *)
adamc@18: 
adamc@14: Fixpoint vstack (ts : tstack) : Set :=
adamc@14:   match ts with
adamc@14:     | nil => unit
adamc@14:     | t :: ts' => typeDenote t * vstack ts'
adamc@14:   end%type.
adamc@14: 
adam@312: (** This is another [Set]-valued function.  This time it is recursive, which is perfectly valid, since [Set] is not treated specially in determining which functions may be written.  We say that the value stack of an empty stack type is any value of type [unit], which has just a single value, [tt].  A nonempty stack type leads to a value stack that is a pair, whose first element has the proper type and whose second element follows the representation for the remainder of the stack type.  We write [%]%\index{notation scopes}\coqdocvar{%#<tt>#type#</tt>#%}% as an instruction to Coq's extensible parser.  In particular, this directive applies to the whole [match] expression, which we ask to be parsed as though it were a type, so that the operator [*] is interpreted as Cartesian product instead of, say, multiplication.  (Note that this use of %\coqdocvar{%#<tt>#type#</tt>#%}% has no connection to the inductive type [type] that we have defined.)
adamc@18: 
adam@312: This idea of programming with types can take a while to internalize, but it enables a very simple definition of instruction denotation.  Our definition is like what you might expect from a Lisp-like version of ML that ignored type information.  Nonetheless, the fact that [tinstrDenote] passes the type-checker guarantees that our stack machine programs can never go wrong.  We use a special form of [let] to destructure a multi-level tuple. *)
adamc@18: 
adamc@14: Definition tinstrDenote ts ts' (i : tinstr ts ts') : vstack ts -> vstack ts' :=
adamc@207:   match i with
adam@312:     | TiNConst _ n => fun s => (n, s)
adam@312:     | TiBConst _ b => fun s => (b, s)
adam@311:     | TiBinop _ _ _ _ b => fun s =>
adam@312:       let '(arg1, (arg2, s')) := s in
adam@312:         ((tbinopDenote b) arg1 arg2, s')
adamc@14:   end.
adamc@14: 
adamc@18: (** Why do we choose to use an anonymous function to bind the initial stack in every case of the [match]?  Consider this well-intentioned but invalid alternative version:
adamc@18: [[
adamc@18: Definition tinstrDenote ts ts' (i : tinstr ts ts') (s : vstack ts) : vstack ts' :=
adamc@207:   match i with
adam@312:     | TiNConst _ n => (n, s)
adam@312:     | TiBConst _ b => (b, s)
adam@311:     | TiBinop _ _ _ _ b =>
adam@312:       let '(arg1, (arg2, s')) := s in
adam@312:         ((tbinopDenote b) arg1 arg2, s')
adamc@18:   end.
adamc@18: 
adamc@205: ]]
adamc@205: 
adamc@18: The Coq type-checker complains that:
adamc@18: 
adam@312: <<
adamc@18: The term "(n, s)" has type "(nat * vstack ts)%type"
adamc@207:  while it is expected to have type "vstack ?119".
adam@312: >>
adamc@207: 
adam@312: This and other mysteries of Coq dependent typing we postpone until Part II of the book.  The upshot of our later discussion is that it is often useful to push inside of [match] branches those function parameters whose types depend on the type of the value being matched.  Our later, more complete treatement of Gallina's typing rules will explain why this helps.
adamc@18: *)
adamc@18: 
adamc@18: (** We finish the semantics with a straightforward definition of program denotation. *)
adamc@18: 
adamc@207: Fixpoint tprogDenote ts ts' (p : tprog ts ts') : vstack ts -> vstack ts' :=
adamc@207:   match p with
adamc@14:     | TNil _ => fun s => s
adamc@14:     | TCons _ _ _ i p' => fun s => tprogDenote p' (tinstrDenote i s)
adamc@14:   end.
adamc@14: 
adamc@14: 
adamc@14: (** ** Translation *)
adamc@14: 
adamc@19: (** To define our compilation, it is useful to have an auxiliary function for concatenating two stack machine programs. *)
adamc@19: 
adamc@207: Fixpoint tconcat ts ts' ts'' (p : tprog ts ts') : tprog ts' ts'' -> tprog ts ts'' :=
adamc@207:   match p with
adamc@14:     | TNil _ => fun p' => p'
adamc@14:     | TCons _ _ _ i p1 => fun p' => TCons i (tconcat p1 p')
adamc@14:   end.
adamc@14: 
adamc@19: (** With that function in place, the compilation is defined very similarly to how it was before, modulo the use of dependent typing. *)
adamc@19: 
adamc@207: Fixpoint tcompile t (e : texp t) (ts : tstack) : tprog ts (t :: ts) :=
adamc@207:   match e with
adam@312:     | TNConst n => TCons (TiNConst _ n) (TNil _)
adam@312:     | TBConst b => TCons (TiBConst _ b) (TNil _)
adamc@14:     | TBinop _ _ _ b e1 e2 => tconcat (tcompile e2 _)
adam@311:       (tconcat (tcompile e1 _) (TCons (TiBinop _ b) (TNil _)))
adamc@14:   end.
adamc@14: 
adam@307: (** One interesting feature of the definition is the underscores appearing to the right of [=>] arrows.  Haskell and ML programmers are quite familiar with compilers that infer type parameters to polymorphic values.  In Coq, it is possible to go even further and ask the system to infer arbitrary terms, by writing underscores in place of specific values.  You may have noticed that we have been calling functions without specifying all of their arguments.  For instance, the recursive calls here to [tcompile] omit the [t] argument.  Coq's %\emph{%#<i>#implicit argument#</i>#%}% mechanism automatically inserts underscores for arguments that it will probably be able to infer.  Inference of such values is far from complete, though; generally, it only works in cases similar to those encountered with polymorphic type instantiation in Haskell and ML.
adamc@19: 
adamc@19: The underscores here are being filled in with stack types.  That is, the Coq type inferencer is, in a sense, inferring something about the flow of control in the translated programs.  We can take a look at exactly which values are filled in: *)
adamc@19: 
adamc@14: Print tcompile.
adamc@19: (** [[
adamc@19: tcompile = 
adamc@19: fix tcompile (t : type) (e : texp t) (ts : tstack) {struct e} :
adamc@19:   tprog ts (t :: ts) :=
adamc@19:   match e in (texp t0) return (tprog ts (t0 :: ts)) with
adam@312:   | TNConst n => TCons (TiNConst ts n) (TNil (Nat :: ts))
adam@312:   | TBConst b => TCons (TiBConst ts b) (TNil (Bool :: ts))
adamc@19:   | TBinop arg1 arg2 res b e1 e2 =>
adamc@19:       tconcat (tcompile arg2 e2 ts)
adamc@19:         (tconcat (tcompile arg1 e1 (arg2 :: ts))
adam@311:            (TCons (TiBinop ts b) (TNil (res :: ts))))
adamc@19:   end
adamc@19:      : forall t : type, texp t -> forall ts : tstack, tprog ts (t :: ts)
adam@302: ]]
adam@302: *)
adamc@19: 
adamc@19: 
adamc@19: (** We can check that the compiler generates programs that behave appropriately on our sample programs from above: *)
adamc@19: 
adamc@19: Eval simpl in tprogDenote (tcompile (TNConst 42) nil) tt.
adam@312: (** [= (42, tt) : vstack (][Nat :: nil)] *)
adamc@207: 
adamc@19: Eval simpl in tprogDenote (tcompile (TBConst true) nil) tt.
adam@312: (** [= (][true][, tt) : vstack (][Bool :: nil)] *)
adamc@207: 
adam@312: Eval simpl in tprogDenote (tcompile (TBinop TTimes (TBinop TPlus (TNConst 2)
adam@312:   (TNConst 2)) (TNConst 7)) nil) tt.
adam@312: (** [= (28, tt) : vstack (][Nat :: nil)] *)
adamc@207: 
adam@312: Eval simpl in tprogDenote (tcompile (TBinop (TEq Nat) (TBinop TPlus (TNConst 2)
adam@312:   (TNConst 2)) (TNConst 7)) nil) tt.
adam@312: (** [= (]%\coqdocconstructor{%#<tt>#false#</tt>#%}%[, tt) : vstack (][Bool :: nil)] *)
adamc@207: 
adam@312: Eval simpl in tprogDenote (tcompile (TBinop TLt (TBinop TPlus (TNConst 2) (TNConst 2))
adam@312:   (TNConst 7)) nil) tt.
adam@312: (** [= (][true][, tt) : vstack (][Bool :: nil)] *)
adamc@19: 
adamc@14: 
adamc@20: (** ** Translation Correctness *)
adamc@20: 
adamc@20: (** We can state a correctness theorem similar to the last one. *)
adamc@20: 
adamc@207: Theorem tcompile_correct : forall t (e : texp t),
adamc@207:   tprogDenote (tcompile e nil) tt = (texpDenote e, tt).
adamc@20: (* begin hide *)
adamc@20: Abort.
adamc@20: (* end hide *)
adamc@22: (* begin thide *)
adamc@20: 
adam@312: (** Again, we need to strengthen the theorem statement so that the induction will go through.  This time, to provide an excuse to demonstrate different tactics, I will develop an alternative approach to this kind of proof, stating the key lemma as: *)
adamc@14: 
adamc@207: Lemma tcompile_correct' : forall t (e : texp t) ts (s : vstack ts),
adamc@207:   tprogDenote (tcompile e ts) s = (texpDenote e, s).
adamc@20: 
adam@394: (** While lemma [compile_correct'] quantified over a program that is the %``%#"#continuation#"#%''~\cite{continuations}% for the expression we are considering, here we avoid drawing in any extra syntactic elements.  In addition to the source expression and its type, we also quantify over an initial stack type and a stack compatible with it.  Running the compilation of the program starting from that stack, we should arrive at a stack that differs only in having the program's denotation pushed onto it.
adamc@20: 
adamc@20:    Let us try to prove this theorem in the same way that we settled on in the last section. *)
adamc@20: 
adamc@14:   induction e; crush.
adamc@20: 
adamc@20: (** We are left with this unproved conclusion:
adamc@20: 
adamc@20: [[
adamc@20: tprogDenote
adamc@20:      (tconcat (tcompile e2 ts)
adamc@20:         (tconcat (tcompile e1 (arg2 :: ts))
adam@311:            (TCons (TiBinop ts t) (TNil (res :: ts))))) s =
adamc@20:    (tbinopDenote t (texpDenote e1) (texpDenote e2), s)
adamc@207:  
adamc@20: ]]
adamc@20: 
adam@312: We need an analogue to the [app_assoc_reverse] theorem that we used to rewrite the goal in the last section.  We can abort this proof and prove such a lemma about [tconcat].
adamc@20: *)
adamc@207: 
adamc@14: Abort.
adamc@14: 
adamc@26: Lemma tconcat_correct : forall ts ts' ts'' (p : tprog ts ts') (p' : tprog ts' ts'')
adamc@14:   (s : vstack ts),
adamc@14:   tprogDenote (tconcat p p') s
adamc@14:   = tprogDenote p' (tprogDenote p s).
adamc@14:   induction p; crush.
adamc@14: Qed.
adamc@14: 
adamc@20: (** This one goes through completely automatically.
adamc@20: 
adam@316: Some code behind the scenes registers [app_assoc_reverse] for use by [crush].  We must register [tconcat_correct] similarly to get the same effect:%\index{Vernacular commands!Hint Rewrite}% *)
adamc@20: 
adam@312: (* begin hide *)
adam@375: Hint Rewrite tconcat_correct.
adam@312: (* end hide *)
adam@375: (** %\noindent%[Hint] %\coqdockw{%#<tt>#Rewrite#</tt>#%}% [tconcat_correct.] *)
adamc@14: 
adam@312: (** Here we meet the pervasive concept of a %\emph{%#<i>#hint#</i>#%}%.  Many proofs can be found through exhaustive enumerations of combinations of possible proof steps; hints provide the set of steps to consider.  The tactic [crush] is applying such brute force search for us silently, and it will consider more possibilities as we add more hints.  This particular hint asks that the lemma be used for left-to-right rewriting, and we ask for the hint to be added to the hint database called [cpdt], which is the database used by [crush].  In general, segragating hints into different databases is helpful to control the performance of proof search, in cases where domain knowledge allows us to narrow the set of proof steps to be considered in brute force search.  Part III of this book considers such pragmatic aspects of proof search in much more detail.
adam@312: 
adam@312: Now we are ready to return to [tcompile_correct'], proving it automatically this time. *)
adamc@20: 
adamc@207: Lemma tcompile_correct' : forall t (e : texp t) ts (s : vstack ts),
adamc@207:   tprogDenote (tcompile e ts) s = (texpDenote e, s).
adamc@14:   induction e; crush.
adamc@14: Qed.
adamc@14: 
adamc@20: (** We can register this main lemma as another hint, allowing us to prove the final theorem trivially. *)
adamc@20: 
adam@312: (* begin hide *)
adam@375: Hint Rewrite tcompile_correct'.
adam@312: (* end hide *)
adam@375: (** %\noindent%[Hint ]%\coqdockw{%#<tt>#Rewrite#</tt>#%}%[ tcompile_correct'.] *)
adamc@14: 
adamc@207: Theorem tcompile_correct : forall t (e : texp t),
adamc@207:   tprogDenote (tcompile e nil) tt = (texpDenote e, tt).
adamc@14:   crush.
adamc@14: Qed.
adamc@22: (* end thide *)
adam@312: 
adam@312: (** It is probably worth emphasizing that we are doing more than building mathematical models.  Our compilers are functional programs that can be executed efficiently.  One strategy for doing so is based on %\index{program extraction}\emph{%#<i>#program extraction#</i>#%}%, which generates OCaml code from Coq developments.  For instance, we run a command to output the OCaml version of [tcompile]:%\index{Vernacular commands!Extraction}% *)
adam@312: 
adam@312: (* begin hide *)
adam@312: Extraction tcompile.
adam@312: (* end hide *)
adam@312: (** %\noindent\coqdockw{%#<tt>#Extraction#</tt>#%}%[ tcompile.] *)
adam@312: 
adam@312: (** <<
adam@312: let rec tcompile t e ts =
adam@312:   match e with
adam@312:   | TNConst n ->
adam@312:     TCons (ts, (Cons (Nat, ts)), (Cons (Nat, ts)), (TiNConst (ts, n)), (TNil
adam@312:       (Cons (Nat, ts))))
adam@312:   | TBConst b ->
adam@312:     TCons (ts, (Cons (Bool, ts)), (Cons (Bool, ts)), (TiBConst (ts, b)),
adam@312:       (TNil (Cons (Bool, ts))))
adam@312:   | TBinop (t1, t2, t0, b, e1, e2) ->
adam@312:     tconcat ts (Cons (t2, ts)) (Cons (t0, ts)) (tcompile t2 e2 ts)
adam@312:       (tconcat (Cons (t2, ts)) (Cons (t1, (Cons (t2, ts)))) (Cons (t0, ts))
adam@312:         (tcompile t1 e1 (Cons (t2, ts))) (TCons ((Cons (t1, (Cons (t2,
adam@312:         ts)))), (Cons (t0, ts)), (Cons (t0, ts)), (TiBinop (t1, t2, t0, ts,
adam@312:         b)), (TNil (Cons (t0, ts))))))
adam@312: >>
adam@312: 
adam@312: We can compile this code with the usual OCaml compiler and obtain an executable program with halfway decent performance.
adam@312: 
adam@312: This chapter has been a whirlwind tour through two examples of the style of Coq development that I advocate.  Parts II and III of the book focus on the key elements of that style, namely dependent types and scripted proof automation, respectively.  Before we get there, we will spend some time in Part I on more standard foundational material.  Part I may still be of interest to seasoned Coq hackers, since I follow the highly automated proof style even at that early stage. *)