Mercurial > cpdt > repo

annotate src/Universes.v @ 417:539ed97750bb

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Update for Coq trunk version intended for final 8.4 release
author Adam Chlipala <adam@chlipala.net>
date Tue, 17 Jul 2012 16:37:58 -0400
parents 934945edc6b5
children 686cf945dd02
rev   line source
adam@377 1 (* Copyright (c) 2009-2012, Adam Chlipala
adamc@227 2 *
adamc@227 3 * This work is licensed under a
adamc@227 4 * Creative Commons Attribution-Noncommercial-No Derivative Works 3.0
adamc@227 5 * Unported License.
adamc@227 6 * The license text is available at:
adamc@227 7 * http://creativecommons.org/licenses/by-nc-nd/3.0/
adamc@227 8 *)
adamc@227 9
adamc@227 10 (* begin hide *)
adam@377 11 Require Import List.
adam@377 12
adam@314 13 Require Import DepList CpdtTactics.
adamc@227 14
adamc@227 15 Set Implicit Arguments.
adamc@227 16 (* end hide *)
adamc@227 17
adam@398 18 (** printing $ %({}*% #(<a/>*# *)
adam@398 19 (** printing ^ %*{})% #*<a/>)# *)
adam@398 20
adam@398 21
adamc@227 22
adamc@227 23 (** %\chapter{Universes and Axioms}% *)
adamc@227 24
adam@343 25 (** Many traditional theorems can be proved in Coq without special knowledge of CIC, the logic behind the prover. A development just seems to be using a particular ASCII notation for standard formulas based on %\index{set theory}%set theory. Nonetheless, as we saw in Chapter 4, CIC differs from set theory in starting from fewer orthogonal primitives. It is possible to define the usual logical connectives as derived notions. The foundation of it all is a dependently typed functional programming language, based on dependent function types and inductive type families. By using the facilities of this language directly, we can accomplish some things much more easily than in mainstream math.
adamc@227 26
adam@343 27 %\index{Gallina}%Gallina, which adds features to the more theoretical CIC%~\cite{CIC}%, is the logic implemented in Coq. It has a relatively simple foundation that can be defined rigorously in a page or two of formal proof rules. Still, there are some important subtleties that have practical ramifications. This chapter focuses on those subtleties, avoiding formal metatheory in favor of example code. *)
adamc@227 28
adamc@227 29
adamc@227 30 (** * The [Type] Hierarchy *)
adamc@227 31
adam@343 32 (** %\index{type hierarchy}%Every object in Gallina has a type. *)
adamc@227 33
adamc@227 34 Check 0.
adamc@227 35 (** %\vspace{-.15in}% [[
adamc@227 36 0
adamc@227 37 : nat
adamc@227 38
adamc@227 39 ]]
adamc@227 40
adamc@227 41 It is natural enough that zero be considered as a natural number. *)
adamc@227 42
adamc@227 43 Check nat.
adamc@227 44 (** %\vspace{-.15in}% [[
adamc@227 45 nat
adamc@227 46 : Set
adamc@227 47
adamc@227 48 ]]
adamc@227 49
adam@287 50 From a set theory perspective, it is unsurprising to consider the natural numbers as a %``%#"#set.#"#%''% *)
adamc@227 51
adamc@227 52 Check Set.
adamc@227 53 (** %\vspace{-.15in}% [[
adamc@227 54 Set
adamc@227 55 : Type
adamc@227 56
adamc@227 57 ]]
adamc@227 58
adam@409 59 The type [Set] may be considered as the set of all sets, a concept that set theory handles in terms of%\index{class (in set theory)}% _classes_. In Coq, this more general notion is [Type]. *)
adamc@227 60
adamc@227 61 Check Type.
adamc@227 62 (** %\vspace{-.15in}% [[
adamc@227 63 Type
adamc@227 64 : Type
adamc@227 65
adamc@227 66 ]]
adamc@227 67
adam@343 68 Strangely enough, [Type] appears to be its own type. It is known that polymorphic languages with this property are inconsistent, via %\index{Girard's paradox}%Girard's paradox%~\cite{GirardsParadox}%. That is, using such a language to encode proofs is unwise, because it is possible to %``%#"#prove#"#%''% any proposition. What is really going on here?
adamc@227 69
adam@343 70 Let us repeat some of our queries after toggling a flag related to Coq's printing behavior.%\index{Vernacular commands!Set Printing Universes}% *)
adamc@227 71
adamc@227 72 Set Printing Universes.
adamc@227 73
adamc@227 74 Check nat.
adamc@227 75 (** %\vspace{-.15in}% [[
adamc@227 76 nat
adamc@227 77 : Set
adam@302 78 ]]
adam@398 79 *)
adamc@227 80
adamc@227 81 Check Set.
adamc@227 82 (** %\vspace{-.15in}% [[
adamc@227 83 Set
adamc@227 84 : Type $ (0)+1 ^
adamc@227 85
adam@302 86 ]]
adam@302 87 *)
adamc@227 88
adamc@227 89 Check Type.
adamc@227 90 (** %\vspace{-.15in}% [[
adamc@227 91 Type $ Top.3 ^
adamc@227 92 : Type $ (Top.3)+1 ^
adamc@227 93
adamc@227 94 ]]
adamc@227 95
adam@287 96 Occurrences of [Type] are annotated with some additional information, inside comments. These annotations have to do with the secret behind [Type]: it really stands for an infinite hierarchy of types. The type of [Set] is [Type(0)], the type of [Type(0)] is [Type(1)], the type of [Type(1)] is [Type(2)], and so on. This is how we avoid the %``%#"#[Type : Type]#"#%''% paradox. As a convenience, the universe hierarchy drives Coq's one variety of subtyping. Any term whose type is [Type] at level [i] is automatically also described by [Type] at level [j] when [j > i].
adamc@227 97
adam@398 98 In the outputs of our first [Check] query, we see that the type level of [Set]'s type is [(0)+1]. Here [0] stands for the level of [Set], and we increment it to arrive at the level that _classifies_ [Set].
adamc@227 99
adam@409 100 In the second query's output, we see that the occurrence of [Type] that we check is assigned a fresh%\index{universe variable}% _universe variable_ [Top.3]. The output type increments [Top.3] to move up a level in the universe hierarchy. As we write code that uses definitions whose types mention universe variables, unification may refine the values of those variables. Luckily, the user rarely has to worry about the details.
adamc@227 101
adam@409 102 Another crucial concept in CIC is%\index{predicativity}% _predicativity_. Consider these queries. *)
adamc@227 103
adamc@227 104 Check forall T : nat, fin T.
adamc@227 105 (** %\vspace{-.15in}% [[
adamc@227 106 forall T : nat, fin T
adamc@227 107 : Set
adam@302 108 ]]
adam@302 109 *)
adamc@227 110
adamc@227 111 Check forall T : Set, T.
adamc@227 112 (** %\vspace{-.15in}% [[
adamc@227 113 forall T : Set, T
adamc@227 114 : Type $ max(0, (0)+1) ^
adam@302 115 ]]
adam@302 116 *)
adamc@227 117
adamc@227 118 Check forall T : Type, T.
adamc@227 119 (** %\vspace{-.15in}% [[
adamc@227 120 forall T : Type $ Top.9 ^ , T
adamc@227 121 : Type $ max(Top.9, (Top.9)+1) ^
adamc@227 122
adamc@227 123 ]]
adamc@227 124
adamc@227 125 These outputs demonstrate the rule for determining which universe a [forall] type lives in. In particular, for a type [forall x : T1, T2], we take the maximum of the universes of [T1] and [T2]. In the first example query, both [T1] ([nat]) and [T2] ([fin T]) are in [Set], so the [forall] type is in [Set], too. In the second query, [T1] is [Set], which is at level [(0)+1]; and [T2] is [T], which is at level [0]. Thus, the [forall] exists at the maximum of these two levels. The third example illustrates the same outcome, where we replace [Set] with an occurrence of [Type] that is assigned universe variable [Top.9]. This universe variable appears in the places where [0] appeared in the previous query.
adamc@227 126
adam@287 127 The behind-the-scenes manipulation of universe variables gives us predicativity. Consider this simple definition of a polymorphic identity function, where the first argument [T] will automatically be marked as implicit, since it can be inferred from the type of the second argument [x]. *)
adamc@227 128
adamc@227 129 Definition id (T : Set) (x : T) : T := x.
adamc@227 130
adamc@227 131 Check id 0.
adamc@227 132 (** %\vspace{-.15in}% [[
adamc@227 133 id 0
adamc@227 134 : nat
adamc@227 135
adamc@227 136 Check id Set.
adam@343 137 ]]
adamc@227 138
adam@343 139 <<
adamc@227 140 Error: Illegal application (Type Error):
adamc@227 141 ...
adam@343 142 The 1st term has type "Type (* (Top.15)+1 *)" which should be coercible to "Set".
adam@343 143 >>
adamc@227 144
adam@343 145 The parameter [T] of [id] must be instantiated with a [Set]. The type [nat] is a [Set], but [Set] is not. We can try fixing the problem by generalizing our definition of [id]. *)
adamc@227 146
adamc@227 147 Reset id.
adamc@227 148 Definition id (T : Type) (x : T) : T := x.
adamc@227 149 Check id 0.
adamc@227 150 (** %\vspace{-.15in}% [[
adamc@227 151 id 0
adamc@227 152 : nat
adam@302 153 ]]
adam@302 154 *)
adamc@227 155
adamc@227 156 Check id Set.
adamc@227 157 (** %\vspace{-.15in}% [[
adamc@227 158 id Set
adamc@227 159 : Type $ Top.17 ^
adam@302 160 ]]
adam@302 161 *)
adamc@227 162
adamc@227 163 Check id Type.
adamc@227 164 (** %\vspace{-.15in}% [[
adamc@227 165 id Type $ Top.18 ^
adamc@227 166 : Type $ Top.19 ^
adam@302 167 ]]
adam@302 168 *)
adamc@227 169
adamc@227 170 (** So far so good. As we apply [id] to different [T] values, the inferred index for [T]'s [Type] occurrence automatically moves higher up the type hierarchy.
adamc@227 171 [[
adamc@227 172 Check id id.
adam@343 173 ]]
adamc@227 174
adam@343 175 <<
adamc@227 176 Error: Universe inconsistency (cannot enforce Top.16 < Top.16).
adam@343 177 >>
adamc@227 178
adam@398 179 %\index{universe inconsistency}%This error message reminds us that the universe variable for [T] still exists, even though it is usually hidden. To apply [id] to itself, that variable would need to be less than itself in the type hierarchy. Universe inconsistency error messages announce cases like this one where a term could only type-check by violating an implied constraint over universe variables. Such errors demonstrate that [Type] is _predicative_, where this word has a CIC meaning closely related to its usual mathematical meaning. A predicative system enforces the constraint that, for any object of quantified type, none of those quantifiers may ever be instantiated with the object itself. %\index{impredicativity}%Impredicativity is associated with popular paradoxes in set theory, involving inconsistent constructions like %``%#"#the set of all sets that do not contain themselves#"#%''% (%\index{Russell's paradox}%Russell's paradox). Similar paradoxes would result from uncontrolled impredicativity in Coq. *)
adamc@227 180
adamc@227 181
adamc@227 182 (** ** Inductive Definitions *)
adamc@227 183
adamc@227 184 (** Predicativity restrictions also apply to inductive definitions. As an example, let us consider a type of expression trees that allows injection of any native Coq value. The idea is that an [exp T] stands for a reflected expression of type [T].
adamc@227 185
adamc@227 186 [[
adamc@227 187 Inductive exp : Set -> Set :=
adamc@227 188 | Const : forall T : Set, T -> exp T
adamc@227 189 | Pair : forall T1 T2, exp T1 -> exp T2 -> exp (T1 * T2)
adamc@227 190 | Eq : forall T, exp T -> exp T -> exp bool.
adam@343 191 ]]
adamc@227 192
adam@343 193 <<
adamc@227 194 Error: Large non-propositional inductive types must be in Type.
adam@343 195 >>
adamc@227 196
adam@409 197 This definition is%\index{large inductive types}% _large_ in the sense that at least one of its constructors takes an argument whose type has type [Type]. Coq would be inconsistent if we allowed definitions like this one in their full generality. Instead, we must change [exp] to live in [Type]. We will go even further and move [exp]'s index to [Type] as well. *)
adamc@227 198
adamc@227 199 Inductive exp : Type -> Type :=
adamc@227 200 | Const : forall T, T -> exp T
adamc@227 201 | Pair : forall T1 T2, exp T1 -> exp T2 -> exp (T1 * T2)
adamc@227 202 | Eq : forall T, exp T -> exp T -> exp bool.
adamc@227 203
adamc@228 204 (** Note that before we had to include an annotation [: Set] for the variable [T] in [Const]'s type, but we need no annotation now. When the type of a variable is not known, and when that variable is used in a context where only types are allowed, Coq infers that the variable is of type [Type]. That is the right behavior here, but it was wrong for the [Set] version of [exp].
adamc@228 205
adamc@228 206 Our new definition is accepted. We can build some sample expressions. *)
adamc@227 207
adamc@227 208 Check Const 0.
adamc@227 209 (** %\vspace{-.15in}% [[
adamc@227 210 Const 0
adamc@227 211 : exp nat
adam@302 212 ]]
adam@302 213 *)
adamc@227 214
adamc@227 215 Check Pair (Const 0) (Const tt).
adamc@227 216 (** %\vspace{-.15in}% [[
adamc@227 217 Pair (Const 0) (Const tt)
adamc@227 218 : exp (nat * unit)
adam@302 219 ]]
adam@302 220 *)
adamc@227 221
adamc@227 222 Check Eq (Const Set) (Const Type).
adamc@227 223 (** %\vspace{-.15in}% [[
adamc@228 224 Eq (Const Set) (Const Type $ Top.59 ^ )
adamc@227 225 : exp bool
adamc@227 226
adamc@227 227 ]]
adamc@227 228
adamc@227 229 We can check many expressions, including fancy expressions that include types. However, it is not hard to hit a type-checking wall.
adamc@227 230
adamc@227 231 [[
adamc@227 232 Check Const (Const O).
adam@343 233 ]]
adamc@227 234
adam@343 235 <<
adamc@227 236 Error: Universe inconsistency (cannot enforce Top.42 < Top.42).
adam@343 237 >>
adamc@227 238
adamc@227 239 We are unable to instantiate the parameter [T] of [Const] with an [exp] type. To see why, it is helpful to print the annotated version of [exp]'s inductive definition. *)
adamc@227 240
adam@417 241 (** [[
adamc@227 242 Print exp.
adam@417 243 ]]
adam@417 244
adam@417 245 [[
adamc@227 246 Inductive exp
adamc@227 247 : Type $ Top.8 ^ ->
adamc@227 248 Type
adamc@227 249 $ max(0, (Top.11)+1, (Top.14)+1, (Top.15)+1, (Top.19)+1) ^ :=
adamc@227 250 Const : forall T : Type $ Top.11 ^ , T -> exp T
adamc@227 251 | Pair : forall (T1 : Type $ Top.14 ^ ) (T2 : Type $ Top.15 ^ ),
adamc@227 252 exp T1 -> exp T2 -> exp (T1 * T2)
adamc@227 253 | Eq : forall T : Type $ Top.19 ^ , exp T -> exp T -> exp bool
adamc@227 254
adamc@227 255 ]]
adamc@227 256
adam@398 257 We see that the index type of [exp] has been assigned to universe level [Top.8]. In addition, each of the four occurrences of [Type] in the types of the constructors gets its own universe variable. Each of these variables appears explicitly in the type of [exp]. In particular, any type [exp T] lives at a universe level found by incrementing by one the maximum of the four argument variables. A consequence of this is that [exp] _must_ live at a higher universe level than any type which may be passed to one of its constructors. This consequence led to the universe inconsistency.
adamc@227 258
adam@343 259 Strangely, the universe variable [Top.8] only appears in one place. Is there no restriction imposed on which types are valid arguments to [exp]? In fact, there is a restriction, but it only appears in a global set of universe constraints that are maintained %``%#"#off to the side,#"#%''% not appearing explicitly in types. We can print the current database.%\index{Vernacular commands!Print Universes}% *)
adamc@227 260
adamc@227 261 Print Universes.
adamc@227 262 (** %\vspace{-.15in}% [[
adamc@227 263 Top.19 < Top.9 <= Top.8
adamc@227 264 Top.15 < Top.9 <= Top.8 <= Coq.Init.Datatypes.38
adamc@227 265 Top.14 < Top.9 <= Top.8 <= Coq.Init.Datatypes.37
adamc@227 266 Top.11 < Top.9 <= Top.8
adamc@227 267
adamc@227 268 ]]
adamc@227 269
adam@343 270 The command outputs many more constraints, but we have collected only those that mention [Top] variables. We see one constraint for each universe variable associated with a constructor argument from [exp]'s definition. Universe variable [Top.19] is the type argument to [Eq]. The constraint for [Top.19] effectively says that [Top.19] must be less than [Top.8], the universe of [exp]'s indices; an intermediate variable [Top.9] appears as an artifact of the way the constraint was generated.
adamc@227 271
adamc@227 272 The next constraint, for [Top.15], is more complicated. This is the universe of the second argument to the [Pair] constructor. Not only must [Top.15] be less than [Top.8], but it also comes out that [Top.8] must be less than [Coq.Init.Datatypes.38]. What is this new universe variable? It is from the definition of the [prod] inductive family, to which types of the form [A * B] are desugared. *)
adamc@227 273
adam@417 274 (* begin hide *)
adam@417 275 Inductive prod := pair.
adam@417 276 Reset prod.
adam@417 277 (* end hide *)
adam@417 278
adam@417 279 (** [[
adamc@227 280 Print prod.
adam@417 281 ]]
adam@417 282
adam@417 283 [[
adamc@227 284 Inductive prod (A : Type $ Coq.Init.Datatypes.37 ^ )
adamc@227 285 (B : Type $ Coq.Init.Datatypes.38 ^ )
adamc@227 286 : Type $ max(Coq.Init.Datatypes.37, Coq.Init.Datatypes.38) ^ :=
adamc@227 287 pair : A -> B -> A * B
adamc@227 288
adamc@227 289 ]]
adamc@227 290
adamc@227 291 We see that the constraint is enforcing that indices to [exp] must not live in a higher universe level than [B]-indices to [prod]. The next constraint above establishes a symmetric condition for [A].
adamc@227 292
adamc@227 293 Thus it is apparent that Coq maintains a tortuous set of universe variable inequalities behind the scenes. It may look like some functions are polymorphic in the universe levels of their arguments, but what is really happening is imperative updating of a system of constraints, such that all uses of a function are consistent with a global set of universe levels. When the constraint system may not be evolved soundly, we get a universe inconsistency error.
adamc@227 294
adamc@227 295 %\medskip%
adamc@227 296
adam@398 297 Something interesting is revealed in the annotated definition of [prod]. A type [prod A B] lives at a universe that is the maximum of the universes of [A] and [B]. From our earlier experiments, we might expect that [prod]'s universe would in fact need to be _one higher_ than the maximum. The critical difference is that, in the definition of [prod], [A] and [B] are defined as _parameters_; that is, they appear named to the left of the main colon, rather than appearing (possibly unnamed) to the right.
adamc@227 298
adamc@231 299 Parameters are not as flexible as normal inductive type arguments. The range types of all of the constructors of a parameterized type must share the same parameters. Nonetheless, when it is possible to define a polymorphic type in this way, we gain the ability to use the new type family in more ways, without triggering universe inconsistencies. For instance, nested pairs of types are perfectly legal. *)
adamc@227 300
adamc@227 301 Check (nat, (Type, Set)).
adamc@227 302 (** %\vspace{-.15in}% [[
adamc@227 303 (nat, (Type $ Top.44 ^ , Set))
adamc@227 304 : Set * (Type $ Top.45 ^ * Type $ Top.46 ^ )
adamc@227 305 ]]
adamc@227 306
adamc@227 307 The same cannot be done with a counterpart to [prod] that does not use parameters. *)
adamc@227 308
adamc@227 309 Inductive prod' : Type -> Type -> Type :=
adamc@227 310 | pair' : forall A B : Type, A -> B -> prod' A B.
adamc@227 311 (** [[
adamc@227 312 Check (pair' nat (pair' Type Set)).
adam@343 313 ]]
adamc@227 314
adam@343 315 <<
adamc@227 316 Error: Universe inconsistency (cannot enforce Top.51 < Top.51).
adam@343 317 >>
adamc@227 318
adamc@233 319 The key benefit parameters bring us is the ability to avoid quantifying over types in the types of constructors. Such quantification induces less-than constraints, while parameters only introduce less-than-or-equal-to constraints.
adamc@233 320
adam@343 321 Coq includes one more (potentially confusing) feature related to parameters. While Gallina does not support real %\index{universe polymorphism}%universe polymorphism, there is a convenience facility that mimics universe polymorphism in some cases. We can illustrate what this means with a simple example. *)
adamc@233 322
adamc@233 323 Inductive foo (A : Type) : Type :=
adamc@233 324 | Foo : A -> foo A.
adamc@229 325
adamc@229 326 (* begin hide *)
adamc@229 327 Unset Printing Universes.
adamc@229 328 (* end hide *)
adamc@229 329
adamc@233 330 Check foo nat.
adamc@233 331 (** %\vspace{-.15in}% [[
adamc@233 332 foo nat
adamc@233 333 : Set
adam@302 334 ]]
adam@302 335 *)
adamc@233 336
adamc@233 337 Check foo Set.
adamc@233 338 (** %\vspace{-.15in}% [[
adamc@233 339 foo Set
adamc@233 340 : Type
adam@302 341 ]]
adam@302 342 *)
adamc@233 343
adamc@233 344 Check foo True.
adamc@233 345 (** %\vspace{-.15in}% [[
adamc@233 346 foo True
adamc@233 347 : Prop
adamc@233 348
adamc@233 349 ]]
adamc@233 350
adam@287 351 The basic pattern here is that Coq is willing to automatically build a %``%#"#copied-and-pasted#"#%''% version of an inductive definition, where some occurrences of [Type] have been replaced by [Set] or [Prop]. In each context, the type-checker tries to find the valid replacements that are lowest in the type hierarchy. Automatic cloning of definitions can be much more convenient than manual cloning. We have already taken advantage of the fact that we may re-use the same families of tuple and list types to form values in [Set] and [Type].
adamc@233 352
adamc@233 353 Imitation polymorphism can be confusing in some contexts. For instance, it is what is responsible for this weird behavior. *)
adamc@233 354
adamc@233 355 Inductive bar : Type := Bar : bar.
adamc@233 356
adamc@233 357 Check bar.
adamc@233 358 (** %\vspace{-.15in}% [[
adamc@233 359 bar
adamc@233 360 : Prop
adamc@233 361 ]]
adamc@233 362
adamc@233 363 The type that Coq comes up with may be used in strictly more contexts than the type one might have expected. *)
adamc@233 364
adamc@229 365
adam@388 366 (** ** Deciphering Baffling Messages About Inability to Unify *)
adam@388 367
adam@388 368 (** One of the most confusing sorts of Coq error messages arises from an interplay between universes, syntax notations, and %\index{implicit arguments}%implicit arguments. Consider the following innocuous lemma, which is symmetry of equality for the special case of types. *)
adam@388 369
adam@388 370 Theorem symmetry : forall A B : Type,
adam@388 371 A = B
adam@388 372 -> B = A.
adam@388 373 intros ? ? H; rewrite H; reflexivity.
adam@388 374 Qed.
adam@388 375
adam@388 376 (** Let us attempt an admittedly silly proof of the following theorem. *)
adam@388 377
adam@388 378 Theorem illustrative_but_silly_detour : unit = unit.
adam@388 379 (** [[
adam@388 380 apply symmetry.
adam@388 381 ]]
adam@388 382 <<
adam@388 383 Error: Impossible to unify "?35 = ?34" with "unit = unit".
adam@388 384 >>
adam@388 385
adam@398 386 Coq tells us that we cannot, in fact, apply our lemma [symmetry] here, but the error message seems defective. In particular, one might think that [apply] should unify [?35] and [?34] with [unit] to ensure that the unification goes through. In fact, the problem is in a part of the unification problem that is _not_ shown to us in this error message!
adam@388 387
adam@388 388 The following command is the secret to getting better error messages in such cases: *)
adam@388 389
adam@388 390 Set Printing All.
adam@388 391 (** [[
adam@388 392 apply symmetry.
adam@388 393 ]]
adam@388 394 <<
adam@388 395 Error: Impossible to unify "@eq Type ?46 ?45" with "@eq Set unit unit".
adam@388 396 >>
adam@388 397
adam@398 398 Now we can see the problem: it is the first, _implicit_ argument to the underlying equality function [eq] that disagrees across the two terms. The universe [Set] may be both an element and a subtype of [Type], but the two are not definitionally equal. *)
adam@388 399
adam@388 400 Abort.
adam@388 401
adam@388 402 (** A variety of changes to the theorem statement would lead to use of [Type] as the implicit argument of [eq]. Here is one such change. *)
adam@388 403
adam@388 404 Theorem illustrative_but_silly_detour : (unit : Type) = unit.
adam@388 405 apply symmetry; reflexivity.
adam@388 406 Qed.
adam@388 407
adam@388 408 (** There are many related issues that can come up with error messages, where one or both of notations and implicit arguments hide important details. The [Set Printing All] command turns off all such features and exposes underlying CIC terms.
adam@388 409
adam@388 410 For completeness, we mention one other class of confusing error message about inability to unify two terms that look obviously unifiable. Each unification variable has a scope; a unification variable instantiation may not mention variables that were not already defined within that scope, at the point in proof search where the unification variable was introduced. Consider this illustrative example: *)
adam@388 411
adam@388 412 Unset Printing All.
adam@388 413
adam@388 414 Theorem ex_symmetry : (exists x, x = 0) -> (exists x, 0 = x).
adam@388 415 econstructor.
adam@388 416 (** %\vspace{-.15in}%[[
adam@388 417 H : exists x : nat, x = 0
adam@388 418 ============================
adam@388 419 0 = ?98
adam@388 420 ]]
adam@388 421 *)
adam@388 422
adam@388 423 destruct H.
adam@388 424 (** %\vspace{-.15in}%[[
adam@388 425 x : nat
adam@388 426 H : x = 0
adam@388 427 ============================
adam@388 428 0 = ?99
adam@388 429 ]]
adam@388 430 *)
adam@388 431
adam@388 432 (** [[
adam@388 433 symmetry; exact H.
adam@388 434 ]]
adam@388 435
adam@388 436 <<
adam@388 437 Error: In environment
adam@388 438 x : nat
adam@388 439 H : x = 0
adam@388 440 The term "H" has type "x = 0" while it is expected to have type
adam@388 441 "?99 = 0".
adam@388 442 >>
adam@388 443
adam@398 444 The problem here is that variable [x] was introduced by [destruct] _after_ we introduced [?99] with [eexists], so the instantiation of [?99] may not mention [x]. A simple reordering of the proof solves the problem. *)
adam@388 445
adam@388 446 Restart.
adam@388 447 destruct 1 as [x]; apply ex_intro with x; symmetry; assumption.
adam@388 448 Qed.
adam@388 449
adam@409 450 (** This restriction for unification variables may seem counterintuitive, but it follows from the fact that CIC contains no concept of unification variable. Rather, to construct the final proof term, at the point in a proof where the unification variable is introduced, we replace it with the instantiation we eventually find for it. It is simply syntactically illegal to refer there to variables that are not in scope. Without such a restriction, we could trivially %``%#"#prove#"#%''% such non-theorems as [exists n : nat, forall m : nat, n = m] by [econstructor; intro; reflexivity]. *)
adam@388 451
adam@388 452
adamc@229 453 (** * The [Prop] Universe *)
adamc@229 454
adam@287 455 (** In Chapter 4, we saw parallel versions of useful datatypes for %``%#"#programs#"#%''% and %``%#"#proofs.#"#%''% The convention was that programs live in [Set], and proofs live in [Prop]. We gave little explanation for why it is useful to maintain this distinction. There is certainly documentation value from separating programs from proofs; in practice, different concerns apply to building the two types of objects. It turns out, however, that these concerns motivate formal differences between the two universes in Coq.
adamc@229 456
adamc@229 457 Recall the types [sig] and [ex], which are the program and proof versions of existential quantification. Their definitions differ only in one place, where [sig] uses [Type] and [ex] uses [Prop]. *)
adamc@229 458
adamc@229 459 Print sig.
adamc@229 460 (** %\vspace{-.15in}% [[
adamc@229 461 Inductive sig (A : Type) (P : A -> Prop) : Type :=
adamc@229 462 exist : forall x : A, P x -> sig P
adam@302 463 ]]
adam@302 464 *)
adamc@229 465
adamc@229 466 Print ex.
adamc@229 467 (** %\vspace{-.15in}% [[
adamc@229 468 Inductive ex (A : Type) (P : A -> Prop) : Prop :=
adamc@229 469 ex_intro : forall x : A, P x -> ex P
adamc@229 470 ]]
adamc@229 471
adamc@229 472 It is natural to want a function to extract the first components of data structures like these. Doing so is easy enough for [sig]. *)
adamc@229 473
adamc@229 474 Definition projS A (P : A -> Prop) (x : sig P) : A :=
adamc@229 475 match x with
adamc@229 476 | exist v _ => v
adamc@229 477 end.
adamc@229 478
adamc@229 479 (** We run into trouble with a version that has been changed to work with [ex].
adamc@229 480 [[
adamc@229 481 Definition projE A (P : A -> Prop) (x : ex P) : A :=
adamc@229 482 match x with
adamc@229 483 | ex_intro v _ => v
adamc@229 484 end.
adam@343 485 ]]
adamc@229 486
adam@343 487 <<
adamc@229 488 Error:
adamc@229 489 Incorrect elimination of "x" in the inductive type "ex":
adamc@229 490 the return type has sort "Type" while it should be "Prop".
adamc@229 491 Elimination of an inductive object of sort Prop
adamc@229 492 is not allowed on a predicate in sort Type
adamc@229 493 because proofs can be eliminated only to build proofs.
adam@343 494 >>
adamc@229 495
adam@343 496 In formal Coq parlance, %\index{elimination}``%#"#elimination#"#%''% means %``%#"#pattern-matching.#"#%''% The typing rules of Gallina forbid us from pattern-matching on a discriminee whose type belongs to [Prop], whenever the result type of the [match] has a type besides [Prop]. This is a sort of %``%#"#information flow#"#%''% policy, where the type system ensures that the details of proofs can never have any effect on parts of a development that are not also marked as proofs.
adamc@229 497
adamc@229 498 This restriction matches informal practice. We think of programs and proofs as clearly separated, and, outside of constructive logic, the idea of computing with proofs is ill-formed. The distinction also has practical importance in Coq, where it affects the behavior of extraction.
adamc@229 499
adam@398 500 Recall that %\index{program extraction}%extraction is Coq's facility for translating Coq developments into programs in general-purpose programming languages like OCaml. Extraction _erases_ proofs and leaves programs intact. A simple example with [sig] and [ex] demonstrates the distinction. *)
adamc@229 501
adamc@229 502 Definition sym_sig (x : sig (fun n => n = 0)) : sig (fun n => 0 = n) :=
adamc@229 503 match x with
adamc@229 504 | exist n pf => exist _ n (sym_eq pf)
adamc@229 505 end.
adamc@229 506
adamc@229 507 Extraction sym_sig.
adamc@229 508 (** <<
adamc@229 509 (** val sym_sig : nat -> nat **)
adamc@229 510
adamc@229 511 let sym_sig x = x
adamc@229 512 >>
adamc@229 513
adamc@229 514 Since extraction erases proofs, the second components of [sig] values are elided, making [sig] a simple identity type family. The [sym_sig] operation is thus an identity function. *)
adamc@229 515
adamc@229 516 Definition sym_ex (x : ex (fun n => n = 0)) : ex (fun n => 0 = n) :=
adamc@229 517 match x with
adamc@229 518 | ex_intro n pf => ex_intro _ n (sym_eq pf)
adamc@229 519 end.
adamc@229 520
adamc@229 521 Extraction sym_ex.
adamc@229 522 (** <<
adamc@229 523 (** val sym_ex : __ **)
adamc@229 524
adamc@229 525 let sym_ex = __
adamc@229 526 >>
adamc@229 527
adam@302 528 In this example, the [ex] type itself is in [Prop], so whole [ex] packages are erased. Coq extracts every proposition as the (Coq-specific) type %\texttt{\_\_}%#<tt>__</tt>#, whose single constructor is %\texttt{\_\_}%#<tt>__</tt>#. Not only are proofs replaced by [__], but proof arguments to functions are also removed completely, as we see here.
adamc@229 529
adam@409 530 Extraction is very helpful as an optimization over programs that contain proofs. In languages like Haskell, advanced features make it possible to program with proofs, as a way of convincing the type checker to accept particular definitions. Unfortunately, when proofs are encoded as values in GADT's%~\cite{GADT}%, these proofs exist at runtime and consume resources. In contrast, with Coq, as long as all proofs are kept within [Prop], extraction is guaranteed to erase them.
adamc@229 531
adam@398 532 Many fans of the %\index{Curry-Howard correspondence}%Curry-Howard correspondence support the idea of _extracting programs from proofs_. In reality, few users of Coq and related tools do any such thing. Instead, extraction is better thought of as an optimization that reduces the runtime costs of expressive typing.
adamc@229 533
adamc@229 534 %\medskip%
adamc@229 535
adam@409 536 We have seen two of the differences between proofs and programs: proofs are subject to an elimination restriction and are elided by extraction. The remaining difference is that [Prop] is%\index{impredicativity}% _impredicative_, as this example shows. *)
adamc@229 537
adamc@229 538 Check forall P Q : Prop, P \/ Q -> Q \/ P.
adamc@229 539 (** %\vspace{-.15in}% [[
adamc@229 540 forall P Q : Prop, P \/ Q -> Q \/ P
adamc@229 541 : Prop
adamc@229 542
adamc@229 543 ]]
adamc@229 544
adamc@230 545 We see that it is possible to define a [Prop] that quantifies over other [Prop]s. This is fortunate, as we start wanting that ability even for such basic purposes as stating propositional tautologies. In the next section of this chapter, we will see some reasons why unrestricted impredicativity is undesirable. The impredicativity of [Prop] interacts crucially with the elimination restriction to avoid those pitfalls.
adamc@230 546
adamc@230 547 Impredicativity also allows us to implement a version of our earlier [exp] type that does not suffer from the weakness that we found. *)
adamc@230 548
adamc@230 549 Inductive expP : Type -> Prop :=
adamc@230 550 | ConstP : forall T, T -> expP T
adamc@230 551 | PairP : forall T1 T2, expP T1 -> expP T2 -> expP (T1 * T2)
adamc@230 552 | EqP : forall T, expP T -> expP T -> expP bool.
adamc@230 553
adamc@230 554 Check ConstP 0.
adamc@230 555 (** %\vspace{-.15in}% [[
adamc@230 556 ConstP 0
adamc@230 557 : expP nat
adam@302 558 ]]
adam@302 559 *)
adamc@230 560
adamc@230 561 Check PairP (ConstP 0) (ConstP tt).
adamc@230 562 (** %\vspace{-.15in}% [[
adamc@230 563 PairP (ConstP 0) (ConstP tt)
adamc@230 564 : expP (nat * unit)
adam@302 565 ]]
adam@302 566 *)
adamc@230 567
adamc@230 568 Check EqP (ConstP Set) (ConstP Type).
adamc@230 569 (** %\vspace{-.15in}% [[
adamc@230 570 EqP (ConstP Set) (ConstP Type)
adamc@230 571 : expP bool
adam@302 572 ]]
adam@302 573 *)
adamc@230 574
adamc@230 575 Check ConstP (ConstP O).
adamc@230 576 (** %\vspace{-.15in}% [[
adamc@230 577 ConstP (ConstP 0)
adamc@230 578 : expP (expP nat)
adamc@230 579
adamc@230 580 ]]
adamc@230 581
adam@287 582 In this case, our victory is really a shallow one. As we have marked [expP] as a family of proofs, we cannot deconstruct our expressions in the usual programmatic ways, which makes them almost useless for the usual purposes. Impredicative quantification is much more useful in defining inductive families that we really think of as judgments. For instance, this code defines a notion of equality that is strictly more permissive than the base equality [=]. *)
adamc@230 583
adamc@230 584 Inductive eqPlus : forall T, T -> T -> Prop :=
adamc@230 585 | Base : forall T (x : T), eqPlus x x
adamc@230 586 | Func : forall dom ran (f1 f2 : dom -> ran),
adamc@230 587 (forall x : dom, eqPlus (f1 x) (f2 x))
adamc@230 588 -> eqPlus f1 f2.
adamc@230 589
adamc@230 590 Check (Base 0).
adamc@230 591 (** %\vspace{-.15in}% [[
adamc@230 592 Base 0
adamc@230 593 : eqPlus 0 0
adam@302 594 ]]
adam@302 595 *)
adamc@230 596
adamc@230 597 Check (Func (fun n => n) (fun n => 0 + n) (fun n => Base n)).
adamc@230 598 (** %\vspace{-.15in}% [[
adamc@230 599 Func (fun n : nat => n) (fun n : nat => 0 + n) (fun n : nat => Base n)
adamc@230 600 : eqPlus (fun n : nat => n) (fun n : nat => 0 + n)
adam@302 601 ]]
adam@302 602 *)
adamc@230 603
adamc@230 604 Check (Base (Base 1)).
adamc@230 605 (** %\vspace{-.15in}% [[
adamc@230 606 Base (Base 1)
adamc@230 607 : eqPlus (Base 1) (Base 1)
adam@302 608 ]]
adam@302 609 *)
adamc@230 610
adam@343 611 (** Stating equality facts about proofs may seem baroque, but we have already seen its utility in the chapter on reasoning about equality proofs. *)
adam@343 612
adamc@230 613
adamc@230 614 (** * Axioms *)
adamc@230 615
adam@409 616 (** While the specific logic Gallina is hardcoded into Coq's implementation, it is possible to add certain logical rules in a controlled way. In other words, Coq may be used to reason about many different refinements of Gallina where strictly more theorems are provable. We achieve this by asserting%\index{axioms}% _axioms_ without proof.
adamc@230 617
adamc@230 618 We will motivate the idea by touring through some standard axioms, as enumerated in Coq's online FAQ. I will add additional commentary as appropriate. *)
adamc@230 619
adamc@230 620 (** ** The Basics *)
adamc@230 621
adam@343 622 (** One simple example of a useful axiom is the %\index{law of the excluded middle}%law of the excluded middle. *)
adamc@230 623
adamc@230 624 Require Import Classical_Prop.
adamc@230 625 Print classic.
adamc@230 626 (** %\vspace{-.15in}% [[
adamc@230 627 *** [ classic : forall P : Prop, P \/ ~ P ]
adamc@230 628 ]]
adamc@230 629
adam@343 630 In the implementation of module [Classical_Prop], this axiom was defined with the command%\index{Vernacular commands!Axiom}% *)
adamc@230 631
adamc@230 632 Axiom classic : forall P : Prop, P \/ ~ P.
adamc@230 633
adam@343 634 (** An [Axiom] may be declared with any type, in any of the universes. There is a synonym %\index{Vernacular commands!Parameter}%[Parameter] for [Axiom], and that synonym is often clearer for assertions not of type [Prop]. For instance, we can assert the existence of objects with certain properties. *)
adamc@230 635
adamc@230 636 Parameter n : nat.
adamc@230 637 Axiom positive : n > 0.
adamc@230 638 Reset n.
adamc@230 639
adam@287 640 (** This kind of %``%#"#axiomatic presentation#"#%''% of a theory is very common outside of higher-order logic. However, in Coq, it is almost always preferable to stick to defining your objects, functions, and predicates via inductive definitions and functional programming.
adamc@230 641
adam@409 642 In general, there is a significant burden associated with any use of axioms. It is easy to assert a set of axioms that together is%\index{inconsistent axioms}% _inconsistent_. That is, a set of axioms may imply [False], which allows any theorem to be proved, which defeats the purpose of a proof assistant. For example, we could assert the following axiom, which is consistent by itself but inconsistent when combined with [classic]. *)
adamc@230 643
adam@287 644 Axiom not_classic : ~ forall P : Prop, P \/ ~ P.
adamc@230 645
adamc@230 646 Theorem uhoh : False.
adam@287 647 generalize classic not_classic; tauto.
adamc@230 648 Qed.
adamc@230 649
adamc@230 650 Theorem uhoh_again : 1 + 1 = 3.
adamc@230 651 destruct uhoh.
adamc@230 652 Qed.
adamc@230 653
adamc@230 654 Reset not_classic.
adamc@230 655
adam@398 656 (** On the subject of the law of the excluded middle itself, this axiom is usually quite harmless, and many practical Coq developments assume it. It has been proved metatheoretically to be consistent with CIC. Here, %``%#"#proved metatheoretically#"#%''% means that someone proved on paper that excluded middle holds in a _model_ of CIC in set theory%~\cite{SetsInTypes}%. All of the other axioms that we will survey in this section hold in the same model, so they are all consistent together.
adamc@230 657
adam@409 658 Recall that Coq implements%\index{constructive logic}% _constructive_ logic by default, where excluded middle is not provable. Proofs in constructive logic can be thought of as programs. A [forall] quantifier denotes a dependent function type, and a disjunction denotes a variant type. In such a setting, excluded middle could be interpreted as a decision procedure for arbitrary propositions, which computability theory tells us cannot exist. Thus, constructive logic with excluded middle can no longer be associated with our usual notion of programming.
adamc@230 659
adam@398 660 Given all this, why is it all right to assert excluded middle as an axiom? The intuitive justification is that the elimination restriction for [Prop] prevents us from treating proofs as programs. An excluded middle axiom that quantified over [Set] instead of [Prop] _would_ be problematic. If a development used that axiom, we would not be able to extract the code to OCaml (soundly) without implementing a genuine universal decision procedure. In contrast, values whose types belong to [Prop] are always erased by extraction, so we sidestep the axiom's algorithmic consequences.
adamc@230 661
adam@343 662 Because the proper use of axioms is so precarious, there are helpful commands for determining which axioms a theorem relies on.%\index{Vernacular commands!Print Assumptions}% *)
adamc@230 663
adamc@230 664 Theorem t1 : forall P : Prop, P -> ~ ~ P.
adamc@230 665 tauto.
adamc@230 666 Qed.
adamc@230 667
adamc@230 668 Print Assumptions t1.
adam@343 669 (** <<
adamc@230 670 Closed under the global context
adam@343 671 >>
adam@302 672 *)
adamc@230 673
adamc@230 674 Theorem t2 : forall P : Prop, ~ ~ P -> P.
adamc@230 675 (** [[
adamc@230 676 tauto.
adam@343 677 ]]
adam@343 678 <<
adamc@230 679 Error: tauto failed.
adam@343 680 >>
adam@302 681 *)
adamc@230 682 intro P; destruct (classic P); tauto.
adamc@230 683 Qed.
adamc@230 684
adamc@230 685 Print Assumptions t2.
adamc@230 686 (** %\vspace{-.15in}% [[
adamc@230 687 Axioms:
adamc@230 688 classic : forall P : Prop, P \/ ~ P
adamc@230 689 ]]
adamc@230 690
adam@398 691 It is possible to avoid this dependence in some specific cases, where excluded middle _is_ provable, for decidable families of propositions. *)
adamc@230 692
adam@287 693 Theorem nat_eq_dec : forall n m : nat, n = m \/ n <> m.
adamc@230 694 induction n; destruct m; intuition; generalize (IHn m); intuition.
adamc@230 695 Qed.
adamc@230 696
adamc@230 697 Theorem t2' : forall n m : nat, ~ ~ (n = m) -> n = m.
adam@287 698 intros n m; destruct (nat_eq_dec n m); tauto.
adamc@230 699 Qed.
adamc@230 700
adamc@230 701 Print Assumptions t2'.
adam@343 702 (** <<
adamc@230 703 Closed under the global context
adam@343 704 >>
adamc@230 705
adamc@230 706 %\bigskip%
adamc@230 707
adam@409 708 Mainstream mathematical practice assumes excluded middle, so it can be useful to have it available in Coq developments, though it is also nice to know that a theorem is proved in a simpler formal system than classical logic. There is a similar story for%\index{proof irrelevance}% _proof irrelevance_, which simplifies proof issues that would not even arise in mainstream math. *)
adamc@230 709
adamc@230 710 Require Import ProofIrrelevance.
adamc@230 711 Print proof_irrelevance.
adamc@230 712 (** %\vspace{-.15in}% [[
adamc@230 713 *** [ proof_irrelevance : forall (P : Prop) (p1 p2 : P), p1 = p2 ]
adamc@230 714 ]]
adamc@230 715
adam@353 716 This axiom asserts that any two proofs of the same proposition are equal. If we replaced [p1 = p2] by [p1 <-> p2], then the statement would be provable. However, equality is a stronger notion than logical equivalence. Recall this example function from Chapter 6. *)
adamc@230 717
adamc@230 718 (* begin hide *)
adamc@230 719 Lemma zgtz : 0 > 0 -> False.
adamc@230 720 crush.
adamc@230 721 Qed.
adamc@230 722 (* end hide *)
adamc@230 723
adamc@230 724 Definition pred_strong1 (n : nat) : n > 0 -> nat :=
adamc@230 725 match n with
adamc@230 726 | O => fun pf : 0 > 0 => match zgtz pf with end
adamc@230 727 | S n' => fun _ => n'
adamc@230 728 end.
adamc@230 729
adam@343 730 (** We might want to prove that different proofs of [n > 0] do not lead to different results from our richly typed predecessor function. *)
adamc@230 731
adamc@230 732 Theorem pred_strong1_irrel : forall n (pf1 pf2 : n > 0), pred_strong1 pf1 = pred_strong1 pf2.
adamc@230 733 destruct n; crush.
adamc@230 734 Qed.
adamc@230 735
adamc@230 736 (** The proof script is simple, but it involved peeking into the definition of [pred_strong1]. For more complicated function definitions, it can be considerably more work to prove that they do not discriminate on details of proof arguments. This can seem like a shame, since the [Prop] elimination restriction makes it impossible to write any function that does otherwise. Unfortunately, this fact is only true metatheoretically, unless we assert an axiom like [proof_irrelevance]. With that axiom, we can prove our theorem without consulting the definition of [pred_strong1]. *)
adamc@230 737
adamc@230 738 Theorem pred_strong1_irrel' : forall n (pf1 pf2 : n > 0), pred_strong1 pf1 = pred_strong1 pf2.
adamc@230 739 intros; f_equal; apply proof_irrelevance.
adamc@230 740 Qed.
adamc@230 741
adamc@230 742
adamc@230 743 (** %\bigskip%
adamc@230 744
adamc@230 745 In the chapter on equality, we already discussed some axioms that are related to proof irrelevance. In particular, Coq's standard library includes this axiom: *)
adamc@230 746
adamc@230 747 Require Import Eqdep.
adamc@230 748 Import Eq_rect_eq.
adamc@230 749 Print eq_rect_eq.
adamc@230 750 (** %\vspace{-.15in}% [[
adamc@230 751 *** [ eq_rect_eq :
adamc@230 752 forall (U : Type) (p : U) (Q : U -> Type) (x : Q p) (h : p = p),
adamc@230 753 x = eq_rect p Q x p h ]
adamc@230 754 ]]
adamc@230 755
adam@343 756 This axiom says that it is permissible to simplify pattern matches over proofs of equalities like [e = e]. The axiom is logically equivalent to some simpler corollaries. In the theorem names, %``%#"#UIP#"#%''% stands for %\index{unicity of identity proofs}``%#"#unicity of identity proofs#"#%''%, where %``%#"#identity#"#%''% is a synonym for %``%#"#equality.#"#%''% *)
adamc@230 757
adamc@230 758 Corollary UIP_refl : forall A (x : A) (pf : x = x), pf = refl_equal x.
adamc@230 759 intros; replace pf with (eq_rect x (eq x) (refl_equal x) x pf); [
adamc@230 760 symmetry; apply eq_rect_eq
adamc@230 761 | exact (match pf as pf' return match pf' in _ = y return x = y with
adamc@230 762 | refl_equal => refl_equal x
adamc@230 763 end = pf' with
adamc@230 764 | refl_equal => refl_equal _
adamc@230 765 end) ].
adamc@230 766 Qed.
adamc@230 767
adamc@230 768 Corollary UIP : forall A (x y : A) (pf1 pf2 : x = y), pf1 = pf2.
adamc@230 769 intros; generalize pf1 pf2; subst; intros;
adamc@230 770 match goal with
adamc@230 771 | [ |- ?pf1 = ?pf2 ] => rewrite (UIP_refl pf1); rewrite (UIP_refl pf2); reflexivity
adamc@230 772 end.
adamc@230 773 Qed.
adamc@230 774
adamc@231 775 (** These corollaries are special cases of proof irrelevance. In developments that only need proof irrelevance for equality, there is no need to assert full irrelevance.
adamc@230 776
adamc@230 777 Another facet of proof irrelevance is that, like excluded middle, it is often provable for specific propositions. For instance, [UIP] is provable whenever the type [A] has a decidable equality operation. The module [Eqdep_dec] of the standard library contains a proof. A similar phenomenon applies to other notable cases, including less-than proofs. Thus, it is often possible to use proof irrelevance without asserting axioms.
adamc@230 778
adamc@230 779 %\bigskip%
adamc@230 780
adamc@230 781 There are two more basic axioms that are often assumed, to avoid complications that do not arise in set theory. *)
adamc@230 782
adamc@230 783 Require Import FunctionalExtensionality.
adamc@230 784 Print functional_extensionality_dep.
adamc@230 785 (** %\vspace{-.15in}% [[
adamc@230 786 *** [ functional_extensionality_dep :
adamc@230 787 forall (A : Type) (B : A -> Type) (f g : forall x : A, B x),
adamc@230 788 (forall x : A, f x = g x) -> f = g ]
adamc@230 789
adamc@230 790 ]]
adamc@230 791
adamc@230 792 This axiom says that two functions are equal if they map equal inputs to equal outputs. Such facts are not provable in general in CIC, but it is consistent to assume that they are.
adamc@230 793
adam@343 794 A simple corollary shows that the same property applies to predicates. *)
adamc@230 795
adamc@230 796 Corollary predicate_extensionality : forall (A : Type) (B : A -> Prop) (f g : forall x : A, B x),
adamc@230 797 (forall x : A, f x = g x) -> f = g.
adamc@230 798 intros; apply functional_extensionality_dep; assumption.
adamc@230 799 Qed.
adamc@230 800
adam@343 801 (** In some cases, one might prefer to assert this corollary as the axiom, to restrict the consequences to proofs and not programs. *)
adam@343 802
adamc@230 803
adamc@230 804 (** ** Axioms of Choice *)
adamc@230 805
adam@343 806 (** Some Coq axioms are also points of contention in mainstream math. The most prominent example is the %\index{axiom of choice}%axiom of choice. In fact, there are multiple versions that we might consider, and, considered in isolation, none of these versions means quite what it means in classical set theory.
adamc@230 807
adam@398 808 First, it is possible to implement a choice operator _without_ axioms in some potentially surprising cases. *)
adamc@230 809
adamc@230 810 Require Import ConstructiveEpsilon.
adamc@230 811 Check constructive_definite_description.
adamc@230 812 (** %\vspace{-.15in}% [[
adamc@230 813 constructive_definite_description
adamc@230 814 : forall (A : Set) (f : A -> nat) (g : nat -> A),
adamc@230 815 (forall x : A, g (f x) = x) ->
adamc@230 816 forall P : A -> Prop,
adamc@230 817 (forall x : A, {P x} + {~ P x}) ->
adamc@230 818 (exists! x : A, P x) -> {x : A | P x}
adam@302 819 ]]
adam@302 820 *)
adamc@230 821
adamc@230 822 Print Assumptions constructive_definite_description.
adam@343 823 (** <<
adamc@230 824 Closed under the global context
adam@343 825 >>
adamc@230 826
adam@398 827 This function transforms a decidable predicate [P] into a function that produces an element satisfying [P] from a proof that such an element exists. The functions [f] and [g], in conjunction with an associated injectivity property, are used to express the idea that the set [A] is countable. Under these conditions, a simple brute force algorithm gets the job done: we just enumerate all elements of [A], stopping when we find one satisfying [P]. The existence proof, specified in terms of _unique_ existence [exists!], guarantees termination. The definition of this operator in Coq uses some interesting techniques, as seen in the implementation of the [ConstructiveEpsilon] module.
adamc@230 828
adamc@230 829 Countable choice is provable in set theory without appealing to the general axiom of choice. To support the more general principle in Coq, we must also add an axiom. Here is a functional version of the axiom of unique choice. *)
adamc@230 830
adamc@230 831 Require Import ClassicalUniqueChoice.
adamc@230 832 Check dependent_unique_choice.
adamc@230 833 (** %\vspace{-.15in}% [[
adamc@230 834 dependent_unique_choice
adamc@230 835 : forall (A : Type) (B : A -> Type) (R : forall x : A, B x -> Prop),
adamc@230 836 (forall x : A, exists! y : B x, R x y) ->
adam@343 837 exists f : forall x : A, B x,
adam@343 838 forall x : A, R x (f x)
adamc@230 839 ]]
adamc@230 840
adamc@230 841 This axiom lets us convert a relational specification [R] into a function implementing that specification. We need only prove that [R] is truly a function. An alternate, stronger formulation applies to cases where [R] maps each input to one or more outputs. We also simplify the statement of the theorem by considering only non-dependent function types. *)
adamc@230 842
adamc@230 843 Require Import ClassicalChoice.
adamc@230 844 Check choice.
adamc@230 845 (** %\vspace{-.15in}% [[
adamc@230 846 choice
adamc@230 847 : forall (A B : Type) (R : A -> B -> Prop),
adamc@230 848 (forall x : A, exists y : B, R x y) ->
adamc@230 849 exists f : A -> B, forall x : A, R x (f x)
adamc@230 850
adamc@230 851 ]]
adamc@230 852
adamc@230 853 This principle is proved as a theorem, based on the unique choice axiom and an additional axiom of relational choice from the [RelationalChoice] module.
adamc@230 854
adamc@230 855 In set theory, the axiom of choice is a fundamental philosophical commitment one makes about the universe of sets. In Coq, the choice axioms say something weaker. For instance, consider the simple restatement of the [choice] axiom where we replace existential quantification by its Curry-Howard analogue, subset types. *)
adamc@230 856
adamc@230 857 Definition choice_Set (A B : Type) (R : A -> B -> Prop) (H : forall x : A, {y : B | R x y})
adamc@230 858 : {f : A -> B | forall x : A, R x (f x)} :=
adamc@230 859 exist (fun f => forall x : A, R x (f x))
adamc@230 860 (fun x => proj1_sig (H x)) (fun x => proj2_sig (H x)).
adamc@230 861
adam@287 862 (** Via the Curry-Howard correspondence, this %``%#"#axiom#"#%''% can be taken to have the same meaning as the original. It is implemented trivially as a transformation not much deeper than uncurrying. Thus, we see that the utility of the axioms that we mentioned earlier comes in their usage to build programs from proofs. Normal set theory has no explicit proofs, so the meaning of the usual axiom of choice is subtlely different. In Gallina, the axioms implement a controlled relaxation of the restrictions on information flow from proofs to programs.
adamc@230 863
adam@287 864 However, when we combine an axiom of choice with the law of the excluded middle, the idea of %``%#"#choice#"#%''% becomes more interesting. Excluded middle gives us a highly non-computational way of constructing proofs, but it does not change the computational nature of programs. Thus, the axiom of choice is still giving us a way of translating between two different sorts of %``%#"#programs,#"#%''% but the input programs (which are proofs) may be written in a rich language that goes beyond normal computability. This truly is more than repackaging a function with a different type.
adamc@230 865
adamc@230 866 %\bigskip%
adamc@230 867
adam@343 868 The Coq tools support a command-line flag %\index{impredicative Set}\texttt{%#<tt>#-impredicative-set#</tt>#%}%, which modifies Gallina in a more fundamental way by making [Set] impredicative. A term like [forall T : Set, T] has type [Set], and inductive definitions in [Set] may have constructors that quantify over arguments of any types. To maintain consistency, an elimination restriction must be imposed, similarly to the restriction for [Prop]. The restriction only applies to large inductive types, where some constructor quantifies over a type of type [Type]. In such cases, a value in this inductive type may only be pattern-matched over to yield a result type whose type is [Set] or [Prop]. This contrasts with [Prop], where the restriction applies even to non-large inductive types, and where the result type may only have type [Prop].
adamc@230 869
adamc@230 870 In old versions of Coq, [Set] was impredicative by default. Later versions make [Set] predicative to avoid inconsistency with some classical axioms. In particular, one should watch out when using impredicative [Set] with axioms of choice. In combination with excluded middle or predicate extensionality, this can lead to inconsistency. Impredicative [Set] can be useful for modeling inherently impredicative mathematical concepts, but almost all Coq developments get by fine without it. *)
adamc@230 871
adamc@230 872 (** ** Axioms and Computation *)
adamc@230 873
adam@398 874 (** One additional axiom-related wrinkle arises from an aspect of Gallina that is very different from set theory: a notion of _computational equivalence_ is central to the definition of the formal system. Axioms tend not to play well with computation. Consider this example. We start by implementing a function that uses a type equality proof to perform a safe type-cast. *)
adamc@230 875
adamc@230 876 Definition cast (x y : Set) (pf : x = y) (v : x) : y :=
adamc@230 877 match pf with
adamc@230 878 | refl_equal => v
adamc@230 879 end.
adamc@230 880
adamc@230 881 (** Computation over programs that use [cast] can proceed smoothly. *)
adamc@230 882
adamc@230 883 Eval compute in (cast (refl_equal (nat -> nat)) (fun n => S n)) 12.
adam@343 884 (** %\vspace{-.15in}%[[
adamc@230 885 = 13
adamc@230 886 : nat
adam@302 887 ]]
adam@302 888 *)
adamc@230 889
adamc@230 890 (** Things do not go as smoothly when we use [cast] with proofs that rely on axioms. *)
adamc@230 891
adamc@230 892 Theorem t3 : (forall n : nat, fin (S n)) = (forall n : nat, fin (n + 1)).
adamc@230 893 change ((forall n : nat, (fun n => fin (S n)) n) = (forall n : nat, (fun n => fin (n + 1)) n));
adamc@230 894 rewrite (functional_extensionality (fun n => fin (n + 1)) (fun n => fin (S n))); crush.
adamc@230 895 Qed.
adamc@230 896
adamc@230 897 Eval compute in (cast t3 (fun _ => First)) 12.
adamc@230 898 (** [[
adamc@230 899 = match t3 in (_ = P) return P with
adamc@230 900 | refl_equal => fun n : nat => First
adamc@230 901 end 12
adamc@230 902 : fin (12 + 1)
adamc@230 903 ]]
adamc@230 904
adamc@230 905 Computation gets stuck in a pattern-match on the proof [t3]. The structure of [t3] is not known, so the match cannot proceed. It turns out a more basic problem leads to this particular situation. We ended the proof of [t3] with [Qed], so the definition of [t3] is not available to computation. That is easily fixed. *)
adamc@230 906
adamc@230 907 Reset t3.
adamc@230 908
adamc@230 909 Theorem t3 : (forall n : nat, fin (S n)) = (forall n : nat, fin (n + 1)).
adamc@230 910 change ((forall n : nat, (fun n => fin (S n)) n) = (forall n : nat, (fun n => fin (n + 1)) n));
adamc@230 911 rewrite (functional_extensionality (fun n => fin (n + 1)) (fun n => fin (S n))); crush.
adamc@230 912 Defined.
adamc@230 913
adamc@230 914 Eval compute in (cast t3 (fun _ => First)) 12.
adamc@230 915 (** [[
adamc@230 916 = match
adamc@230 917 match
adamc@230 918 match
adamc@230 919 functional_extensionality
adamc@230 920 ....
adamc@230 921 ]]
adamc@230 922
adam@398 923 We elide most of the details. A very unwieldy tree of nested matches on equality proofs appears. This time evaluation really _is_ stuck on a use of an axiom.
adamc@230 924
adamc@230 925 If we are careful in using tactics to prove an equality, we can still compute with casts over the proof. *)
adamc@230 926
adamc@230 927 Lemma plus1 : forall n, S n = n + 1.
adamc@230 928 induction n; simpl; intuition.
adamc@230 929 Defined.
adamc@230 930
adamc@230 931 Theorem t4 : forall n, fin (S n) = fin (n + 1).
adamc@230 932 intro; f_equal; apply plus1.
adamc@230 933 Defined.
adamc@230 934
adamc@230 935 Eval compute in cast (t4 13) First.
adamc@230 936 (** %\vspace{-.15in}% [[
adamc@230 937 = First
adamc@230 938 : fin (13 + 1)
adam@302 939 ]]
adam@343 940
adam@343 941 This simple computational reduction hides the use of a recursive function to produce a suitable [refl_equal] proof term. The recursion originates in our use of [induction] in [t4]'s proof. *)
adam@343 942
adam@344 943
adam@344 944 (** ** Methods for Avoiding Axioms *)
adam@344 945
adam@409 946 (** The last section demonstrated one reason to avoid axioms: they interfere with computational behavior of terms. A further reason is to reduce the philosophical commitment of a theorem. The more axioms one assumes, the harder it becomes to convince oneself that the formal system corresponds appropriately to one's intuitions. A refinement of this last point, in applications like %\index{proof-carrying code}%proof-carrying code%~\cite{PCC}% in computer security, has to do with minimizing the size of a%\index{trusted code base}% _trusted code base_. To convince ourselves that a theorem is true, we must convince ourselves of the correctness of the program that checks the theorem. Axioms effectively become new source code for the checking program, increasing the effort required to perform a correctness audit.
adam@344 947
adam@344 948 An earlier section gave one example of avoiding an axiom. We proved that [pred_strong1] is agnostic to details of the proofs passed to it as arguments, by unfolding the definition of the function. A %``%#"#simpler#"#%''% proof keeps the function definition opaque and instead applies a proof irrelevance axiom. By accepting a more complex proof, we reduce our philosophical commitment and trusted base. (By the way, the less-than relation that the proofs in question here prove turns out to admit proof irrelevance as a theorem provable within normal Gallina!)
adam@344 949
adam@344 950 One dark secret of the [dep_destruct] tactic that we have used several times is reliance on an axiom. Consider this simple case analysis principle for [fin] values: *)
adam@344 951
adam@344 952 Theorem fin_cases : forall n (f : fin (S n)), f = First \/ exists f', f = Next f'.
adam@344 953 intros; dep_destruct f; eauto.
adam@344 954 Qed.
adam@344 955
adam@344 956 Print Assumptions fin_cases.
adam@344 957 (** %\vspace{-.15in}%[[
adam@344 958 Axioms:
adam@344 959 JMeq.JMeq_eq : forall (A : Type) (x y : A), JMeq.JMeq x y -> x = y
adam@344 960 ]]
adam@344 961
adam@344 962 The proof depends on the [JMeq_eq] axiom that we met in the chapter on equality proofs. However, a smarter tactic could have avoided an axiom dependence. Here is an alternate proof via a slightly strange looking lemma. *)
adam@344 963
adam@344 964 (* begin thide *)
adam@344 965 Lemma fin_cases_again' : forall n (f : fin n),
adam@344 966 match n return fin n -> Prop with
adam@344 967 | O => fun _ => False
adam@344 968 | S n' => fun f => f = First \/ exists f', f = Next f'
adam@344 969 end f.
adam@344 970 destruct f; eauto.
adam@344 971 Qed.
adam@344 972
adam@344 973 (** We apply a variant of the %\index{convoy pattern}%convoy pattern, which we are used to seeing in function implementations. Here, the pattern helps us state a lemma in a form where the argument to [fin] is a variable. Recall that, thanks to basic typing rules for pattern-matching, [destruct] will only work effectively on types whose non-parameter arguments are variables. The %\index{tactics!exact}%[exact] tactic, which takes as argument a literal proof term, now gives us an easy way of proving the original theorem. *)
adam@344 974
adam@344 975 Theorem fin_cases_again : forall n (f : fin (S n)), f = First \/ exists f', f = Next f'.
adam@344 976 intros; exact (fin_cases_again' f).
adam@344 977 Qed.
adam@344 978 (* end thide *)
adam@344 979
adam@344 980 Print Assumptions fin_cases_again.
adam@344 981 (** %\vspace{-.15in}%
adam@344 982 <<
adam@344 983 Closed under the global context
adam@344 984 >>
adam@344 985
adam@345 986 *)
adam@345 987
adam@345 988 (* begin thide *)
adam@345 989 (** As the Curry-Howard correspondence might lead us to expect, the same pattern may be applied in programming as in proving. Axioms are relevant in programming, too, because, while Coq includes useful extensions like [Program] that make dependently typed programming more straightforward, in general these extensions generate code that relies on axioms about equality. We can use clever pattern matching to write our code axiom-free.
adam@345 990
adam@345 991 As an example, consider a [Set] version of [fin_cases]. We use [Set] types instead of [Prop] types, so that return values have computational content and may be used to guide the behavior of algorithms. Beside that, we are essentially writing the same %``%#"#proof#"#%''% in a more explicit way. *)
adam@345 992
adam@345 993 Definition finOut n (f : fin n) : match n return fin n -> Type with
adam@345 994 | O => fun _ => Empty_set
adam@345 995 | _ => fun f => {f' : _ | f = Next f'} + {f = First}
adam@345 996 end f :=
adam@345 997 match f with
adam@345 998 | First _ => inright _ (refl_equal _)
adam@345 999 | Next _ f' => inleft _ (exist _ f' (refl_equal _))
adam@345 1000 end.
adam@345 1001 (* end thide *)
adam@345 1002
adam@345 1003 (** As another example, consider the following type of formulas in first-order logic. The intent of the type definition will not be important in what follows, but we give a quick intuition for the curious reader. Our formulas may include [forall] quantification over arbitrary [Type]s, and we index formulas by environments telling which variables are in scope and what their types are; such an environment is a [list Type]. A constructor [Inject] lets us include any Coq [Prop] as a formula, and [VarEq] and [Lift] can be used for variable references, in what is essentially the de Bruijn index convention. (Again, the detail in this paragraph is not important to understand the discussion that follows!) *)
adam@344 1004
adam@344 1005 Inductive formula : list Type -> Type :=
adam@344 1006 | Inject : forall Ts, Prop -> formula Ts
adam@344 1007 | VarEq : forall T Ts, T -> formula (T :: Ts)
adam@344 1008 | Lift : forall T Ts, formula Ts -> formula (T :: Ts)
adam@344 1009 | Forall : forall T Ts, formula (T :: Ts) -> formula Ts
adam@344 1010 | And : forall Ts, formula Ts -> formula Ts -> formula Ts.
adam@344 1011
adam@344 1012 (** This example is based on my own experiences implementing variants of a program logic called XCAP%~\cite{XCAP}%, which also includes an inductive predicate for characterizing which formulas are provable. Here I include a pared-down version of such a predicate, with only two constructors, which is sufficient to illustrate certain tricky issues. *)
adam@344 1013
adam@344 1014 Inductive proof : formula nil -> Prop :=
adam@344 1015 | PInject : forall (P : Prop), P -> proof (Inject nil P)
adam@344 1016 | PAnd : forall p q, proof p -> proof q -> proof (And p q).
adam@344 1017
adam@344 1018 (** Let us prove a lemma showing that a %``%#"#[P /\ Q -> P]#"#%''% rule is derivable within the rules of [proof]. *)
adam@344 1019
adam@344 1020 Theorem proj1 : forall p q, proof (And p q) -> proof p.
adam@344 1021 destruct 1.
adam@344 1022 (** %\vspace{-.15in}%[[
adam@344 1023 p : formula nil
adam@344 1024 q : formula nil
adam@344 1025 P : Prop
adam@344 1026 H : P
adam@344 1027 ============================
adam@344 1028 proof p
adam@344 1029 ]]
adam@344 1030 *)
adam@344 1031
adam@344 1032 (** We are reminded that [induction] and [destruct] do not work effectively on types with non-variable arguments. The first subgoal, shown above, is clearly unprovable. (Consider the case where [p = Inject nil False].)
adam@344 1033
adam@344 1034 An application of the %\index{tactics!dependent destruction}%[dependent destruction] tactic (the basis for [dep_destruct]) solves the problem handily. We use a shorthand with the %\index{tactics!intros}%[intros] tactic that lets us use question marks for variable names that do not matter. *)
adam@344 1035
adam@344 1036 Restart.
adam@344 1037 Require Import Program.
adam@344 1038 intros ? ? H; dependent destruction H; auto.
adam@344 1039 Qed.
adam@344 1040
adam@344 1041 Print Assumptions proj1.
adam@344 1042 (** %\vspace{-.15in}%[[
adam@344 1043 Axioms:
adam@344 1044 eq_rect_eq : forall (U : Type) (p : U) (Q : U -> Type) (x : Q p) (h : p = p),
adam@344 1045 x = eq_rect p Q x p h
adam@344 1046 ]]
adam@344 1047
adam@344 1048 Unfortunately, that built-in tactic appeals to an axiom. It is still possible to avoid axioms by giving the proof via another odd-looking lemma. Here is a first attempt that fails at remaining axiom-free, using a common equality-based trick for supporting induction on non-variable arguments to type families. The trick works fine without axioms for datatypes more traditional than [formula], but we run into trouble with our current type. *)
adam@344 1049
adam@344 1050 Lemma proj1_again' : forall r, proof r
adam@344 1051 -> forall p q, r = And p q -> proof p.
adam@344 1052 destruct 1; crush.
adam@344 1053 (** %\vspace{-.15in}%[[
adam@344 1054 H0 : Inject [] P = And p q
adam@344 1055 ============================
adam@344 1056 proof p
adam@344 1057 ]]
adam@344 1058
adam@344 1059 The first goal looks reasonable. Hypothesis [H0] is clearly contradictory, as [discriminate] can show. *)
adam@344 1060
adam@344 1061 discriminate.
adam@344 1062 (** %\vspace{-.15in}%[[
adam@344 1063 H : proof p
adam@344 1064 H1 : And p q = And p0 q0
adam@344 1065 ============================
adam@344 1066 proof p0
adam@344 1067 ]]
adam@344 1068
adam@344 1069 It looks like we are almost done. Hypothesis [H1] gives [p = p0] by injectivity of constructors, and then [H] finishes the case. *)
adam@344 1070
adam@344 1071 injection H1; intros.
adam@344 1072
adam@344 1073 (** Unfortunately, the %``%#"#equality#"#%''% that we expected between [p] and [p0] comes in a strange form:
adam@344 1074
adam@344 1075 [[
adam@344 1076 H3 : existT (fun Ts : list Type => formula Ts) []%list p =
adam@344 1077 existT (fun Ts : list Type => formula Ts) []%list p0
adam@344 1078 ============================
adam@344 1079 proof p0
adam@344 1080 ]]
adam@344 1081
adam@345 1082 It may take a bit of tinkering, but, reviewing Chapter 3's discussion of writing injection principles manually, it makes sense that an [existT] type is the most direct way to express the output of [injection] on a dependently typed constructor. The constructor [And] is dependently typed, since it takes a parameter [Ts] upon which the types of [p] and [q] depend. Let us not dwell further here on why this goal appears; the reader may like to attempt the (impossible) exercise of building a better injection lemma for [And], without using axioms.
adam@344 1083
adam@344 1084 How exactly does an axiom come into the picture here? Let us ask [crush] to finish the proof. *)
adam@344 1085
adam@344 1086 crush.
adam@344 1087 Qed.
adam@344 1088
adam@344 1089 Print Assumptions proj1_again'.
adam@344 1090 (** %\vspace{-.15in}%[[
adam@344 1091 Axioms:
adam@344 1092 eq_rect_eq : forall (U : Type) (p : U) (Q : U -> Type) (x : Q p) (h : p = p),
adam@344 1093 x = eq_rect p Q x p h
adam@344 1094 ]]
adam@344 1095
adam@344 1096 It turns out that this familiar axiom about equality (or some other axiom) is required to deduce [p = p0] from the hypothesis [H3] above. The soundness of that proof step is neither provable nor disprovable in Gallina.
adam@344 1097
adam@344 1098 Hope is not lost, however. We can produce an even stranger looking lemma, which gives us the theorem without axioms. *)
adam@344 1099
adam@344 1100 Lemma proj1_again'' : forall r, proof r
adam@344 1101 -> match r with
adam@344 1102 | And Ps p _ => match Ps return formula Ps -> Prop with
adam@344 1103 | nil => fun p => proof p
adam@344 1104 | _ => fun _ => True
adam@344 1105 end p
adam@344 1106 | _ => True
adam@344 1107 end.
adam@344 1108 destruct 1; auto.
adam@344 1109 Qed.
adam@344 1110
adam@344 1111 Theorem proj1_again : forall p q, proof (And p q) -> proof p.
adam@344 1112 intros ? ? H; exact (proj1_again'' H).
adam@344 1113 Qed.
adam@344 1114
adam@344 1115 Print Assumptions proj1_again.
adam@344 1116 (** <<
adam@344 1117 Closed under the global context
adam@344 1118 >>
adam@344 1119
adam@377 1120 This example illustrates again how some of the same design patterns we learned for dependently typed programming can be used fruitfully in theorem statements.
adam@377 1121
adam@377 1122 %\medskip%
adam@377 1123
adam@398 1124 To close the chapter, we consider one final way to avoid dependence on axioms. Often this task is equivalent to writing definitions such that they _compute_. That is, we want Coq's normal reduction to be able to run certain programs to completion. Here is a simple example where such computation can get stuck. In proving properties of such functions, we would need to apply axioms like %\index{axiom K}%K manually to make progress.
adam@377 1125
adam@377 1126 Imagine we are working with %\index{deep embedding}%deeply embedded syntax of some programming language, where each term is considered to be in the scope of a number of free variables that hold normal Coq values. To enforce proper typing, we will need to model a Coq typing environment somehow. One natural choice is as a list of types, where variable number [i] will be treated as a reference to the [i]th element of the list. *)
adam@377 1127
adam@377 1128 Section withTypes.
adam@377 1129 Variable types : list Set.
adam@377 1130
adam@377 1131 (** To give the semantics of terms, we will need to represent value environments, which assign each variable a term of the proper type. *)
adam@377 1132
adam@377 1133 Variable values : hlist (fun x : Set => x) types.
adam@377 1134
adam@377 1135 (** Now imagine that we are writing some procedure that operates on a distinguished variable of type [nat]. A hypothesis formalizes this assumption, using the standard library function [nth_error] for looking up list elements by position. *)
adam@377 1136
adam@377 1137 Variable natIndex : nat.
adam@377 1138 Variable natIndex_ok : nth_error types natIndex = Some nat.
adam@377 1139
adam@377 1140 (** It is not hard to use this hypothesis to write a function for extracting the [nat] value in position [natIndex] of [values], starting with two helpful lemmas, each of which we finish with [Defined] to mark the lemma as transparent, so that its definition may be expanded during evaluation. *)
adam@377 1141
adam@377 1142 Lemma nth_error_nil : forall A n x,
adam@377 1143 nth_error (@nil A) n = Some x
adam@377 1144 -> False.
adam@377 1145 destruct n; simpl; unfold error; congruence.
adam@377 1146 Defined.
adam@377 1147
adam@377 1148 Implicit Arguments nth_error_nil [A n x].
adam@377 1149
adam@377 1150 Lemma Some_inj : forall A (x y : A),
adam@377 1151 Some x = Some y
adam@377 1152 -> x = y.
adam@377 1153 congruence.
adam@377 1154 Defined.
adam@377 1155
adam@377 1156 Fixpoint getNat (types' : list Set) (values' : hlist (fun x : Set => x) types')
adam@377 1157 (natIndex : nat) : (nth_error types' natIndex = Some nat) -> nat :=
adam@377 1158 match values' with
adam@377 1159 | HNil => fun pf => match nth_error_nil pf with end
adam@377 1160 | HCons t ts x values'' =>
adam@377 1161 match natIndex return nth_error (t :: ts) natIndex = Some nat -> nat with
adam@377 1162 | O => fun pf =>
adam@377 1163 match Some_inj pf in _ = T return T with
adam@377 1164 | refl_equal => x
adam@377 1165 end
adam@377 1166 | S natIndex' => getNat values'' natIndex'
adam@377 1167 end
adam@377 1168 end.
adam@377 1169 End withTypes.
adam@377 1170
adam@377 1171 (** The problem becomes apparent when we experiment with running [getNat] on a concrete [types] list. *)
adam@377 1172
adam@377 1173 Definition myTypes := unit :: nat :: bool :: nil.
adam@377 1174 Definition myValues : hlist (fun x : Set => x) myTypes :=
adam@377 1175 tt ::: 3 ::: false ::: HNil.
adam@377 1176
adam@377 1177 Definition myNatIndex := 1.
adam@377 1178
adam@377 1179 Theorem myNatIndex_ok : nth_error myTypes myNatIndex = Some nat.
adam@377 1180 reflexivity.
adam@377 1181 Defined.
adam@377 1182
adam@377 1183 Eval compute in getNat myValues myNatIndex myNatIndex_ok.
adam@377 1184 (** %\vspace{-.15in}%[[
adam@377 1185 = 3
adam@377 1186 ]]
adam@377 1187
adam@398 1188 We have not hit the problem yet, since we proceeded with a concrete equality proof for [myNatIndex_ok]. However, consider a case where we want to reason about the behavior of [getNat] _independently_ of a specific proof. *)
adam@377 1189
adam@377 1190 Theorem getNat_is_reasonable : forall pf, getNat myValues myNatIndex pf = 3.
adam@377 1191 intro; compute.
adam@377 1192 (**
adam@377 1193 <<
adam@377 1194 1 subgoal
adam@377 1195 >>
adam@377 1196 %\vspace{-.3in}%[[
adam@377 1197 pf : nth_error myTypes myNatIndex = Some nat
adam@377 1198 ============================
adam@377 1199 match
adam@377 1200 match
adam@377 1201 pf in (_ = y)
adam@377 1202 return (nat = match y with
adam@377 1203 | Some H => H
adam@377 1204 | None => nat
adam@377 1205 end)
adam@377 1206 with
adam@377 1207 | eq_refl => eq_refl
adam@377 1208 end in (_ = T) return T
adam@377 1209 with
adam@377 1210 | eq_refl => 3
adam@377 1211 end = 3
adam@377 1212 ]]
adam@377 1213
adam@377 1214 Since the details of the equality proof [pf] are not known, computation can proceed no further. A rewrite with axiom K would allow us to make progress, but we can rethink the definitions a bit to avoid depending on axioms. *)
adam@377 1215
adam@377 1216 Abort.
adam@377 1217
adam@377 1218 (** Here is a definition of a function that turns out to be useful, though no doubt its purpose will be mysterious for now. A call [update ls n x] overwrites the [n]th position of the list [ls] with the value [x], padding the end of the list with extra [x] values as needed to ensure sufficient length. *)
adam@377 1219
adam@377 1220 Fixpoint copies A (x : A) (n : nat) : list A :=
adam@377 1221 match n with
adam@377 1222 | O => nil
adam@377 1223 | S n' => x :: copies x n'
adam@377 1224 end.
adam@377 1225
adam@377 1226 Fixpoint update A (ls : list A) (n : nat) (x : A) : list A :=
adam@377 1227 match ls with
adam@377 1228 | nil => copies x n ++ x :: nil
adam@377 1229 | y :: ls' => match n with
adam@377 1230 | O => x :: ls'
adam@377 1231 | S n' => y :: update ls' n' x
adam@377 1232 end
adam@377 1233 end.
adam@377 1234
adam@377 1235 (** Now let us revisit the definition of [getNat]. *)
adam@377 1236
adam@377 1237 Section withTypes'.
adam@377 1238 Variable types : list Set.
adam@377 1239 Variable natIndex : nat.
adam@377 1240
adam@398 1241 (** Here is the trick: instead of asserting properties about the list [types], we build a %``%#"#new#"#%''% list that is _guaranteed by construction_ to have those properties. *)
adam@377 1242
adam@377 1243 Definition types' := update types natIndex nat.
adam@377 1244
adam@377 1245 Variable values : hlist (fun x : Set => x) types'.
adam@377 1246
adam@377 1247 (** Now a bit of dependent pattern matching helps us rewrite [getNat] in a way that avoids any use of equality proofs. *)
adam@377 1248
adam@378 1249 Fixpoint skipCopies (n : nat)
adam@378 1250 : hlist (fun x : Set => x) (copies nat n ++ nat :: nil) -> nat :=
adam@378 1251 match n with
adam@378 1252 | O => fun vs => hhd vs
adam@378 1253 | S n' => fun vs => skipCopies n' (htl vs)
adam@378 1254 end.
adam@378 1255
adam@377 1256 Fixpoint getNat' (types'' : list Set) (natIndex : nat)
adam@377 1257 : hlist (fun x : Set => x) (update types'' natIndex nat) -> nat :=
adam@377 1258 match types'' with
adam@378 1259 | nil => skipCopies natIndex
adam@377 1260 | t :: types0 =>
adam@377 1261 match natIndex return hlist (fun x : Set => x)
adam@377 1262 (update (t :: types0) natIndex nat) -> nat with
adam@377 1263 | O => fun vs => hhd vs
adam@377 1264 | S natIndex' => fun vs => getNat' types0 natIndex' (htl vs)
adam@377 1265 end
adam@377 1266 end.
adam@377 1267 End withTypes'.
adam@377 1268
adam@398 1269 (** Now the surprise comes in how easy it is to _use_ [getNat']. While typing works by modification of a types list, we can choose parameters so that the modification has no effect. *)
adam@377 1270
adam@377 1271 Theorem getNat_is_reasonable : getNat' myTypes myNatIndex myValues = 3.
adam@377 1272 reflexivity.
adam@377 1273 Qed.
adam@377 1274
adam@377 1275 (** The same parameters as before work without alteration, and we avoid use of axioms. *)