adamc@83: (* Copyright (c) 2008, Adam Chlipala
adamc@83:  * 
adamc@83:  * This work is licensed under a
adamc@83:  * Creative Commons Attribution-Noncommercial-No Derivative Works 3.0
adamc@83:  * Unported License.
adamc@83:  * The license text is available at:
adamc@83:  *   http://creativecommons.org/licenses/by-nc-nd/3.0/
adamc@83:  *)
adamc@83: 
adamc@83: (* begin hide *)
adamc@85: Require Import Arith Bool List.
adamc@83: 
adamc@86: Require Import Tactics MoreSpecif.
adamc@83: 
adamc@83: Set Implicit Arguments.
adamc@83: (* end hide *)
adamc@83: 
adamc@83: 
adamc@83: (** %\chapter{More Dependent Types}% *)
adamc@83: 
adamc@83: (** Subset types and their relatives help us integrate verification with programming.  Though they reorganize the certified programmer's workflow, they tend not to have deep effects on proofs.  We write largely the same proofs as we would for classical verification, with some of the structure moved into the programs themselves.  It turns out that, when we use dependent types to their full potential, we warp the development and proving process even more than that, picking up "free theorems" to the extent that often a certified program is hardly more complex than its uncertified counterpart in Haskell or ML.
adamc@83: 
adamc@83:    In particular, we have only scratched the tip of the iceberg that is Coq's inductive definition mechanism.  The inductive types we have seen so far have their counterparts in the other proof assistants that we surveyed in Chapter 1.  This chapter explores the strange new world of dependent inductive datatypes (that is, dependent inductive types outside [Prop]), a possibility which sets Coq apart from all of the competition not based on type theory. *)
adamc@83: 
adamc@84: 
adamc@84: (** * Length-Indexed Lists *)
adamc@84: 
adamc@84: (** Many introductions to dependent types start out by showing how to use them to eliminate array bounds checks.  When the type of an array tells you how many elements it has, your compiler can detect out-of-bounds dereferences statically.  Since we are working in a pure functional language, the next best thing is length-indexed lists, which the following code defines. *)
adamc@84: 
adamc@84: Section ilist.
adamc@84:   Variable A : Set.
adamc@84: 
adamc@84:   Inductive ilist : nat -> Set :=
adamc@84:   | Nil : ilist O
adamc@84:   | Cons : forall n, A -> ilist n -> ilist (S n).
adamc@84: 
adamc@84: (** We see that, within its section, [ilist] is given type [nat -> Set].  Previously, every inductive type we have seen has either had plain [Set] as its type or has been a predicate with some type ending in [Prop].  The full generality of inductive definitions lets us integrate the expressivity of predicates directly into our normal programming.
adamc@84: 
adamc@84:    The [nat] argument to [ilist] tells us the length of the list.  The types of [ilist]'s constructors tell us that a [Nil] list has length [O] and that a [Cons] list has length one greater than the length of its sublist.  We may apply [ilist] to any natural number, even natural numbers that are only known at runtime.  It is this breaking of the %\textit{%#<i>#phase distinction#</i>#%}% that characterizes [ilist] as %\textit{%#<i>#dependently typed#</i>#%}%.
adamc@84: 
adamc@84:    In expositions of list types, we usually see the length function defined first, but here that would not be a very productive function to code.  Instead, let us implement list concatenation.
adamc@84: 
adamc@84:    [[
adamc@84: Fixpoint app n1 (ls1 : ilist n1) n2 (ls2 : ilist n2) {struct ls1} : ilist (n1 + n2) :=
adamc@84:   match ls1 with
adamc@84:     | Nil => ls2
adamc@84:     | Cons _ x ls1' => Cons x (app ls1' ls2)
adamc@84:   end.
adamc@84: 
adamc@84:   Coq is not happy with this definition:
adamc@84: 
adamc@84: [[
adamc@84: The term "ls2" has type "ilist n2" while it is expected to have type
adamc@84:  "ilist (?14 + n2)"
adamc@84: ]]
adamc@84: 
adamc@84:   We see the return of a problem we have considered before.  Without explicit annotations, Coq does not enrich our typing assumptions in the branches of a [match] expression.  It is clear that the unification variable [?14] should be resolved to 0 in this context, so that we have [0 + n2] reducing to [n2], but Coq does not realize that.  We cannot fix the problem using just the simple [return] clauses we applied in the last chapter.  We need to combine a [return] clause with a new kind of annotation, an [in] clause. *)
adamc@84: 
adamc@100: (* EX: Implement concatenation *)
adamc@100: 
adamc@100: (* begin thide *)
adamc@84: Fixpoint app n1 (ls1 : ilist n1) n2 (ls2 : ilist n2) {struct ls1} : ilist (n1 + n2) :=
adamc@84:   match ls1 in (ilist n1) return (ilist (n1 + n2)) with
adamc@84:     | Nil => ls2
adamc@84:     | Cons _ x ls1' => Cons x (app ls1' ls2)
adamc@84:   end.
adamc@100: (* end thide *)
adamc@84: 
adamc@84: (** This version of [app] passes the type checker.  Using [return] alone allowed us to express a dependency of the [match] result type on the %\textit{%#<i>#value#</i>#%}% of the discriminee.  What [in] adds to our arsenal is a way of expressing a dependency on the %\textit{%#<i>#type#</i>#%}% of the discriminee.  Specifically, the [n1] in the [in] clause above is a %\textit{%#<i>#binding occurrence#</i>#%}% whose scope is the [return] clause.
adamc@84: 
adamc@84: We may use [in] clauses only to bind names for the arguments of an inductive type family.  That is, each [in] clause must be an inductive type family name applied to a sequence of underscores and variable names of the proper length.  The positions for %\textit{%#<i>#parameters#</i>#%}% to the type family must all be underscores.  Parameters are those arguments declared with section variables or with entries to the left of the first colon in an inductive definition.  They cannot vary depending on which constructor was used to build the discriminee, so Coq prohibits pointless matches on them.  It is those arguments defined in the type to the right of the colon that we may name with [in] clauses.
adamc@84: 
adamc@84: Our [app] function could be typed in so-called %\textit{%#<i>#stratified#</i>#%}% type systems, which avoid true dependency.  We could consider the length indices to lists to live in a separate, compile-time-only universe from the lists themselves.  Our next example would be harder to implement in a stratified system.  We write an injection function from regular lists to length-indexed lists.  A stratified implementation would need to duplicate the definition of lists across compile-time and run-time versions, and the run-time versions would need to be indexed by the compile-time versions. *)
adamc@84: 
adamc@100: (* EX: Implement injection from normal lists *)
adamc@100: 
adamc@100: (* begin thide *)
adamc@84: Fixpoint inject (ls : list A) : ilist (length ls) :=
adamc@84:   match ls return (ilist (length ls)) with
adamc@84:     | nil => Nil
adamc@84:     | h :: t => Cons h (inject t)
adamc@84:   end.
adamc@84: 
adamc@84: (** We can define an inverse conversion and prove that it really is an inverse. *)
adamc@84: 
adamc@84: Fixpoint unject n (ls : ilist n) {struct ls} : list A :=
adamc@84:   match ls with
adamc@84:     | Nil => nil
adamc@84:     | Cons _ h t => h :: unject t
adamc@84:   end.
adamc@84: 
adamc@84: Theorem inject_inverse : forall ls, unject (inject ls) = ls.
adamc@84:   induction ls; crush.
adamc@84: Qed.
adamc@100: (* end thide *)
adamc@100: 
adamc@100: (* EX: Implement statically-checked "car"/"hd" *)
adamc@84: 
adamc@84: (** Now let us attempt a function that is surprisingly tricky to write.  In ML, the list head function raises an exception when passed an empty list.  With length-indexed lists, we can rule out such invalid calls statically, and here is a first attempt at doing so.
adamc@84: 
adamc@84: [[
adamc@84: Definition hd n (ls : ilist (S n)) : A :=
adamc@84:   match ls with
adamc@84:     | Nil => ???
adamc@84:     | Cons _ h _ => h
adamc@84:   end.
adamc@84: 
adamc@84: It is not clear what to write for the [Nil] case, so we are stuck before we even turn our function over to the type checker.  We could try omitting the [Nil] case:
adamc@84: 
adamc@84: [[
adamc@84: Definition hd n (ls : ilist (S n)) : A :=
adamc@84:   match ls with
adamc@84:     | Cons _ h _ => h
adamc@84:   end.
adamc@84: 
adamc@84: [[
adamc@84: Error: Non exhaustive pattern-matching: no clause found for pattern Nil
adamc@84: ]]
adamc@84: 
adamc@84: Unlike in ML, we cannot use inexhaustive pattern matching, becuase there is no conception of a %\texttt{%#<tt>#Match#</tt>#%}% exception to be thrown.  We might try using an [in] clause somehow.
adamc@84: 
adamc@84: [[
adamc@84: Definition hd n (ls : ilist (S n)) : A :=
adamc@84:   match ls in (ilist (S n)) with
adamc@84:     | Cons _ h _ => h
adamc@84:   end.
adamc@84: 
adamc@84: [[
adamc@84: Error: The reference n was not found in the current environment
adamc@84: ]]
adamc@84: 
adamc@84: In this and other cases, we feel like we want [in] clauses with type family arguments that are not variables.  Unfortunately, Coq only supports variables in those positions.  A completely general mechanism could only be supported with a solution to the problem of higher-order unification, which is undecidable.  There %\textit{%#<i>#are#</i>#%}% useful heuristics for handling non-variable indices which are gradually making their way into Coq, but we will spend some time in this and the next few chapters on effective pattern matching on dependent types using only the primitive [match] annotations.
adamc@84: 
adamc@84: Our final, working attempt at [hd] uses an auxiliary function and a surprising [return] annotation. *)
adamc@84: 
adamc@100: (* begin thide *)
adamc@84: Definition hd' n (ls : ilist n) :=
adamc@84:   match ls in (ilist n) return (match n with O => unit | S _ => A end) with
adamc@84:     | Nil => tt
adamc@84:     | Cons _ h _ => h
adamc@84:   end.
adamc@84: 
adamc@84: Definition hd n (ls : ilist (S n)) : A := hd' ls.
adamc@100: (* end thide *)
adamc@84: 
adamc@84: (** We annotate our main [match] with a type that is itself a [match].  We write that the function [hd'] returns [unit] when the list is empty and returns the carried type [A] in all other cases.  In the definition of [hd], we just call [hd'].  Because the index of [ls] is known to be nonzero, the type checker reduces the [match] in the type of [hd'] to [A]. *)
adamc@84: 
adamc@84: End ilist.
adamc@85: 
adamc@85: 
adamc@85: (** * A Tagless Interpreter *)
adamc@85: 
adamc@85: (** A favorite example for motivating the power of functional programming is implementation of a simple expression language interpreter.  In ML and Haskell, such interpreters are often implemented using an algebraic datatype of values, where at many points it is checked that a value was built with the right constructor of the value type.  With dependent types, we can implement a %\textit{%#<i>#tagless#</i>#%}% interpreter that both removes this source of runtime ineffiency and gives us more confidence that our implementation is correct. *)
adamc@85: 
adamc@85: Inductive type : Set :=
adamc@85: | Nat : type
adamc@85: | Bool : type
adamc@85: | Prod : type -> type -> type.
adamc@85: 
adamc@85: Inductive exp : type -> Set :=
adamc@85: | NConst : nat -> exp Nat
adamc@85: | Plus : exp Nat -> exp Nat -> exp Nat
adamc@85: | Eq : exp Nat -> exp Nat -> exp Bool
adamc@85: 
adamc@85: | BConst : bool -> exp Bool
adamc@85: | And : exp Bool -> exp Bool -> exp Bool
adamc@85: | If : forall t, exp Bool -> exp t -> exp t -> exp t
adamc@85: 
adamc@85: | Pair : forall t1 t2, exp t1 -> exp t2 -> exp (Prod t1 t2)
adamc@85: | Fst : forall t1 t2, exp (Prod t1 t2) -> exp t1
adamc@85: | Snd : forall t1 t2, exp (Prod t1 t2) -> exp t2.
adamc@85: 
adamc@85: (** We have a standard algebraic datatype [type], defining a type language of naturals, booleans, and product (pair) types.  Then we have the indexed inductive type [exp], where the argument to [exp] tells us the encoded type of an expression.  In effect, we are defining the typing rules for expressions simultaneously with the syntax.
adamc@85: 
adamc@85:    We can give types and expressions semantics in a new style, based critically on the chance for %\textit{%#<i>#type-level computation#</i>#%}%. *)
adamc@85: 
adamc@85: Fixpoint typeDenote (t : type) : Set :=
adamc@85:   match t with
adamc@85:     | Nat => nat
adamc@85:     | Bool => bool
adamc@85:     | Prod t1 t2 => typeDenote t1 * typeDenote t2
adamc@85:   end%type.
adamc@85: 
adamc@85: (** [typeDenote] compiles types of our object language into "native" Coq types.  It is deceptively easy to implement.  The only new thing we see is the [%type] annotation, which tells Coq to parse the [match] expression using the notations associated with types.  Without this annotation, the [*] would be interpreted as multiplication on naturals, rather than as the product type constructor.  [type] is one example of an identifer bound to a %\textit{%#<i>#notation scope#</i>#%}%.  We will deal more explicitly with notations and notation scopes in later chapters.
adamc@85: 
adamc@85:    We can define a function [expDenote] that is typed in terms of [typeDenote]. *)
adamc@85: 
adamc@85: Fixpoint expDenote t (e : exp t) {struct e} : typeDenote t :=
adamc@85:   match e in (exp t) return (typeDenote t) with
adamc@85:     | NConst n => n
adamc@85:     | Plus e1 e2 => expDenote e1 + expDenote e2
adamc@85:     | Eq e1 e2 => if eq_nat_dec (expDenote e1) (expDenote e2) then true else false
adamc@85: 
adamc@85:     | BConst b => b
adamc@85:     | And e1 e2 => expDenote e1 && expDenote e2
adamc@85:     | If _ e' e1 e2 => if expDenote e' then expDenote e1 else expDenote e2
adamc@85: 
adamc@85:     | Pair _ _ e1 e2 => (expDenote e1, expDenote e2)
adamc@85:     | Fst _ _ e' => fst (expDenote e')
adamc@85:     | Snd _ _ e' => snd (expDenote e')
adamc@85:   end.
adamc@85: 
adamc@85: (** Again we find that an [in] annotation is essential for type-checking a function.  Besides that, the definition is routine.  In fact, it is less complicated than what we would write in ML or Haskell 98, since we do not need to worry about pushing final values in and out of an algebraic datatype.  The only unusual thing is the use of an expression of the form [if E then true else false] in the [Eq] case.  Remember that [eq_nat_dec] has a rich dependent type, rather than a simple boolean type.  Coq's native [if] is overloaded to work on a test of any two-constructor type, so we can use [if] to build a simple boolean from the [sumbool] that [eq_nat_dec] returns.
adamc@85: 
adamc@85:    We can implement our old favorite, a constant folding function, and prove it correct.  It will be useful to write a function [pairOut] that checks if an [exp] of [Prod] type is a pair, returning its two components if so.  Unsurprisingly, a first attempt leads to a type error.
adamc@85: 
adamc@85: [[
adamc@85: Definition pairOut t1 t2 (e : exp (Prod t1 t2)) : option (exp t1 * exp t2) :=
adamc@85:   match e in (exp (Prod t1 t2)) return option (exp t1 * exp t2) with
adamc@85:     | Pair _ _ e1 e2 => Some (e1, e2)
adamc@85:     | _ => None
adamc@85:   end.
adamc@85: 
adamc@85: [[
adamc@85: Error: The reference t2 was not found in the current environment
adamc@85: ]]
adamc@85: 
adamc@85: We run again into the problem of not being able to specify non-variable arguments in [in] clauses.  The problem would just be hopeless without a use of an [in] clause, though, since the result type of the [match] depends on an argument to [exp].  Our solution will be to use a more general type, as we did for [hd].  First, we define a type-valued function to use in assigning a type to [pairOut]. *)
adamc@85: 
adamc@100: (* EX: Define a function [pairOut : forall t1 t2, exp (Prod t1 t2) -> option (exp t1 * exp t2)] *)
adamc@100: 
adamc@100: (* begin thide *)
adamc@85: Definition pairOutType (t : type) :=
adamc@85:   match t with
adamc@85:     | Prod t1 t2 => option (exp t1 * exp t2)
adamc@85:     | _ => unit
adamc@85:   end.
adamc@85: 
adamc@85: (** When passed a type that is a product, [pairOutType] returns our final desired type.  On any other input type, [pairOutType] returns [unit], since we do not care about extracting components of non-pairs.  Now we can write another helper function to provide the default behavior of [pairOut], which we will apply for inputs that are not literal pairs. *)
adamc@85: 
adamc@85: Definition pairOutDefault (t : type) :=
adamc@85:   match t return (pairOutType t) with
adamc@85:     | Prod _ _ => None
adamc@85:     | _ => tt
adamc@85:   end.
adamc@85: 
adamc@85: (** Now [pairOut] is deceptively easy to write. *)
adamc@85: 
adamc@85: Definition pairOut t (e : exp t) :=
adamc@85:   match e in (exp t) return (pairOutType t) with
adamc@85:     | Pair _ _ e1 e2 => Some (e1, e2)
adamc@85:     | _ => pairOutDefault _
adamc@85:   end.
adamc@100: (* end thide *)
adamc@85: 
adamc@85: (** There is one important subtlety in this definition.  Coq allows us to use convenient ML-style pattern matching notation, but, internally and in proofs, we see that patterns are expanded out completely, matching one level of inductive structure at a time.  Thus, the default case in the [match] above expands out to one case for each constructor of [exp] besides [Pair], and the underscore in [pairOutDefault _] is resolved differently in each case.  From an ML or Haskell programmer's perspective, what we have here is type inference determining which code is run (returning either [None] or [tt]), which goes beyond what is possible with type inference guiding parametric polymorphism in Hindley-Milner languages, but is similar to what goes on with Haskell type classes.
adamc@85: 
adamc@85: With [pairOut] available, we can write [cfold] in a straightforward way.  There are really no surprises beyond that Coq verifies that this code has such an expressive type, given the small annotation burden. *)
adamc@85: 
adamc@204: Fixpoint cfold t (e : exp t) : exp t :=
adamc@204:   match e with
adamc@85:     | NConst n => NConst n
adamc@85:     | Plus e1 e2 =>
adamc@85:       let e1' := cfold e1 in
adamc@85:       let e2' := cfold e2 in
adamc@204:       match e1', e2' return _ with
adamc@85:         | NConst n1, NConst n2 => NConst (n1 + n2)
adamc@85:         | _, _ => Plus e1' e2'
adamc@85:       end
adamc@85:     | Eq e1 e2 =>
adamc@85:       let e1' := cfold e1 in
adamc@85:       let e2' := cfold e2 in
adamc@204:       match e1', e2' return _ with
adamc@85:         | NConst n1, NConst n2 => BConst (if eq_nat_dec n1 n2 then true else false)
adamc@85:         | _, _ => Eq e1' e2'
adamc@85:       end
adamc@85: 
adamc@85:     | BConst b => BConst b
adamc@85:     | And e1 e2 =>
adamc@85:       let e1' := cfold e1 in
adamc@85:       let e2' := cfold e2 in
adamc@204:       match e1', e2' return _ with
adamc@85:         | BConst b1, BConst b2 => BConst (b1 && b2)
adamc@85:         | _, _ => And e1' e2'
adamc@85:       end
adamc@85:     | If _ e e1 e2 =>
adamc@85:       let e' := cfold e in
adamc@85:       match e' with
adamc@85:         | BConst true => cfold e1
adamc@85:         | BConst false => cfold e2
adamc@85:         | _ => If e' (cfold e1) (cfold e2)
adamc@85:       end
adamc@85: 
adamc@85:     | Pair _ _ e1 e2 => Pair (cfold e1) (cfold e2)
adamc@85:     | Fst _ _ e =>
adamc@85:       let e' := cfold e in
adamc@85:       match pairOut e' with
adamc@85:         | Some p => fst p
adamc@85:         | None => Fst e'
adamc@85:       end
adamc@85:     | Snd _ _ e =>
adamc@85:       let e' := cfold e in
adamc@85:       match pairOut e' with
adamc@85:         | Some p => snd p
adamc@85:         | None => Snd e'
adamc@85:       end
adamc@85:   end.
adamc@85: 
adamc@85: (** The correctness theorem for [cfold] turns out to be easy to prove, once we get over one serious hurdle. *)
adamc@85: 
adamc@85: Theorem cfold_correct : forall t (e : exp t), expDenote e = expDenote (cfold e).
adamc@100: (* begin thide *)
adamc@85:   induction e; crush.
adamc@85: 
adamc@85: (** The first remaining subgoal is:
adamc@85: 
adamc@85:    [[
adamc@85: 
adamc@85:   expDenote (cfold e1) + expDenote (cfold e2) =
adamc@85:    expDenote
adamc@85:      match cfold e1 with
adamc@85:      | NConst n1 =>
adamc@85:          match cfold e2 with
adamc@85:          | NConst n2 => NConst (n1 + n2)
adamc@85:          | Plus _ _ => Plus (cfold e1) (cfold e2)
adamc@85:          | Eq _ _ => Plus (cfold e1) (cfold e2)
adamc@85:          | BConst _ => Plus (cfold e1) (cfold e2)
adamc@85:          | And _ _ => Plus (cfold e1) (cfold e2)
adamc@85:          | If _ _ _ _ => Plus (cfold e1) (cfold e2)
adamc@85:          | Pair _ _ _ _ => Plus (cfold e1) (cfold e2)
adamc@85:          | Fst _ _ _ => Plus (cfold e1) (cfold e2)
adamc@85:          | Snd _ _ _ => Plus (cfold e1) (cfold e2)
adamc@85:          end
adamc@85:      | Plus _ _ => Plus (cfold e1) (cfold e2)
adamc@85:      | Eq _ _ => Plus (cfold e1) (cfold e2)
adamc@85:      | BConst _ => Plus (cfold e1) (cfold e2)
adamc@85:      | And _ _ => Plus (cfold e1) (cfold e2)
adamc@85:      | If _ _ _ _ => Plus (cfold e1) (cfold e2)
adamc@85:      | Pair _ _ _ _ => Plus (cfold e1) (cfold e2)
adamc@85:      | Fst _ _ _ => Plus (cfold e1) (cfold e2)
adamc@85:      | Snd _ _ _ => Plus (cfold e1) (cfold e2)
adamc@85:      end
adamc@85:      ]]
adamc@85: 
adamc@85:      We would like to do a case analysis on [cfold e1], and we attempt that in the way that has worked so far.
adamc@85: 
adamc@85:      [[
adamc@85:   destruct (cfold e1).
adamc@85: 
adamc@85:   [[
adamc@85: User error: e1 is used in hypothesis e
adamc@85: ]]
adamc@85: 
adamc@85:     Coq gives us another cryptic error message.  Like so many others, this one basically means that Coq is not able to build some proof about dependent types.  It is hard to generate helpful and specific error messages for problems like this, since that would require some kind of understanding of the dependency structure of a piece of code.  We will encounter many examples of case-specific tricks for recovering from errors like this one.
adamc@85: 
adamc@85:     For our current proof, we can use a tactic [dep_destruct] defined in the book [Tactics] module.  General elimination/inversion of dependently-typed hypotheses is undecidable, since it must be implemented with [match] expressions that have the restriction on [in] clauses that we have already discussed.  [dep_destruct] makes a best effort to handle some common cases.  In a future chapter, we will learn about the explicit manipulation of equality proofs that is behind [dep_destruct]'s implementation in Ltac, but for now, we treat it as a useful black box. *)
adamc@85:   
adamc@85:   dep_destruct (cfold e1).
adamc@85: 
adamc@85:   (** This successfully breaks the subgoal into 5 new subgoals, one for each constructor of [exp] that could produce an [exp Nat].  Note that [dep_destruct] is successful in ruling out the other cases automatically, in effect automating some of the work that we have done manually in implementing functions like [hd] and [pairOut].
adamc@85: 
adamc@85:      This is the only new trick we need to learn to complete the proof.  We can back up and give a short, automated proof. *)
adamc@85: 
adamc@85:   Restart.
adamc@85: 
adamc@85:   induction e; crush;
adamc@85:     repeat (match goal with
adamc@85:               | [ |- context[cfold ?E] ] => dep_destruct (cfold E)
adamc@85:               | [ |- (if ?E then _ else _) = _ ] => destruct E
adamc@85:             end; crush).
adamc@85: Qed.
adamc@100: (* end thide *)
adamc@86: 
adamc@86: 
adamc@103: (** * Dependently-Typed Red-Black Trees *)
adamc@94: 
adamc@100: (** TODO: Add commentary for this section. *)
adamc@100: 
adamc@94: Inductive color : Set := Red | Black.
adamc@94: 
adamc@94: Inductive rbtree : color -> nat -> Set :=
adamc@94: | Leaf : rbtree Black 0
adamc@94: | RedNode : forall n, rbtree Black n -> nat-> rbtree Black n -> rbtree Red n
adamc@94: | BlackNode : forall c1 c2 n, rbtree c1 n -> nat -> rbtree c2 n -> rbtree Black (S n).
adamc@94: 
adamc@100: (* EX: Prove that every [rbtree] is balanced. *)
adamc@100: 
adamc@100: (* begin thide *)
adamc@95: Require Import Max Min.
adamc@95: 
adamc@95: Section depth.
adamc@95:   Variable f : nat -> nat -> nat.
adamc@95: 
adamc@95:   Fixpoint depth c n (t : rbtree c n) {struct t} : nat :=
adamc@95:     match t with
adamc@95:       | Leaf => 0
adamc@95:       | RedNode _ t1 _ t2 => S (f (depth t1) (depth t2))
adamc@95:       | BlackNode _ _ _ t1 _ t2 => S (f (depth t1) (depth t2))
adamc@95:     end.
adamc@95: End depth.
adamc@95: 
adamc@95: Theorem depth_min : forall c n (t : rbtree c n), depth min t >= n.
adamc@95:   induction t; crush;
adamc@95:     match goal with
adamc@95:       | [ |- context[min ?X ?Y] ] => destruct (min_dec X Y)
adamc@95:     end; crush.
adamc@95: Qed.
adamc@95: 
adamc@95: Lemma depth_max' : forall c n (t : rbtree c n), match c with
adamc@95:                                                   | Red => depth max t <= 2 * n + 1
adamc@95:                                                   | Black => depth max t <= 2 * n
adamc@95:                                                 end.
adamc@95:   induction t; crush;
adamc@95:     match goal with
adamc@95:       | [ |- context[max ?X ?Y] ] => destruct (max_dec X Y)
adamc@100:     end; crush;
adamc@100:     repeat (match goal with
adamc@100:               | [ H : context[match ?C with Red => _ | Black => _ end] |- _ ] => destruct C
adamc@100:             end; crush).
adamc@95: Qed.
adamc@95: 
adamc@95: Theorem depth_max : forall c n (t : rbtree c n), depth max t <= 2 * n + 1.
adamc@95:   intros; generalize (depth_max' t); destruct c; crush.
adamc@95: Qed.
adamc@95: 
adamc@95: Theorem balanced : forall c n (t : rbtree c n), 2 * depth min t + 1 >= depth max t.
adamc@95:   intros; generalize (depth_min t); generalize (depth_max t); crush.
adamc@95: Qed.
adamc@100: (* end thide *)
adamc@95: 
adamc@95: 
adamc@94: Inductive rtree : nat -> Set :=
adamc@94: | RedNode' : forall c1 c2 n, rbtree c1 n -> nat -> rbtree c2 n -> rtree n.
adamc@94: 
adamc@96: Section present.
adamc@96:   Variable x : nat.
adamc@96: 
adamc@96:   Fixpoint present c n (t : rbtree c n) {struct t} : Prop :=
adamc@96:     match t with
adamc@96:       | Leaf => False
adamc@96:       | RedNode _ a y b => present a \/ x = y \/ present b
adamc@96:       | BlackNode _ _ _ a y b => present a \/ x = y \/ present b
adamc@96:     end.
adamc@96: 
adamc@96:   Definition rpresent n (t : rtree n) : Prop :=
adamc@96:     match t with
adamc@96:       | RedNode' _ _ _ a y b => present a \/ x = y \/ present b
adamc@96:     end.
adamc@96: End present.
adamc@96: 
adamc@100: Locate "{ _ : _ & _ }".
adamc@100: Print sigT.
adamc@100: 
adamc@94: Notation "{< x >}" := (existT _ _ x).
adamc@94: 
adamc@94: Definition balance1 n (a : rtree n) (data : nat) c2 :=
adamc@94:   match a in rtree n return rbtree c2 n -> { c : color & rbtree c (S n) } with
adamc@94:     | RedNode' _ _ _ t1 y t2 =>
adamc@94:       match t1 in rbtree c n return rbtree _ n -> rbtree c2 n -> { c : color & rbtree c (S n) } with
adamc@94:         | RedNode _ a x b => fun c d => {<RedNode (BlackNode a x b) y (BlackNode c data d)>}
adamc@94:         | t1' => fun t2 =>
adamc@94:           match t2 in rbtree c n return rbtree _ n -> rbtree c2 n -> { c : color & rbtree c (S n) } with
adamc@94:             | RedNode _ b x c => fun a d => {<RedNode (BlackNode a y b) x (BlackNode c data d)>}
adamc@95:             | b => fun a t => {<BlackNode (RedNode a y b) data t>}
adamc@94:           end t1'
adamc@94:       end t2
adamc@94:   end.
adamc@94: 
adamc@94: Definition balance2 n (a : rtree n) (data : nat) c2 :=
adamc@94:   match a in rtree n return rbtree c2 n -> { c : color & rbtree c (S n) } with
adamc@94:     | RedNode' _ _ _ t1 z t2 =>
adamc@94:       match t1 in rbtree c n return rbtree _ n -> rbtree c2 n -> { c : color & rbtree c (S n) } with
adamc@94:         | RedNode _ b y c => fun d a => {<RedNode (BlackNode a data b) y (BlackNode c z d)>}
adamc@94:         | t1' => fun t2 =>
adamc@94:           match t2 in rbtree c n return rbtree _ n -> rbtree c2 n -> { c : color & rbtree c (S n) } with
adamc@94:             | RedNode _ c z' d => fun b a => {<RedNode (BlackNode a data b) z (BlackNode c z' d)>}
adamc@95:             | b => fun a t => {<BlackNode t data (RedNode a z b)>}
adamc@94:           end t1'
adamc@94:       end t2
adamc@94:   end.
adamc@94: 
adamc@94: Section insert.
adamc@94:   Variable x : nat.
adamc@94: 
adamc@94:   Definition insResult c n :=
adamc@94:     match c with
adamc@94:       | Red => rtree n
adamc@94:       | Black => { c' : color & rbtree c' n }
adamc@94:     end.
adamc@94: 
adamc@94:   Fixpoint ins c n (t : rbtree c n) {struct t} : insResult c n :=
adamc@94:     match t in (rbtree c n) return (insResult c n) with
adamc@94:       | Leaf => {< RedNode Leaf x Leaf >}
adamc@94:       | RedNode _ a y b =>
adamc@94:         if le_lt_dec x y
adamc@94:           then RedNode' (projT2 (ins a)) y b
adamc@94:           else RedNode' a y (projT2 (ins b))
adamc@94:       | BlackNode c1 c2 _ a y b =>
adamc@94:         if le_lt_dec x y
adamc@94:           then
adamc@94:             match c1 return insResult c1 _ -> _ with
adamc@94:               | Red => fun ins_a => balance1 ins_a y b
adamc@94:               | _ => fun ins_a => {< BlackNode (projT2 ins_a) y b >}
adamc@94:             end (ins a)
adamc@94:           else
adamc@94:             match c2 return insResult c2 _ -> _ with
adamc@94:               | Red => fun ins_b => balance2 ins_b y a
adamc@94:               | _ => fun ins_b => {< BlackNode a y (projT2 ins_b) >}
adamc@94:             end (ins b)
adamc@94:     end.
adamc@94: 
adamc@94:   Definition insertResult c n :=
adamc@94:     match c with
adamc@94:       | Red => rbtree Black (S n)
adamc@94:       | Black => { c' : color & rbtree c' n }
adamc@94:     end.
adamc@94: 
adamc@97:   Definition makeRbtree c n : insResult c n -> insertResult c n :=
adamc@94:     match c return insResult c n -> insertResult c n with
adamc@94:       | Red => fun r =>
adamc@94:         match r in rtree n return insertResult Red n with
adamc@94:           | RedNode' _ _ _ a x b => BlackNode a x b
adamc@94:         end
adamc@94:       | Black => fun r => r
adamc@94:     end.
adamc@94: 
adamc@97:   Implicit Arguments makeRbtree [c n].
adamc@94: 
adamc@94:   Definition insert c n (t : rbtree c n) : insertResult c n :=
adamc@97:     makeRbtree (ins t).
adamc@94: 
adamc@95:   Section present.
adamc@95:     Variable z : nat.
adamc@95: 
adamc@98:     Ltac present_balance :=
adamc@98:       crush;
adamc@98:       repeat (match goal with
adamc@98:                 | [ H : context[match ?T with
adamc@98:                                   | Leaf => _
adamc@98:                                   | RedNode _ _ _ _ => _
adamc@98:                                   | BlackNode _ _ _ _ _ _ => _
adamc@98:                                 end] |- _ ] => dep_destruct T
adamc@98:                 | [ |- context[match ?T with
adamc@98:                                  | Leaf => _
adamc@98:                                  | RedNode _ _ _ _ => _
adamc@98:                                  | BlackNode _ _ _ _ _ _ => _
adamc@98:                                  end] ] => dep_destruct T
adamc@98:               end; crush).
adamc@98: 
adamc@95:     Lemma present_balance1 : forall n (a : rtree n) (y : nat) c2 (b : rbtree c2 n) ,
adamc@95:       present z (projT2 (balance1 a y b))
adamc@95:       <-> rpresent z a \/ z = y \/ present z b.
adamc@98:       destruct a; present_balance.
adamc@95:     Qed.
adamc@95: 
adamc@95:     Lemma present_balance2 : forall n (a : rtree n) (y : nat) c2 (b : rbtree c2 n) ,
adamc@95:       present z (projT2 (balance2 a y b))
adamc@95:       <-> rpresent z a \/ z = y \/ present z b.
adamc@98:       destruct a; present_balance.
adamc@95:     Qed.
adamc@95: 
adamc@95:     Definition present_insResult c n :=
adamc@95:       match c return (rbtree c n -> insResult c n -> Prop) with
adamc@95:         | Red => fun t r => rpresent z r <-> z = x \/ present z t
adamc@95:         | Black => fun t r => present z (projT2 r) <-> z = x \/ present z t
adamc@95:       end.
adamc@95: 
adamc@95:     Theorem present_ins : forall c n (t : rbtree c n),
adamc@95:       present_insResult t (ins t).
adamc@95:       induction t; crush;
adamc@95:         repeat (match goal with
adamc@95:                   | [ H : context[if ?E then _ else _] |- _ ] => destruct E
adamc@95:                   | [ |- context[if ?E then _ else _] ] => destruct E
adamc@95:                   | [ H : context[match ?C with Red => _ | Black => _ end] |- _ ] => destruct C
adamc@95:                 end; crush);
adamc@95:         try match goal with
adamc@95:               | [ H : context[balance1 ?A ?B ?C] |- _ ] =>
adamc@95:                 generalize (present_balance1 A B C)
adamc@95:             end;
adamc@95:         try match goal with
adamc@95:               | [ H : context[balance2 ?A ?B ?C] |- _ ] =>
adamc@95:                 generalize (present_balance2 A B C)
adamc@95:             end;
adamc@95:         try match goal with
adamc@95:               | [ |- context[balance1 ?A ?B ?C] ] =>
adamc@95:                 generalize (present_balance1 A B C)
adamc@95:             end;
adamc@95:         try match goal with
adamc@95:               | [ |- context[balance2 ?A ?B ?C] ] =>
adamc@95:                 generalize (present_balance2 A B C)
adamc@95:             end;
adamc@95:         intuition;
adamc@95:           match goal with
adamc@95:             | [ z : nat, x : nat |- _ ] =>
adamc@95:               match goal with
adamc@95:                 | [ H : z = x |- _ ] => rewrite H in *; clear H
adamc@95:               end
adamc@95:           end;
adamc@95:           tauto.
adamc@95:     Qed.
adamc@95: 
adamc@97:     Ltac present_insert t :=
adamc@97:       unfold insert; inversion t;
adamc@97:         generalize (present_ins t); simpl;
adamc@97:           dep_destruct (ins t); tauto.
adamc@97: 
adamc@95:     Theorem present_insert_Red : forall n (t : rbtree Red n),
adamc@95:       present z (insert t)
adamc@95:       <-> (z = x \/ present z t).
adamc@97:       intros; present_insert t.
adamc@95:     Qed.
adamc@95: 
adamc@95:     Theorem present_insert_Black : forall n (t : rbtree Black n),
adamc@95:       present z (projT2 (insert t))
adamc@95:       <-> (z = x \/ present z t).
adamc@97:       intros; present_insert t.
adamc@95:     Qed.
adamc@95:   End present.
adamc@94: End insert.
adamc@94: 
adamc@94: 
adamc@86: (** * A Certified Regular Expression Matcher *)
adamc@86: 
adamc@93: (** Another interesting example is regular expressions with dependent types that express which predicates over strings particular regexps implement.  We can then assign a dependent type to a regular expression matching function, guaranteeing that it always decides the string property that we expect it to decide.
adamc@93: 
adamc@93:    Before defining the syntax of expressions, it is helpful to define an inductive type capturing the meaning of the Kleene star.  We use Coq's string support, which comes through a combination of the [Strings] library and some parsing notations built into Coq.  Operators like [++] and functions like [length] that we know from lists are defined again for strings.  Notation scopes help us control which versions we want to use in particular contexts. *)
adamc@93: 
adamc@86: Require Import Ascii String.
adamc@86: Open Scope string_scope.
adamc@86: 
adamc@91: Section star.
adamc@91:   Variable P : string -> Prop.
adamc@91: 
adamc@91:   Inductive star : string -> Prop :=
adamc@91:   | Empty : star ""
adamc@91:   | Iter : forall s1 s2,
adamc@91:     P s1
adamc@91:     -> star s2
adamc@91:     -> star (s1 ++ s2).
adamc@91: End star.
adamc@91: 
adamc@93: (** Now we can make our first attempt at defining a [regexp] type that is indexed by predicates on strings.  Here is a reasonable-looking definition that is restricted to constant characters and concatenation.
adamc@93: 
adamc@93: [[
adamc@93: Inductive regexp : (string -> Prop) -> Set :=
adamc@93: | Char : forall ch : ascii,
adamc@93:   regexp (fun s => s = String ch "")
adamc@93: | Concat : forall (P1 P2 : string -> Prop) (r1 : regexp P1) (r2 : regexp P2),
adamc@93:   regexp (fun s => exists s1, exists s2, s = s1 ++ s2 /\ P1 s1 /\ P2 s2).
adamc@93: 
adamc@93: [[
adamc@93: User error: Large non-propositional inductive types must be in Type
adamc@93: ]]
adamc@93: 
adamc@93: What is a large inductive type?  In Coq, it is an inductive type that has a constructor which quantifies over some type of type [Type].  We have not worked with [Type] very much to this point.  Every term of CIC has a type, including [Set] and [Prop], which are assigned type [Type].  The type [string -> Prop] from the failed definition also has type [Type].
adamc@93: 
adamc@93: It turns out that allowing large inductive types in [Set] leads to contradictions when combined with certain kinds of classical logic reasoning.  Thus, by default, such types are ruled out.  There is a simple fix for our [regexp] definition, which is to place our new type in [Type].  While fixing the problem, we also expand the list of constructors to cover the remaining regular expression operators. *)
adamc@93: 
adamc@89: Inductive regexp : (string -> Prop) -> Type :=
adamc@86: | Char : forall ch : ascii,
adamc@86:   regexp (fun s => s = String ch "")
adamc@86: | Concat : forall P1 P2 (r1 : regexp P1) (r2 : regexp P2),
adamc@87:   regexp (fun s => exists s1, exists s2, s = s1 ++ s2 /\ P1 s1 /\ P2 s2)
adamc@87: | Or : forall P1 P2 (r1 : regexp P1) (r2 : regexp P2),
adamc@91:   regexp (fun s => P1 s \/ P2 s)
adamc@91: | Star : forall P (r : regexp P),
adamc@91:   regexp (star P).
adamc@86: 
adamc@93: (** Many theorems about strings are useful for implementing a certified regexp matcher, and few of them are in the [Strings] library.  The book source includes statements, proofs, and hint commands for a handful of such omittted theorems.  Since they are orthogonal to our use of dependent types, we hide them in the rendered versions of this book. *)
adamc@93: 
adamc@93: (* begin hide *)
adamc@86: Open Scope specif_scope.
adamc@86: 
adamc@86: Lemma length_emp : length "" <= 0.
adamc@86:   crush.
adamc@86: Qed.
adamc@86: 
adamc@86: Lemma append_emp : forall s, s = "" ++ s.
adamc@86:   crush.
adamc@86: Qed.
adamc@86: 
adamc@86: Ltac substring :=
adamc@86:   crush;
adamc@86:   repeat match goal with
adamc@86:            | [ |- context[match ?N with O => _ | S _ => _ end] ] => destruct N; crush
adamc@86:          end.
adamc@86: 
adamc@86: Lemma substring_le : forall s n m,
adamc@86:   length (substring n m s) <= m.
adamc@86:   induction s; substring.
adamc@86: Qed.
adamc@86: 
adamc@86: Lemma substring_all : forall s,
adamc@86:   substring 0 (length s) s = s.
adamc@86:   induction s; substring.
adamc@86: Qed.
adamc@86: 
adamc@86: Lemma substring_none : forall s n,
adamc@93:   substring n 0 s = "".
adamc@86:   induction s; substring.
adamc@86: Qed.
adamc@86: 
adamc@86: Hint Rewrite substring_all substring_none : cpdt.
adamc@86: 
adamc@86: Lemma substring_split : forall s m,
adamc@86:   substring 0 m s ++ substring m (length s - m) s = s.
adamc@86:   induction s; substring.
adamc@86: Qed.
adamc@86: 
adamc@86: Lemma length_app1 : forall s1 s2,
adamc@86:   length s1 <= length (s1 ++ s2).
adamc@86:   induction s1; crush.
adamc@86: Qed.
adamc@86: 
adamc@86: Hint Resolve length_emp append_emp substring_le substring_split length_app1.
adamc@86: 
adamc@86: Lemma substring_app_fst : forall s2 s1 n,
adamc@86:   length s1 = n
adamc@86:   -> substring 0 n (s1 ++ s2) = s1.
adamc@86:   induction s1; crush.
adamc@86: Qed.
adamc@86: 
adamc@86: Lemma substring_app_snd : forall s2 s1 n,
adamc@86:   length s1 = n
adamc@86:   -> substring n (length (s1 ++ s2) - n) (s1 ++ s2) = s2.
adamc@86:   Hint Rewrite <- minus_n_O : cpdt.
adamc@86: 
adamc@86:   induction s1; crush.
adamc@86: Qed.
adamc@86: 
adamc@91: Hint Rewrite substring_app_fst substring_app_snd using (trivial; fail) : cpdt.
adamc@93: (* end hide *)
adamc@93: 
adamc@93: (** A few auxiliary functions help us in our final matcher definition.  The function [split] will be used to implement the regexp concatenation case. *)
adamc@86: 
adamc@86: Section split.
adamc@86:   Variables P1 P2 : string -> Prop.
adamc@91:   Variable P1_dec : forall s, {P1 s} + { ~P1 s}.
adamc@91:   Variable P2_dec : forall s, {P2 s} + { ~P2 s}.
adamc@93:   (** We require a choice of two arbitrary string predicates and functions for deciding them. *)
adamc@86: 
adamc@86:   Variable s : string.
adamc@93:   (** Our computation will take place relative to a single fixed string, so it is easiest to make it a [Variable], rather than an explicit argument to our functions. *)
adamc@93: 
adamc@93:   (** [split'] is the workhorse behind [split].  It searches through the possible ways of splitting [s] into two pieces, checking the two predicates against each such pair.  [split'] progresses right-to-left, from splitting all of [s] into the first piece to splitting all of [s] into the second piece.  It takes an extra argument, [n], which specifies how far along we are in this search process. *)
adamc@86: 
adamc@86:   Definition split' (n : nat) : n <= length s
adamc@86:     -> {exists s1, exists s2, length s1 <= n /\ s1 ++ s2 = s /\ P1 s1 /\ P2 s2}
adamc@86:     + {forall s1 s2, length s1 <= n -> s1 ++ s2 = s -> ~P1 s1 \/ ~P2 s2}.
adamc@86:     refine (fix F (n : nat) : n <= length s
adamc@86:       -> {exists s1, exists s2, length s1 <= n /\ s1 ++ s2 = s /\ P1 s1 /\ P2 s2}
adamc@86:       + {forall s1 s2, length s1 <= n -> s1 ++ s2 = s -> ~P1 s1 \/ ~P2 s2} :=
adamc@86:       match n return n <= length s
adamc@86:         -> {exists s1, exists s2, length s1 <= n /\ s1 ++ s2 = s /\ P1 s1 /\ P2 s2}
adamc@86:         + {forall s1 s2, length s1 <= n -> s1 ++ s2 = s -> ~P1 s1 \/ ~P2 s2} with
adamc@86:         | O => fun _ => Reduce (P1_dec "" && P2_dec s)
adamc@93:         | S n' => fun _ => (P1_dec (substring 0 (S n') s)
adamc@93:             && P2_dec (substring (S n') (length s - S n') s))
adamc@86:           || F n' _
adamc@86:       end); clear F; crush; eauto 7;
adamc@86:     match goal with
adamc@86:       | [ _ : length ?S <= 0 |- _ ] => destruct S
adamc@86:       | [ _ : length ?S' <= S ?N |- _ ] =>
adamc@86:         generalize (eq_nat_dec (length S') (S N)); destruct 1
adamc@86:     end; crush.
adamc@86:   Defined.
adamc@86: 
adamc@93:   (** There is one subtle point in the [split'] code that is worth mentioning.  The main body of the function is a [match] on [n].  In the case where [n] is known to be [S n'], we write [S n'] in several places where we might be tempted to write [n].  However, without further work to craft proper [match] annotations, the type-checker does not use the equality between [n] and [S n'].  Thus, it is common to see patterns repeated in [match] case bodies in dependently-typed Coq code.  We can at least use a [let] expression to avoid copying the pattern more than once, replacing the first case body with:
adamc@93: 
adamc@93:      [[
adamc@93: 
adamc@93:         | S n' => fun _ => let n := S n' in
adamc@93:           (P1_dec (substring 0 n s)
adamc@93:             && P2_dec (substring n (length s - n) s))
adamc@93:           || F n' _
adamc@93:      ]]
adamc@93: 
adamc@93:      [split] itself is trivial to implement in terms of [split'].  We just ask [split'] to begin its search with [n = length s]. *)
adamc@93: 
adamc@86:   Definition split : {exists s1, exists s2, s = s1 ++ s2 /\ P1 s1 /\ P2 s2}
adamc@86:     + {forall s1 s2, s = s1 ++ s2 -> ~P1 s1 \/ ~P2 s2}.
adamc@86:     refine (Reduce (split' (n := length s) _)); crush; eauto.
adamc@86:   Defined.
adamc@86: End split.
adamc@86: 
adamc@86: Implicit Arguments split [P1 P2].
adamc@86: 
adamc@93: (* begin hide *)
adamc@91: Lemma app_empty_end : forall s, s ++ "" = s.
adamc@91:   induction s; crush.
adamc@91: Qed.
adamc@91: 
adamc@91: Hint Rewrite app_empty_end : cpdt.
adamc@91: 
adamc@91: Lemma substring_self : forall s n,
adamc@91:   n <= 0
adamc@91:   -> substring n (length s - n) s = s.
adamc@91:   induction s; substring.
adamc@91: Qed.
adamc@91: 
adamc@91: Lemma substring_empty : forall s n m,
adamc@91:   m <= 0
adamc@91:   -> substring n m s = "".
adamc@91:   induction s; substring.
adamc@91: Qed.
adamc@91: 
adamc@91: Hint Rewrite substring_self substring_empty using omega : cpdt.
adamc@91: 
adamc@91: Lemma substring_split' : forall s n m,
adamc@91:   substring n m s ++ substring (n + m) (length s - (n + m)) s
adamc@91:   = substring n (length s - n) s.
adamc@91:   Hint Rewrite substring_split : cpdt.
adamc@91: 
adamc@91:   induction s; substring.
adamc@91: Qed.
adamc@91: 
adamc@91: Lemma substring_stack : forall s n2 m1 m2,
adamc@91:   m1 <= m2
adamc@91:   -> substring 0 m1 (substring n2 m2 s)
adamc@91:   = substring n2 m1 s.
adamc@91:   induction s; substring.
adamc@91: Qed.
adamc@91: 
adamc@91: Ltac substring' :=
adamc@91:   crush;
adamc@91:   repeat match goal with
adamc@91:            | [ |- context[match ?N with O => _ | S _ => _ end] ] => case_eq N; crush
adamc@91:          end.
adamc@91: 
adamc@91: Lemma substring_stack' : forall s n1 n2 m1 m2,
adamc@91:   n1 + m1 <= m2
adamc@91:   -> substring n1 m1 (substring n2 m2 s)
adamc@91:   = substring (n1 + n2) m1 s.
adamc@91:   induction s; substring';
adamc@91:     match goal with
adamc@91:       | [ |- substring ?N1 _ _ = substring ?N2 _ _ ] =>
adamc@91:         replace N1 with N2; crush
adamc@91:     end.
adamc@91: Qed.
adamc@91: 
adamc@91: Lemma substring_suffix : forall s n,
adamc@91:   n <= length s
adamc@91:   -> length (substring n (length s - n) s) = length s - n.
adamc@91:   induction s; substring.
adamc@91: Qed.
adamc@91: 
adamc@91: Lemma substring_suffix_emp' : forall s n m,
adamc@91:   substring n (S m) s = ""
adamc@91:   -> n >= length s.
adamc@91:   induction s; crush;
adamc@91:     match goal with
adamc@91:       | [ |- ?N >= _ ] => destruct N; crush
adamc@91:     end;
adamc@91:     match goal with
adamc@91:       [ |- S ?N >= S ?E ] => assert (N >= E); [ eauto | omega ]
adamc@91:     end.
adamc@91: Qed.
adamc@91: 
adamc@91: Lemma substring_suffix_emp : forall s n m,
adamc@92:   substring n m s = ""
adamc@92:   -> m > 0
adamc@91:   -> n >= length s.
adamc@91:   destruct m as [| m]; [crush | intros; apply substring_suffix_emp' with m; assumption].
adamc@91: Qed.
adamc@91: 
adamc@91: Hint Rewrite substring_stack substring_stack' substring_suffix
adamc@91:   using omega : cpdt.
adamc@91: 
adamc@91: Lemma minus_minus : forall n m1 m2,
adamc@91:   m1 + m2 <= n
adamc@91:   -> n - m1 - m2 = n - (m1 + m2).
adamc@91:   intros; omega.
adamc@91: Qed.
adamc@91: 
adamc@91: Lemma plus_n_Sm' : forall n m : nat, S (n + m) = m + S n.
adamc@91:   intros; omega.
adamc@91: Qed.
adamc@91: 
adamc@91: Hint Rewrite minus_minus using omega : cpdt.
adamc@93: (* end hide *)
adamc@93: 
adamc@93: (** One more helper function will come in handy: [dec_star], for implementing another linear search through ways of splitting a string, this time for implementing the Kleene star. *)
adamc@91: 
adamc@91: Section dec_star.
adamc@91:   Variable P : string -> Prop.
adamc@91:   Variable P_dec : forall s, {P s} + { ~P s}.
adamc@91: 
adamc@93:   (** Some new lemmas and hints about the [star] type family are useful here.  We omit them here; they are included in the book source at this point. *)
adamc@93: 
adamc@93:   (* begin hide *)
adamc@91:   Hint Constructors star.
adamc@91: 
adamc@91:   Lemma star_empty : forall s,
adamc@91:     length s = 0
adamc@91:     -> star P s.
adamc@91:     destruct s; crush.
adamc@91:   Qed.
adamc@91: 
adamc@91:   Lemma star_singleton : forall s, P s -> star P s.
adamc@91:     intros; rewrite <- (app_empty_end s); auto.
adamc@91:   Qed.
adamc@91: 
adamc@91:   Lemma star_app : forall s n m,
adamc@91:     P (substring n m s)
adamc@91:     -> star P (substring (n + m) (length s - (n + m)) s)
adamc@91:     -> star P (substring n (length s - n) s).
adamc@91:     induction n; substring;
adamc@91:       match goal with
adamc@91:         | [ H : P (substring ?N ?M ?S) |- _ ] =>
adamc@91:           solve [ rewrite <- (substring_split S M); auto
adamc@91:             | rewrite <- (substring_split' S N M); auto ]
adamc@91:       end.
adamc@91:   Qed.
adamc@91: 
adamc@91:   Hint Resolve star_empty star_singleton star_app.
adamc@91: 
adamc@91:   Variable s : string.
adamc@91: 
adamc@91:   Lemma star_inv : forall s,
adamc@91:     star P s
adamc@91:     -> s = ""
adamc@91:     \/ exists i, i < length s
adamc@91:       /\ P (substring 0 (S i) s)
adamc@91:       /\ star P (substring (S i) (length s - S i) s).
adamc@91:     Hint Extern 1 (exists i : nat, _) =>
adamc@91:       match goal with
adamc@91:         | [ H : P (String _ ?S) |- _ ] => exists (length S); crush
adamc@91:       end.
adamc@91: 
adamc@91:     induction 1; [
adamc@91:       crush
adamc@91:       | match goal with
adamc@91:           | [ _ : P ?S |- _ ] => destruct S; crush
adamc@91:         end
adamc@91:     ].
adamc@91:   Qed.    
adamc@91: 
adamc@91:   Lemma star_substring_inv : forall n,
adamc@91:     n <= length s
adamc@91:     -> star P (substring n (length s - n) s)
adamc@91:     -> substring n (length s - n) s = ""
adamc@91:     \/ exists l, l < length s - n
adamc@91:       /\ P (substring n (S l) s)
adamc@91:       /\ star P (substring (n + S l) (length s - (n + S l)) s).
adamc@91:     Hint Rewrite plus_n_Sm' : cpdt.
adamc@91: 
adamc@91:     intros;
adamc@91:       match goal with
adamc@91:         | [ H : star _ _ |- _ ] => generalize (star_inv H); do 3 crush; eauto
adamc@91:       end.
adamc@91:   Qed.
adamc@93:   (* end hide *)
adamc@93: 
adamc@93:   (** The function [dec_star''] implements a single iteration of the star.  That is, it tries to find a string prefix matching [P], and it calls a parameter function on the remainder of the string. *)
adamc@91: 
adamc@91:   Section dec_star''.
adamc@91:     Variable n : nat.
adamc@93:     (** [n] is the length of the prefix of [s] that we have already processed. *)
adamc@91: 
adamc@91:     Variable P' : string -> Prop.
adamc@91:     Variable P'_dec : forall n' : nat, n' > n
adamc@91:       -> {P' (substring n' (length s - n') s)}
adamc@91:       + { ~P' (substring n' (length s - n') s)}.
adamc@93:     (** When we use [dec_star''], we will instantiate [P'_dec] with a function for continuing the search for more instances of [P] in [s]. *)
adamc@93: 
adamc@93:     (** Now we come to [dec_star''] itself.  It takes as an input a natural [l] that records how much of the string has been searched so far, as we did for [split'].  The return type expresses that [dec_star''] is looking for an index into [s] that splits [s] into a nonempty prefix and a suffix, such that the prefix satisfies [P] and the suffix satisfies [P']. *)
adamc@91: 
adamc@91:     Definition dec_star'' (l : nat)
adamc@91:       : {exists l', S l' <= l
adamc@91:         /\ P (substring n (S l') s) /\ P' (substring (n + S l') (length s - (n + S l')) s)}
adamc@91:       + {forall l', S l' <= l
adamc@93:         -> ~P (substring n (S l') s)
adamc@93:         \/ ~P' (substring (n + S l') (length s - (n + S l')) s)}.
adamc@91:       refine (fix F (l : nat) : {exists l', S l' <= l
adamc@91:         /\ P (substring n (S l') s) /\ P' (substring (n + S l') (length s - (n + S l')) s)}
adamc@91:       + {forall l', S l' <= l
adamc@93:         -> ~P (substring n (S l') s)
adamc@93:         \/ ~P' (substring (n + S l') (length s - (n + S l')) s)} :=
adamc@91:       match l return {exists l', S l' <= l
adamc@91:         /\ P (substring n (S l') s) /\ P' (substring (n + S l') (length s - (n + S l')) s)}
adamc@91:       + {forall l', S l' <= l ->
adamc@93:         ~P (substring n (S l') s)
adamc@93:         \/ ~P' (substring (n + S l') (length s - (n + S l')) s)} with
adamc@91:         | O => _
adamc@91:         | S l' =>
adamc@91:           (P_dec (substring n (S l') s) && P'_dec (n' := n + S l') _)
adamc@91:           || F l'
adamc@91:       end); clear F; crush; eauto 7;
adamc@91:       match goal with
adamc@91:         | [ H : ?X <= S ?Y |- _ ] => destruct (eq_nat_dec X (S Y)); crush
adamc@91:       end.
adamc@91:     Defined.
adamc@91:   End dec_star''.
adamc@91: 
adamc@93:   (* begin hide *)
adamc@92:   Lemma star_length_contra : forall n,
adamc@92:     length s > n
adamc@92:     -> n >= length s
adamc@92:     -> False.
adamc@92:     crush.
adamc@92:   Qed.
adamc@92: 
adamc@92:   Lemma star_length_flip : forall n n',
adamc@92:     length s - n <= S n'
adamc@92:     -> length s > n
adamc@92:     -> length s - n > 0.
adamc@92:     crush.
adamc@92:   Qed.
adamc@92: 
adamc@92:   Hint Resolve star_length_contra star_length_flip substring_suffix_emp.
adamc@93:   (* end hide *)
adamc@92: 
adamc@93:   (** The work of [dec_star''] is nested inside another linear search by [dec_star'], which provides the final functionality we need, but for arbitrary suffixes of [s], rather than just for [s] overall. *)
adamc@93:   
adamc@91:   Definition dec_star' (n n' : nat) : length s - n' <= n
adamc@91:     -> {star P (substring n' (length s - n') s)}
adamc@93:     + { ~star P (substring n' (length s - n') s)}.
adamc@91:     refine (fix F (n n' : nat) {struct n} : length s - n' <= n
adamc@91:       -> {star P (substring n' (length s - n') s)}
adamc@93:       + { ~star P (substring n' (length s - n') s)} :=
adamc@91:       match n return length s - n' <= n
adamc@91:         -> {star P (substring n' (length s - n') s)}
adamc@93:         + { ~star P (substring n' (length s - n') s)} with
adamc@91:         | O => fun _ => Yes
adamc@91:         | S n'' => fun _ =>
adamc@91:           le_gt_dec (length s) n'
adamc@91:           || dec_star'' (n := n') (star P) (fun n0 _ => Reduce (F n'' n0 _)) (length s - n')
adamc@92:       end); clear F; crush; eauto;
adamc@92:     match goal with
adamc@92:       | [ H : star _ _ |- _ ] => apply star_substring_inv in H; crush; eauto
adamc@92:     end;
adamc@92:     match goal with
adamc@92:       | [ H1 : _ < _ - _, H2 : forall l' : nat, _ <= _ - _ -> _ |- _ ] =>
adamc@92:         generalize (H2 _ (lt_le_S _ _ H1)); tauto
adamc@92:     end.
adamc@91:   Defined.
adamc@91: 
adamc@93:   (** Finally, we have [dec_star].  It has a straightforward implementation.  We introduce a spurious match on [s] so that [simpl] will know to reduce calls to [dec_star].  The heuristic that [simpl] uses is only to unfold identifier definitions when doing so would simplify some [match] expression. *)
adamc@93: 
adamc@91:   Definition dec_star : {star P s} + { ~star P s}.
adamc@204:     refine (match s return _ with
adamc@91:               | "" => Reduce (dec_star' (n := length s) 0 _)
adamc@91:               | _ => Reduce (dec_star' (n := length s) 0 _)
adamc@91:             end); crush.
adamc@91:   Defined.
adamc@91: End dec_star.
adamc@91: 
adamc@93: (* begin hide *)
adamc@86: Lemma app_cong : forall x1 y1 x2 y2,
adamc@86:   x1 = x2
adamc@86:   -> y1 = y2
adamc@86:   -> x1 ++ y1 = x2 ++ y2.
adamc@86:   congruence.
adamc@86: Qed.
adamc@86: 
adamc@86: Hint Resolve app_cong.
adamc@93: (* end hide *)
adamc@93: 
adamc@93: (** With these helper functions completed, the implementation of our [matches] function is refreshingly straightforward.  We only need one small piece of specific tactic work beyond what [crush] does for us. *)
adamc@86: 
adamc@86: Definition matches P (r : regexp P) s : {P s} + { ~P s}.
adamc@86:   refine (fix F P (r : regexp P) s : {P s} + { ~P s} :=
adamc@86:     match r with
adamc@86:       | Char ch => string_dec s (String ch "")
adamc@86:       | Concat _ _ r1 r2 => Reduce (split (F _ r1) (F _ r2) s)
adamc@87:       | Or _ _ r1 r2 => F _ r1 s || F _ r2 s
adamc@91:       | Star _ r => dec_star _ _ _
adamc@86:     end); crush;
adamc@86:   match goal with
adamc@86:     | [ H : _ |- _ ] => generalize (H _ _ (refl_equal _))
adamc@93:   end; tauto.
adamc@86: Defined.
adamc@86: 
adamc@93: (* begin hide *)
adamc@86: Example hi := Concat (Char "h"%char) (Char "i"%char).
adamc@86: Eval simpl in matches hi "hi".
adamc@86: Eval simpl in matches hi "bye".
adamc@87: 
adamc@87: Example a_b := Or (Char "a"%char) (Char "b"%char).
adamc@87: Eval simpl in matches a_b "".
adamc@87: Eval simpl in matches a_b "a".
adamc@87: Eval simpl in matches a_b "aa".
adamc@87: Eval simpl in matches a_b "b".
adamc@91: 
adamc@91: Example a_star := Star (Char "a"%char).
adamc@91: Eval simpl in matches a_star "".
adamc@91: Eval simpl in matches a_star "a".
adamc@91: Eval simpl in matches a_star "b".
adamc@91: Eval simpl in matches a_star "aa".
adamc@93: (* end hide *)
adamc@101: 
adamc@101: 
adamc@101: (** * Exercises *)
adamc@101: 
adamc@101: (** %\begin{enumerate}%#<ol>#
adamc@101: 
adamc@101: %\item%#<li># Define a kind of dependently-typed lists, where a list's type index gives a lower bound on how many of its elements satisfy a particular predicate.  In particular, for an arbitrary set [A] and a predicate [P] over it:
adamc@101: %\begin{enumerate}%#<ol>#
adamc@101:   %\item%#<li># Define a type [plist : nat -> Set].  Each [plist n] should be a list of [A]s, where it is guaranteed that at least [n] distinct elements satisfy [P].  There is wide latitude in choosing how to encode this.  You should try to avoid using subset types or any other mechanism based on annotating non-dependent types with propositions after-the-fact.#</li>#
adamc@102:   %\item%#<li># Define a version of list concatenation that works on [plist]s.  The type of this new function should express as much information as possible about the output [plist].#</li>#
adamc@101:   %\item%#<li># Define a function [plistOut] for translating [plist]s to normal [list]s.#</li>#
adamc@101:   %\item%#<li># Define a function [plistIn] for translating [list]s to [plist]s.  The type of [plistIn] should make it clear that the best bound on [P]-matching elements is chosen.  You may assume that you are given a dependently-typed function for deciding instances of [P].#</li>#
adamc@101:   %\item%#<li># Prove that, for any list [ls], [plistOut (plistIn ls) = ls].  This should be the only part of the exercise where you use tactic-based proving.#</li>#
adamc@101:   %\item%#<li># Define a function [grab : forall n (ls : plist (S n)), sig P].  That is, when given a [plist] guaranteed to contain at least one element satisfying [P], [grab] produces such an element.  [sig] is the type family of sigma types, and [sig P] is extensionally equivalent to [{x : A | P x}], though the latter form uses an eta-expansion of [P] instead of [P] itself as the predicate.#</li>#
adamc@101: #</ol>#%\end{enumerate}% #</li>#
adamc@101:    
adamc@102: #</ol>#%\end{enumerate}% *)