Mercurial > cpdt > repo

annotate src/StackMachine.v @ 206:3f4576f15130

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Revising for 8.2 through first big example
author Adam Chlipala <adamc@hcoop.net>
date Fri, 06 Nov 2009 16:44:06 -0500
parents f05514cc6c0d
children a7be5d9a2fd4
rev   line source
adamc@206 1 (* Copyright (c) 2008-2009, Adam Chlipala
adamc@2 2 *
adamc@2 3 * This work is licensed under a
adamc@2 4 * Creative Commons Attribution-Noncommercial-No Derivative Works 3.0
adamc@2 5 * Unported License.
adamc@2 6 * The license text is available at:
adamc@2 7 * http://creativecommons.org/licenses/by-nc-nd/3.0/
adamc@2 8 *)
adamc@2 9
adamc@3 10 (* begin hide *)
adamc@2 11 Require Import List.
adamc@2 12
adamc@2 13 Require Import Tactics.
adamc@14 14
adamc@14 15 Set Implicit Arguments.
adamc@3 16 (* end hide *)
adamc@2 17
adamc@2 18
adamc@25 19 (** %\chapter{Some Quick Examples}% *)
adamc@25 20
adamc@25 21
adamc@206 22 (** I will start off by jumping right in to a fully-worked set of examples, building certified compilers from increasingly complicated source languages to stack machines. We will meet a few useful tactics and see how they can be used in manual proofs, and we will also see how easily these proofs can be automated instead. I assume that you have installed Coq and Proof General. The code in this book is tested with Coq version 8.2pl1, though parts may work with other versions.
adamc@9 23
adamc@25 24 As always, you can step through the source file %\texttt{%#<tt>#StackMachine.v#</tt>#%}% for this chapter interactively in Proof General. Alternatively, to get a feel for the whole lifecycle of creating a Coq development, you can enter the pieces of source code in this chapter in a new %\texttt{%#<tt>#.v#</tt>#%}% file in an Emacs buffer. If you do the latter, include a line [Require Import List Tactics.] at the start of the file, to match some code hidden in this rendering of the chapter source, and be sure to run the Coq binary %\texttt{%#<tt>#coqtop#</tt>#%}% with the command-line argument %\texttt{%#<tt>#-I SRC#</tt>#%}%, where %\texttt{%#<tt>#SRC#</tt>#%}% is the path to a directory containing the source for this book. In either case, you will need to run %\texttt{%#<tt>#make#</tt>#%}% in the root directory of the source distribution for the book before getting started. If you have installed Proof General properly, it should start automatically when you visit a %\texttt{%#<tt>#.v#</tt>#%}% buffer in Emacs.
adamc@25 25
adamc@25 26 There are some minor headaches associated with getting Proof General to pass the proper command line arguments to the %\texttt{%#<tt>#coqtop#</tt>#%}% program. The best way to add settings that will be shared by many source files is to add a custom variable setting to your %\texttt{%#<tt>#.emacs#</tt>#%}% file, like this:
adamc@25 27 %\begin{verbatim}%#<pre>#(custom-set-variables
adamc@25 28 ...
adamc@206 29 '(coq-prog-args '("-I" "/path/to/cpdt/src"))
adamc@25 30 ...
adamc@25 31 )#</pre>#%\end{verbatim}%
adamc@25 32 The extra arguments demonstrated here are the proper choices for working with the code for this book. The ellipses stand for other Emacs customization settings you may already have. It can be helpful to save several alternate sets of flags in your %\texttt{%#<tt>#.emacs#</tt>#%}% file, with all but one commented out within the %\texttt{%#<tt>#custom-set-variables#</tt>#%}% block at any given time.
adamc@11 33
adamc@11 34 With Proof General, the portion of a buffer that Coq has processed is highlighted in some way, like being given a blue background. You step through Coq source files by positioning the point at the position you want Coq to run to and pressing C-C C-RET. This can be used both for normal step-by-step coding, by placing the point inside some command past the end of the highlighted region; and for undoing, by placing the point inside the highlighted region. *)
adamc@9 35
adamc@9 36
adamc@20 37 (** * Arithmetic Expressions Over Natural Numbers *)
adamc@2 38
adamc@40 39 (** We will begin with that staple of compiler textbooks, arithmetic expressions over a single type of numbers. *)
adamc@9 40
adamc@20 41 (** ** Source Language *)
adamc@9 42
adamc@9 43 (** We begin with the syntax of the source language. *)
adamc@2 44
adamc@4 45 Inductive binop : Set := Plus | Times.
adamc@2 46
adamc@9 47 (** Our first line of Coq code should be unsurprising to ML and Haskell programmers. We define an algebraic datatype [binop] to stand for the binary operators of our source language. There are just two wrinkles compared to ML and Haskell. First, we use the keyword [Inductive], in place of %\texttt{%#<tt>#data#</tt>#%}%, %\texttt{%#<tt>#datatype#</tt>#%}%, or %\texttt{%#<tt>#type#</tt>#%}%. This is not just a trivial surface syntax difference; inductive types in Coq are much more expressive than garden variety algebraic datatypes, essentially enabling us to encode all of mathematics, though we begin humbly in this chapter. Second, there is the [: Set] fragment, which declares that we are defining a datatype that should be thought of as a constituent of programs. Later, we will see other options for defining datatypes in the universe of proofs or in an infinite hierarchy of universes, encompassing both programs and proofs, that is useful in higher-order constructions. *)
adamc@9 48
adamc@4 49 Inductive exp : Set :=
adamc@4 50 | Const : nat -> exp
adamc@4 51 | Binop : binop -> exp -> exp -> exp.
adamc@2 52
adamc@9 53 (** Now we define the type of arithmetic expressions. We write that a constant may be built from one argument, a natural number; and a binary operation may be built from a choice of operator and two operand expressions.
adamc@9 54
adamc@9 55 A note for readers following along in the PDF version: coqdoc supports pretty-printing of tokens in LaTeX or HTML. Where you see a right arrow character, the source contains the ASCII text %\texttt{%#<tt>#->#</tt>#%}%. Other examples of this substitution appearing in this chapter are a double right arrow for %\texttt{%#<tt>#=>#</tt>#%}% and the inverted 'A' symbol for %\texttt{%#<tt>#forall#</tt>#%}%. When in doubt about the ASCII version of a symbol, you can consult the chapter source code.
adamc@9 56
adamc@9 57 %\medskip%
adamc@9 58
adamc@9 59 Now we are ready to say what these programs mean. We will do this by writing an interpreter that can be thought of as a trivial operational or denotational semantics. (If you are not familiar with these semantic techniques, no need to worry; we will stick to "common sense" constructions.) *)
adamc@9 60
adamc@4 61 Definition binopDenote (b : binop) : nat -> nat -> nat :=
adamc@4 62 match b with
adamc@4 63 | Plus => plus
adamc@4 64 | Times => mult
adamc@4 65 end.
adamc@2 66
adamc@9 67 (** The meaning of a binary operator is a binary function over naturals, defined with pattern-matching notation analogous to the %\texttt{%#<tt>#case#</tt>#%}% and %\texttt{%#<tt>#match#</tt>#%}% of ML and Haskell, and referring to the functions [plus] and [mult] from the Coq standard library. The keyword [Definition] is Coq's all-purpose notation for binding a term of the programming language to a name, with some associated syntactic sugar, like the notation we see here for defining a function. That sugar could be expanded to yield this definition:
adamc@9 68
adamc@9 69 [[
adamc@9 70 Definition binopDenote : binop -> nat -> nat -> nat := fun (b : binop) =>
adamc@9 71 match b with
adamc@9 72 | Plus => plus
adamc@9 73 | Times => mult
adamc@9 74 end.
adamc@9 75
adamc@205 76 ]]
adamc@205 77
adamc@9 78 In this example, we could also omit all of the type annotations, arriving at:
adamc@9 79
adamc@9 80 [[
adamc@9 81 Definition binopDenote := fun b =>
adamc@9 82 match b with
adamc@9 83 | Plus => plus
adamc@9 84 | Times => mult
adamc@9 85 end.
adamc@9 86
adamc@205 87 ]]
adamc@205 88
adamc@9 89 Languages like Haskell and ML have a convenient %\textit{%#<i>#principal typing#</i>#%}% property, which gives us strong guarantees about how effective type inference will be. Unfortunately, Coq's type system is so expressive that any kind of "complete" type inference is impossible, and the task even seems to be hard heuristically in practice. Nonetheless, Coq includes some very helpful heuristics, many of them copying the workings of Haskell and ML type-checkers for programs that fall in simple fragments of Coq's language.
adamc@9 90
adamc@9 91 This is as good a time as any to mention the preponderance of different languages associated with Coq. The theoretical foundation of Coq is a formal system called the %\textit{%#<i>#Calculus of Inductive Constructions (CIC)#</i>#%}%, which is an extension of the older %\textit{%#<i>#Calculus of Constructions (CoC)#</i>#%}%. CIC is quite a spartan foundation, which is helpful for proving metatheory but not so helpful for real development. Still, it is nice to know that it has been proved that CIC enjoys properties like %\textit{%#<i>#strong normalization#</i>#%}%, meaning that every program (and, more importantly, every proof term) terminates; and %\textit{%#<i>#relative consistency#</i>#%}% with systems like versions of Zermelo Fraenkel set theory, which roughly means that you can believe that Coq proofs mean that the corresponding propositions are "really true," if you believe in set theory.
adamc@9 92
adamc@40 93 Coq is actually based on an extension of CIC called %\textit{%#<i>#Gallina#</i>#%}%. The text after the [:=] and before the period in the last code example is a term of Gallina. Gallina adds many useful features that are not compiled internally to more primitive CIC features. The important metatheorems about CIC have not been extended to the full breadth of these features, but most Coq users do not seem to lose much sleep over this omission.
adamc@9 94
adamc@9 95 Commands like [Inductive] and [Definition] are part of %\textit{%#<i>#the vernacular#</i>#%}%, which includes all sorts of useful queries and requests to the Coq system.
adamc@9 96
adamc@9 97 Finally, there is %\textit{%#<i>#Ltac#</i>#%}%, Coq's domain-specific language for writing proofs and decision procedures. We will see some basic examples of Ltac later in this chapter, and much of this book is devoted to more involved Ltac examples.
adamc@9 98
adamc@9 99 %\medskip%
adamc@9 100
adamc@9 101 We can give a simple definition of the meaning of an expression: *)
adamc@9 102
adamc@4 103 Fixpoint expDenote (e : exp) : nat :=
adamc@4 104 match e with
adamc@4 105 | Const n => n
adamc@4 106 | Binop b e1 e2 => (binopDenote b) (expDenote e1) (expDenote e2)
adamc@4 107 end.
adamc@2 108
adamc@9 109 (** We declare explicitly that this is a recursive definition, using the keyword [Fixpoint]. The rest should be old hat for functional programmers. *)
adamc@2 110
adamc@16 111 (** It is convenient to be able to test definitions before starting to prove things about them. We can verify that our semantics is sensible by evaluating some sample uses. *)
adamc@16 112
adamc@16 113 Eval simpl in expDenote (Const 42).
adamc@205 114 (** [= 42 : nat] *)
adamc@205 115
adamc@16 116 Eval simpl in expDenote (Binop Plus (Const 2) (Const 2)).
adamc@205 117 (** [= 4 : nat] *)
adamc@205 118
adamc@16 119 Eval simpl in expDenote (Binop Times (Binop Plus (Const 2) (Const 2)) (Const 7)).
adamc@205 120 (** [= 28 : nat] *)
adamc@9 121
adamc@20 122 (** ** Target Language *)
adamc@4 123
adamc@10 124 (** We will compile our source programs onto a simple stack machine, whose syntax is: *)
adamc@2 125
adamc@4 126 Inductive instr : Set :=
adamc@4 127 | IConst : nat -> instr
adamc@4 128 | IBinop : binop -> instr.
adamc@2 129
adamc@4 130 Definition prog := list instr.
adamc@4 131 Definition stack := list nat.
adamc@2 132
adamc@10 133 (** An instruction either pushes a constant onto the stack or pops two arguments, applies a binary operator to them, and pushes the result onto the stack. A program is a list of instructions, and a stack is a list of natural numbers.
adamc@10 134
adamc@10 135 We can give instructions meanings as functions from stacks to optional stacks, where running an instruction results in [None] in case of a stack underflow and results in [Some s'] when the result of execution is the new stack [s']. [::] is the "list cons" operator from the Coq standard library. *)
adamc@10 136
adamc@4 137 Definition instrDenote (i : instr) (s : stack) : option stack :=
adamc@4 138 match i with
adamc@4 139 | IConst n => Some (n :: s)
adamc@4 140 | IBinop b =>
adamc@4 141 match s with
adamc@4 142 | arg1 :: arg2 :: s' => Some ((binopDenote b) arg1 arg2 :: s')
adamc@4 143 | _ => None
adamc@4 144 end
adamc@4 145 end.
adamc@2 146
adamc@206 147 (** With [instrDenote] defined, it is easy to define a function [progDenote], which iterates application of [instrDenote] through a whole program.
adamc@10 148
adamc@206 149 [[
adamc@4 150 Fixpoint progDenote (p : prog) (s : stack) {struct p} : option stack :=
adamc@4 151 match p with
adamc@4 152 | nil => Some s
adamc@4 153 | i :: p' =>
adamc@4 154 match instrDenote i s with
adamc@4 155 | None => None
adamc@4 156 | Some s' => progDenote p' s'
adamc@4 157 end
adamc@4 158 end.
adamc@2 159
adamc@206 160 ]]
adamc@206 161
adamc@206 162 There is one interesting difference compared to our previous example of a [Fixpoint]. This recursive function takes two arguments, [p] and [s]. It is critical for the soundness of Coq that every program terminate, so a shallow syntactic termination check is imposed on every recursive function definition. One of the function parameters must be designated to decrease monotonically across recursive calls. That is, every recursive call must use a version of that argument that has been pulled out of the current argument by some number of [match] expressions. [expDenote] has only one argument, so we did not need to specify which of its arguments decreases. For [progDenote], we resolve the ambiguity by writing [{struct p}] to indicate that argument [p] decreases structurally.
adamc@206 163
adamc@206 164 Recent versions of Coq will also infer a termination argument, so that we may write simply: *)
adamc@206 165
adamc@206 166 Fixpoint progDenote (p : prog) (s : stack) : option stack :=
adamc@206 167 match p with
adamc@206 168 | nil => Some s
adamc@206 169 | i :: p' =>
adamc@206 170 match instrDenote i s with
adamc@206 171 | None => None
adamc@206 172 | Some s' => progDenote p' s'
adamc@206 173 end
adamc@206 174 end.
adamc@2 175
adamc@4 176
adamc@9 177 (** ** Translation *)
adamc@4 178
adamc@10 179 (** Our compiler itself is now unsurprising. [++] is the list concatenation operator from the Coq standard library. *)
adamc@2 180
adamc@4 181 Fixpoint compile (e : exp) : prog :=
adamc@4 182 match e with
adamc@4 183 | Const n => IConst n :: nil
adamc@4 184 | Binop b e1 e2 => compile e2 ++ compile e1 ++ IBinop b :: nil
adamc@4 185 end.
adamc@2 186
adamc@2 187
adamc@16 188 (** Before we set about proving that this compiler is correct, we can try a few test runs, using our sample programs from earlier. *)
adamc@16 189
adamc@16 190 Eval simpl in compile (Const 42).
adamc@206 191 (** [= IConst 42 :: nil : prog] *)
adamc@206 192
adamc@16 193 Eval simpl in compile (Binop Plus (Const 2) (Const 2)).
adamc@206 194 (** [= IConst 2 :: IConst 2 :: IBinop Plus :: nil : prog] *)
adamc@206 195
adamc@16 196 Eval simpl in compile (Binop Times (Binop Plus (Const 2) (Const 2)) (Const 7)).
adamc@206 197 (** [= IConst 7 :: IConst 2 :: IConst 2 :: IBinop Plus :: IBinop Times :: nil : prog] *)
adamc@16 198
adamc@40 199 (** We can also run our compiled programs and check that they give the right results. *)
adamc@16 200
adamc@16 201 Eval simpl in progDenote (compile (Const 42)) nil.
adamc@206 202 (** [= Some (42 :: nil) : option stack] *)
adamc@206 203
adamc@16 204 Eval simpl in progDenote (compile (Binop Plus (Const 2) (Const 2))) nil.
adamc@206 205 (** [= Some (4 :: nil) : option stack] *)
adamc@206 206
adamc@16 207 Eval simpl in progDenote (compile (Binop Times (Binop Plus (Const 2) (Const 2)) (Const 7))) nil.
adamc@206 208 (** [= Some (28 :: nil) : option stack] *)
adamc@16 209
adamc@16 210
adamc@20 211 (** ** Translation Correctness *)
adamc@4 212
adamc@11 213 (** We are ready to prove that our compiler is implemented correctly. We can use a new vernacular command [Theorem] to start a correctness proof, in terms of the semantics we defined earlier: *)
adamc@11 214
adamc@26 215 Theorem compile_correct : forall e, progDenote (compile e) nil = Some (expDenote e :: nil).
adamc@11 216 (* begin hide *)
adamc@11 217 Abort.
adamc@11 218 (* end hide *)
adamc@22 219 (* begin thide *)
adamc@11 220
adamc@11 221 (** Though a pencil-and-paper proof might clock out at this point, writing "by a routine induction on [e]," it turns out not to make sense to attack this proof directly. We need to use the standard trick of %\textit{%#<i>#strengthening the induction hypothesis#</i>#%}%. We do that by proving an auxiliary lemma:
adamc@11 222 *)
adamc@2 223
adamc@206 224 Lemma compile_correct' : forall e p s,
adamc@206 225 progDenote (compile e ++ p) s = progDenote p (expDenote e :: s).
adamc@11 226
adamc@11 227 (** After the period in the [Lemma] command, we are in %\textit{%#<i>#the interactive proof-editing mode#</i>#%}%. We find ourselves staring at this ominous screen of text:
adamc@11 228
adamc@11 229 [[
adamc@11 230 1 subgoal
adamc@11 231
adamc@11 232 ============================
adamc@15 233 forall (e : exp) (p : list instr) (s : stack),
adamc@15 234 progDenote (compile e ++ p) s = progDenote p (expDenote e :: s)
adamc@206 235
adamc@11 236 ]]
adamc@11 237
adamc@11 238 Coq seems to be restating the lemma for us. What we are seeing is a limited case of a more general protocol for describing where we are in a proof. We are told that we have a single subgoal. In general, during a proof, we can have many pending subgoals, each of which is a logical proposition to prove. Subgoals can be proved in any order, but it usually works best to prove them in the order that Coq chooses.
adamc@11 239
adamc@11 240 Next in the output, we see our single subgoal described in full detail. There is a double-dashed line, above which would be our free variables and hypotheses, if we had any. Below the line is the conclusion, which, in general, is to be proved from the hypotheses.
adamc@11 241
adamc@11 242 We manipulate the proof state by running commands called %\textit{%#<i>#tactics#</i>#%}%. Let us start out by running one of the most important tactics:
adamc@11 243 *)
adamc@11 244
adamc@4 245 induction e.
adamc@2 246
adamc@11 247 (** We declare that this proof will proceed by induction on the structure of the expression [e]. This swaps out our initial subgoal for two new subgoals, one for each case of the inductive proof:
adamc@11 248
adamc@11 249 [[
adamc@11 250 2 subgoals
adamc@11 251
adamc@11 252 n : nat
adamc@11 253 ============================
adamc@11 254 forall (s : stack) (p : list instr),
adamc@11 255 progDenote (compile (Const n) ++ p) s =
adamc@11 256 progDenote p (expDenote (Const n) :: s)
adamc@11 257 ]]
adamc@11 258 [[
adamc@11 259 subgoal 2 is:
adamc@11 260 forall (s : stack) (p : list instr),
adamc@11 261 progDenote (compile (Binop b e1 e2) ++ p) s =
adamc@11 262 progDenote p (expDenote (Binop b e1 e2) :: s)
adamc@206 263
adamc@11 264 ]]
adamc@11 265
adamc@11 266 The first and current subgoal is displayed with the double-dashed line below free variables and hypotheses, while later subgoals are only summarized with their conclusions. We see an example of a free variable in the first subgoal; [n] is a free variable of type [nat]. The conclusion is the original theorem statement where [e] has been replaced by [Const n]. In a similar manner, the second case has [e] replaced by a generalized invocation of the [Binop] expression constructor. We can see that proving both cases corresponds to a standard proof by structural induction.
adamc@11 267
adamc@11 268 We begin the first case with another very common tactic.
adamc@11 269 *)
adamc@11 270
adamc@4 271 intros.
adamc@11 272
adamc@11 273 (** The current subgoal changes to:
adamc@11 274 [[
adamc@11 275
adamc@11 276 n : nat
adamc@11 277 s : stack
adamc@11 278 p : list instr
adamc@11 279 ============================
adamc@11 280 progDenote (compile (Const n) ++ p) s =
adamc@11 281 progDenote p (expDenote (Const n) :: s)
adamc@206 282
adamc@11 283 ]]
adamc@11 284
adamc@11 285 We see that [intros] changes [forall]-bound variables at the beginning of a goal into free variables.
adamc@11 286
adamc@11 287 To progress further, we need to use the definitions of some of the functions appearing in the goal. The [unfold] tactic replaces an identifier with its definition.
adamc@11 288 *)
adamc@11 289
adamc@4 290 unfold compile.
adamc@11 291 (** [[
adamc@11 292 n : nat
adamc@11 293 s : stack
adamc@11 294 p : list instr
adamc@11 295 ============================
adamc@11 296 progDenote ((IConst n :: nil) ++ p) s =
adamc@11 297 progDenote p (expDenote (Const n) :: s)
adamc@206 298
adamc@11 299 ]] *)
adamc@11 300
adamc@4 301 unfold expDenote.
adamc@11 302 (** [[
adamc@11 303 n : nat
adamc@11 304 s : stack
adamc@11 305 p : list instr
adamc@11 306 ============================
adamc@11 307 progDenote ((IConst n :: nil) ++ p) s = progDenote p (n :: s)
adamc@206 308
adamc@11 309 ]]
adamc@11 310
adamc@11 311 We only need to unfold the first occurrence of [progDenote] to prove the goal: *)
adamc@11 312
adamc@11 313 unfold progDenote at 1.
adamc@11 314
adamc@11 315 (** [[
adamc@11 316
adamc@11 317 n : nat
adamc@11 318 s : stack
adamc@11 319 p : list instr
adamc@11 320 ============================
adamc@11 321 (fix progDenote (p0 : prog) (s0 : stack) {struct p0} :
adamc@11 322 option stack :=
adamc@11 323 match p0 with
adamc@11 324 | nil => Some s0
adamc@11 325 | i :: p' =>
adamc@11 326 match instrDenote i s0 with
adamc@11 327 | Some s' => progDenote p' s'
adamc@11 328 | None => None (A:=stack)
adamc@11 329 end
adamc@11 330 end) ((IConst n :: nil) ++ p) s =
adamc@11 331 progDenote p (n :: s)
adamc@206 332
adamc@11 333 ]]
adamc@11 334
adamc@11 335 This last [unfold] has left us with an anonymous fixpoint version of [progDenote], which will generally happen when unfolding recursive definitions. Fortunately, in this case, we can eliminate such complications right away, since the structure of the argument [(IConst n :: nil) ++ p] is known, allowing us to simplify the internal pattern match with the [simpl] tactic:
adamc@11 336 *)
adamc@11 337
adamc@4 338 simpl.
adamc@11 339 (** [[
adamc@11 340 n : nat
adamc@11 341 s : stack
adamc@11 342 p : list instr
adamc@11 343 ============================
adamc@11 344 (fix progDenote (p0 : prog) (s0 : stack) {struct p0} :
adamc@11 345 option stack :=
adamc@11 346 match p0 with
adamc@11 347 | nil => Some s0
adamc@11 348 | i :: p' =>
adamc@11 349 match instrDenote i s0 with
adamc@11 350 | Some s' => progDenote p' s'
adamc@11 351 | None => None (A:=stack)
adamc@11 352 end
adamc@11 353 end) p (n :: s) = progDenote p (n :: s)
adamc@206 354
adamc@11 355 ]]
adamc@11 356
adamc@11 357 Now we can unexpand the definition of [progDenote]:
adamc@11 358 *)
adamc@11 359
adamc@11 360 fold progDenote.
adamc@11 361
adamc@11 362 (** [[
adamc@11 363
adamc@11 364 n : nat
adamc@11 365 s : stack
adamc@11 366 p : list instr
adamc@11 367 ============================
adamc@11 368 progDenote p (n :: s) = progDenote p (n :: s)
adamc@206 369
adamc@11 370 ]]
adamc@11 371
adamc@11 372 It looks like we are at the end of this case, since we have a trivial equality. Indeed, a single tactic finishes us off:
adamc@11 373 *)
adamc@11 374
adamc@4 375 reflexivity.
adamc@2 376
adamc@11 377 (** On to the second inductive case:
adamc@11 378
adamc@11 379 [[
adamc@11 380 b : binop
adamc@11 381 e1 : exp
adamc@11 382 IHe1 : forall (s : stack) (p : list instr),
adamc@11 383 progDenote (compile e1 ++ p) s = progDenote p (expDenote e1 :: s)
adamc@11 384 e2 : exp
adamc@11 385 IHe2 : forall (s : stack) (p : list instr),
adamc@11 386 progDenote (compile e2 ++ p) s = progDenote p (expDenote e2 :: s)
adamc@11 387 ============================
adamc@11 388 forall (s : stack) (p : list instr),
adamc@11 389 progDenote (compile (Binop b e1 e2) ++ p) s =
adamc@11 390 progDenote p (expDenote (Binop b e1 e2) :: s)
adamc@206 391
adamc@11 392 ]]
adamc@11 393
adamc@11 394 We see our first example of hypotheses above the double-dashed line. They are the inductive hypotheses [IHe1] and [IHe2] corresponding to the subterms [e1] and [e2], respectively.
adamc@11 395
adamc@11 396 We start out the same way as before, introducing new free variables and unfolding and folding the appropriate definitions. The seemingly frivolous [unfold]/[fold] pairs are actually accomplishing useful work, because [unfold] will sometimes perform easy simplifications. *)
adamc@11 397
adamc@4 398 intros.
adamc@4 399 unfold compile.
adamc@4 400 fold compile.
adamc@4 401 unfold expDenote.
adamc@4 402 fold expDenote.
adamc@11 403
adamc@44 404 (** Now we arrive at a point where the tactics we have seen so far are insufficient. No further definition unfoldings get us anywhere, so we will need to try something different.
adamc@11 405
adamc@11 406 [[
adamc@11 407 b : binop
adamc@11 408 e1 : exp
adamc@11 409 IHe1 : forall (s : stack) (p : list instr),
adamc@11 410 progDenote (compile e1 ++ p) s = progDenote p (expDenote e1 :: s)
adamc@11 411 e2 : exp
adamc@11 412 IHe2 : forall (s : stack) (p : list instr),
adamc@11 413 progDenote (compile e2 ++ p) s = progDenote p (expDenote e2 :: s)
adamc@11 414 s : stack
adamc@11 415 p : list instr
adamc@11 416 ============================
adamc@11 417 progDenote ((compile e2 ++ compile e1 ++ IBinop b :: nil) ++ p) s =
adamc@11 418 progDenote p (binopDenote b (expDenote e1) (expDenote e2) :: s)
adamc@206 419
adamc@11 420 ]]
adamc@11 421
adamc@11 422 What we need is the associative law of list concatenation, available as a theorem [app_ass] in the standard library. *)
adamc@11 423
adamc@11 424 Check app_ass.
adamc@11 425 (** [[
adamc@11 426 app_ass
adamc@11 427 : forall (A : Type) (l m n : list A), (l ++ m) ++ n = l ++ m ++ n
adamc@206 428
adamc@11 429 ]]
adamc@11 430
adamc@11 431 We use it to perform a rewrite: *)
adamc@11 432
adamc@4 433 rewrite app_ass.
adamc@11 434
adamc@206 435 (** changing the conclusion to:
adamc@11 436
adamc@206 437 [[
adamc@11 438 progDenote (compile e2 ++ (compile e1 ++ IBinop b :: nil) ++ p) s =
adamc@11 439 progDenote p (binopDenote b (expDenote e1) (expDenote e2) :: s)
adamc@206 440
adamc@11 441 ]]
adamc@11 442
adamc@11 443 Now we can notice that the lefthand side of the equality matches the lefthand side of the second inductive hypothesis, so we can rewrite with that hypothesis, too: *)
adamc@11 444
adamc@4 445 rewrite IHe2.
adamc@11 446 (** [[
adamc@11 447 progDenote ((compile e1 ++ IBinop b :: nil) ++ p) (expDenote e2 :: s) =
adamc@11 448 progDenote p (binopDenote b (expDenote e1) (expDenote e2) :: s)
adamc@206 449
adamc@11 450 ]]
adamc@11 451
adamc@11 452 The same process lets us apply the remaining hypothesis. *)
adamc@11 453
adamc@4 454 rewrite app_ass.
adamc@4 455 rewrite IHe1.
adamc@11 456 (** [[
adamc@11 457 progDenote ((IBinop b :: nil) ++ p) (expDenote e1 :: expDenote e2 :: s) =
adamc@11 458 progDenote p (binopDenote b (expDenote e1) (expDenote e2) :: s)
adamc@206 459
adamc@11 460 ]]
adamc@11 461
adamc@11 462 Now we can apply a similar sequence of tactics to that that ended the proof of the first case.
adamc@11 463 *)
adamc@11 464
adamc@11 465 unfold progDenote at 1.
adamc@4 466 simpl.
adamc@11 467 fold progDenote.
adamc@4 468 reflexivity.
adamc@11 469
adamc@11 470 (** And the proof is completed, as indicated by the message:
adamc@11 471
adamc@11 472 [[
adamc@11 473 Proof completed.
adamc@11 474
adamc@205 475 ]]
adamc@205 476
adamc@11 477 And there lies our first proof. Already, even for simple theorems like this, the final proof script is unstructured and not very enlightening to readers. If we extend this approach to more serious theorems, we arrive at the unreadable proof scripts that are the favorite complaints of opponents of tactic-based proving. Fortunately, Coq has rich support for scripted automation, and we can take advantage of such a scripted tactic (defined elsewhere) to make short work of this lemma. We abort the old proof attempt and start again.
adamc@11 478 *)
adamc@11 479
adamc@4 480 Abort.
adamc@2 481
adamc@26 482 Lemma compile_correct' : forall e s p, progDenote (compile e ++ p) s =
adamc@4 483 progDenote p (expDenote e :: s).
adamc@4 484 induction e; crush.
adamc@4 485 Qed.
adamc@2 486
adamc@11 487 (** We need only to state the basic inductive proof scheme and call a tactic that automates the tedious reasoning in between. In contrast to the period tactic terminator from our last proof, the semicolon tactic separator supports structured, compositional proofs. The tactic [t1; t2] has the effect of running [t1] and then running [t2] on each remaining subgoal. The semicolon is one of the most fundamental building blocks of effective proof automation. The period terminator is very useful for exploratory proving, where you need to see intermediate proof states, but final proofs of any serious complexity should have just one period, terminating a single compound tactic that probably uses semicolons.
adamc@11 488
adamc@11 489 The proof of our main theorem is now easy. We prove it with four period-terminated tactics, though separating them with semicolons would work as well; the version here is easier to step through. *)
adamc@11 490
adamc@26 491 Theorem compile_correct : forall e, progDenote (compile e) nil = Some (expDenote e :: nil).
adamc@11 492 intros.
adamc@11 493 (** [[
adamc@11 494 e : exp
adamc@11 495 ============================
adamc@11 496 progDenote (compile e) nil = Some (expDenote e :: nil)
adamc@206 497
adamc@11 498 ]]
adamc@11 499
adamc@26 500 At this point, we want to massage the lefthand side to match the statement of [compile_correct']. A theorem from the standard library is useful: *)
adamc@11 501
adamc@11 502 Check app_nil_end.
adamc@11 503 (** [[
adamc@11 504 app_nil_end
adamc@11 505 : forall (A : Type) (l : list A), l = l ++ nil
adamc@11 506 ]] *)
adamc@11 507
adamc@4 508 rewrite (app_nil_end (compile e)).
adamc@11 509
adamc@11 510 (** This time, we explicitly specify the value of the variable [l] from the theorem statement, since multiple expressions of list type appear in the conclusion. [rewrite] might choose the wrong place to rewrite if we did not specify which we want.
adamc@11 511
adamc@11 512 [[
adamc@11 513 e : exp
adamc@11 514 ============================
adamc@11 515 progDenote (compile e ++ nil) nil = Some (expDenote e :: nil)
adamc@206 516
adamc@11 517 ]]
adamc@11 518
adamc@11 519 Now we can apply the lemma. *)
adamc@11 520
adamc@26 521 rewrite compile_correct'.
adamc@11 522 (** [[
adamc@11 523 e : exp
adamc@11 524 ============================
adamc@11 525 progDenote nil (expDenote e :: nil) = Some (expDenote e :: nil)
adamc@206 526
adamc@11 527 ]]
adamc@11 528
adamc@11 529 We are almost done. The lefthand and righthand sides can be seen to match by simple symbolic evaluation. That means we are in luck, because Coq identifies any pair of terms as equal whenever they normalize to the same result by symbolic evaluation. By the definition of [progDenote], that is the case here, but we do not need to worry about such details. A simple invocation of [reflexivity] does the normalization and checks that the two results are syntactically equal. *)
adamc@11 530
adamc@4 531 reflexivity.
adamc@4 532 Qed.
adamc@22 533 (* end thide *)
adamc@14 534
adamc@14 535
adamc@20 536 (** * Typed Expressions *)
adamc@14 537
adamc@14 538 (** In this section, we will build on the initial example by adding additional expression forms that depend on static typing of terms for safety. *)
adamc@14 539
adamc@20 540 (** ** Source Language *)
adamc@14 541
adamc@15 542 (** We define a trivial language of types to classify our expressions: *)
adamc@15 543
adamc@14 544 Inductive type : Set := Nat | Bool.
adamc@14 545
adamc@15 546 (** Now we define an expanded set of binary operators. *)
adamc@15 547
adamc@14 548 Inductive tbinop : type -> type -> type -> Set :=
adamc@14 549 | TPlus : tbinop Nat Nat Nat
adamc@14 550 | TTimes : tbinop Nat Nat Nat
adamc@14 551 | TEq : forall t, tbinop t t Bool
adamc@14 552 | TLt : tbinop Nat Nat Bool.
adamc@14 553
adamc@15 554 (** The definition of [tbinop] is different from [binop] in an important way. Where we declared that [binop] has type [Set], here we declare that [tbinop] has type [type -> type -> type -> Set]. We define [tbinop] as an %\textit{%#<i>#indexed type family#</i>#%}%. Indexed inductive types are at the heart of Coq's expressive power; almost everything else of interest is defined in terms of them.
adamc@15 555
adamc@15 556 ML and Haskell have indexed algebraic datatypes. For instance, their list types are indexed by the type of data that the list carries. However, compared to Coq, ML and Haskell 98 place two important restrictions on datatype definitions.
adamc@15 557
adamc@15 558 First, the indices of the range of each data constructor must be type variables bound at the top level of the datatype definition. There is no way to do what we did here, where we, for instance, say that [TPlus] is a constructor building a [tbinop] whose indices are all fixed at [Nat]. %\textit{%#<i>#Generalized algebraic datatypes (GADTs)#</i>#%}% are a popular feature in GHC Haskell and other languages that removes this first restriction.
adamc@15 559
adamc@40 560 The second restriction is not lifted by GADTs. In ML and Haskell, indices of types must be types and may not be %\textit{%#<i>#expressions#</i>#%}%. In Coq, types may be indexed by arbitrary Gallina terms. Type indices can live in the same universe as programs, and we can compute with them just like regular programs. Haskell supports a hobbled form of computation in type indices based on multi-parameter type classes, and recent extensions like type functions bring Haskell programming even closer to "real" functional programming with types, but, without dependent typing, there must always be a gap between how one programs with types and how one programs normally.
adamc@15 561 *)
adamc@15 562
adamc@15 563 (** We can define a similar type family for typed expressions. *)
adamc@15 564
adamc@14 565 Inductive texp : type -> Set :=
adamc@14 566 | TNConst : nat -> texp Nat
adamc@14 567 | TBConst : bool -> texp Bool
adamc@14 568 | TBinop : forall arg1 arg2 res, tbinop arg1 arg2 res -> texp arg1 -> texp arg2 -> texp res.
adamc@14 569
adamc@15 570 (** Thanks to our use of dependent types, every well-typed [texp] represents a well-typed source expression, by construction. This turns out to be very convenient for many things we might want to do with expressions. For instance, it is easy to adapt our interpreter approach to defining semantics. We start by defining a function mapping the types of our languages into Coq types: *)
adamc@15 571
adamc@14 572 Definition typeDenote (t : type) : Set :=
adamc@14 573 match t with
adamc@14 574 | Nat => nat
adamc@14 575 | Bool => bool
adamc@14 576 end.
adamc@14 577
adamc@15 578 (** It can take a few moments to come to terms with the fact that [Set], the type of types of programs, is itself a first-class type, and that we can write functions that return [Set]s. Past that wrinkle, the definition of [typeDenote] is trivial, relying on the [nat] and [bool] types from the Coq standard library.
adamc@15 579
adamc@15 580 We need to define a few auxiliary functions, implementing our boolean binary operators that do not appear with the right types in the standard library. They are entirely standard and ML-like, with the one caveat being that the Coq [nat] type uses a unary representation, where [O] is zero and [S n] is the successor of [n].
adamc@15 581 *)
adamc@15 582
adamc@14 583 Definition eq_bool (b1 b2 : bool) : bool :=
adamc@14 584 match b1, b2 with
adamc@14 585 | true, true => true
adamc@14 586 | false, false => true
adamc@14 587 | _, _ => false
adamc@14 588 end.
adamc@14 589
adamc@14 590 Fixpoint eq_nat (n1 n2 : nat) {struct n1} : bool :=
adamc@14 591 match n1, n2 with
adamc@14 592 | O, O => true
adamc@14 593 | S n1', S n2' => eq_nat n1' n2'
adamc@14 594 | _, _ => false
adamc@14 595 end.
adamc@14 596
adamc@14 597 Fixpoint lt (n1 n2 : nat) {struct n1} : bool :=
adamc@14 598 match n1, n2 with
adamc@14 599 | O, S _ => true
adamc@14 600 | S n1', S n2' => lt n1' n2'
adamc@14 601 | _, _ => false
adamc@14 602 end.
adamc@14 603
adamc@15 604 (** Now we can interpret binary operators: *)
adamc@15 605
adamc@14 606 Definition tbinopDenote arg1 arg2 res (b : tbinop arg1 arg2 res)
adamc@14 607 : typeDenote arg1 -> typeDenote arg2 -> typeDenote res :=
adamc@14 608 match b in (tbinop arg1 arg2 res) return (typeDenote arg1 -> typeDenote arg2 -> typeDenote res) with
adamc@14 609 | TPlus => plus
adamc@14 610 | TTimes => mult
adamc@14 611 | TEq Nat => eq_nat
adamc@14 612 | TEq Bool => eq_bool
adamc@14 613 | TLt => lt
adamc@14 614 end.
adamc@14 615
adamc@15 616 (** This function has just a few differences from the denotation functions we saw earlier. First, [tbinop] is an indexed type, so its indices become additional arguments to [tbinopDenote]. Second, we need to perform a genuine %\textit{%#<i>#dependent pattern match#</i>#%}% to come up with a definition of this function that type-checks. In each branch of the [match], we need to use branch-specific information about the indices to [tbinop]. General type inference that takes such information into account is undecidable, and Coq avoids pursuing special heuristics for the problem, instead asking users to write annotations, like we see above on the line with [match].
adamc@15 617
adamc@40 618 The [in] annotation restates the type of the term being case-analyzed. Though we use the same names for the indices as we use in the type of the original argument binder, these are actually fresh variables, and they are %\textit{%#<i>#binding occurrences#</i>#%}%. Their scope is the [return] clause. That is, [arg1], [arg2], and [arg3] are new bound variables bound only within the return clause [typeDenote arg1 -> typeDenote arg2 -> typeDenote res]. By being explicit about the functional relationship between the type indices and the match result, we regain decidable type inference.
adamc@15 619
adamc@15 620 The same tricks suffice to define an expression denotation function in an unsurprising way:
adamc@15 621 *)
adamc@15 622
adamc@14 623 Fixpoint texpDenote t (e : texp t) {struct e} : typeDenote t :=
adamc@14 624 match e in (texp t) return (typeDenote t) with
adamc@14 625 | TNConst n => n
adamc@14 626 | TBConst b => b
adamc@14 627 | TBinop _ _ _ b e1 e2 => (tbinopDenote b) (texpDenote e1) (texpDenote e2)
adamc@14 628 end.
adamc@14 629
adamc@17 630 (** We can evaluate a few example programs to convince ourselves that this semantics is correct. *)
adamc@17 631
adamc@17 632 Eval simpl in texpDenote (TNConst 42).
adamc@18 633 (** [[
adamc@18 634 = 42 : typeDenote Nat
adamc@18 635 ]] *)
adamc@17 636 Eval simpl in texpDenote (TBConst true).
adamc@18 637 (** [[
adamc@18 638 = true : typeDenote Bool
adamc@18 639 ]] *)
adamc@17 640 Eval simpl in texpDenote (TBinop TTimes (TBinop TPlus (TNConst 2) (TNConst 2)) (TNConst 7)).
adamc@18 641 (** [[
adamc@18 642 = 28 : typeDenote Nat
adamc@18 643 ]] *)
adamc@17 644 Eval simpl in texpDenote (TBinop (TEq Nat) (TBinop TPlus (TNConst 2) (TNConst 2)) (TNConst 7)).
adamc@18 645 (** [[
adamc@18 646 = false : typeDenote Bool
adamc@18 647 ]] *)
adamc@17 648 Eval simpl in texpDenote (TBinop TLt (TBinop TPlus (TNConst 2) (TNConst 2)) (TNConst 7)).
adamc@18 649 (** [[
adamc@18 650 = true : typeDenote Bool
adamc@18 651 ]] *)
adamc@17 652
adamc@14 653
adamc@20 654 (** ** Target Language *)
adamc@14 655
adamc@18 656 (** Now we want to define a suitable stack machine target for compilation. In the example of the untyped language, stack machine programs could encounter stack underflows and "get stuck." This was unfortunate, since we had to deal with this complication even though we proved that our compiler never produced underflowing programs. We could have used dependent types to force all stack machine programs to be underflow-free.
adamc@18 657
adamc@18 658 For our new languages, besides underflow, we also have the problem of stack slots with naturals instead of bools or vice versa. This time, we will use indexed typed families to avoid the need to reason about potential failures.
adamc@18 659
adamc@18 660 We start by defining stack types, which classify sets of possible stacks. *)
adamc@18 661
adamc@14 662 Definition tstack := list type.
adamc@14 663
adamc@18 664 (** Any stack classified by a [tstack] must have exactly as many elements, and each stack element must have the type found in the same position of the stack type.
adamc@18 665
adamc@18 666 We can define instructions in terms of stack types, where every instruction's type tells us what initial stack type it expects and what final stack type it will produce. *)
adamc@18 667
adamc@14 668 Inductive tinstr : tstack -> tstack -> Set :=
adamc@14 669 | TINConst : forall s, nat -> tinstr s (Nat :: s)
adamc@14 670 | TIBConst : forall s, bool -> tinstr s (Bool :: s)
adamc@14 671 | TIBinop : forall arg1 arg2 res s,
adamc@14 672 tbinop arg1 arg2 res
adamc@14 673 -> tinstr (arg1 :: arg2 :: s) (res :: s).
adamc@14 674
adamc@18 675 (** Stack machine programs must be a similar inductive family, since, if we again used the [list] type family, we would not be able to guarantee that intermediate stack types match within a program. *)
adamc@18 676
adamc@14 677 Inductive tprog : tstack -> tstack -> Set :=
adamc@14 678 | TNil : forall s, tprog s s
adamc@14 679 | TCons : forall s1 s2 s3,
adamc@14 680 tinstr s1 s2
adamc@14 681 -> tprog s2 s3
adamc@14 682 -> tprog s1 s3.
adamc@14 683
adamc@18 684 (** Now, to define the semantics of our new target language, we need a representation for stacks at runtime. We will again take advantage of type information to define types of value stacks that, by construction, contain the right number and types of elements. *)
adamc@18 685
adamc@14 686 Fixpoint vstack (ts : tstack) : Set :=
adamc@14 687 match ts with
adamc@14 688 | nil => unit
adamc@14 689 | t :: ts' => typeDenote t * vstack ts'
adamc@14 690 end%type.
adamc@14 691
adamc@18 692 (** This is another [Set]-valued function. This time it is recursive, which is perfectly valid, since [Set] is not treated specially in determining which functions may be written. We say that the value stack of an empty stack type is any value of type [unit], which has just a single value, [tt]. A nonempty stack type leads to a value stack that is a pair, whose first element has the proper type and whose second element follows the representation for the remainder of the stack type.
adamc@18 693
adamc@18 694 This idea of programming with types can take a while to internalize, but it enables a very simple definition of instruction denotation. We have the same kind of type annotations for the dependent [match], but everything else is like what you might expect from a Lisp-like version of ML that ignored type information. Nonetheless, the fact that [tinstrDenote] passes the type-checker guarantees that our stack machine programs can never go wrong. *)
adamc@18 695
adamc@14 696 Definition tinstrDenote ts ts' (i : tinstr ts ts') : vstack ts -> vstack ts' :=
adamc@14 697 match i in (tinstr ts ts') return (vstack ts -> vstack ts') with
adamc@14 698 | TINConst _ n => fun s => (n, s)
adamc@14 699 | TIBConst _ b => fun s => (b, s)
adamc@14 700 | TIBinop _ _ _ _ b => fun s =>
adamc@14 701 match s with
adamc@14 702 (arg1, (arg2, s')) => ((tbinopDenote b) arg1 arg2, s')
adamc@14 703 end
adamc@14 704 end.
adamc@14 705
adamc@18 706 (** Why do we choose to use an anonymous function to bind the initial stack in every case of the [match]? Consider this well-intentioned but invalid alternative version:
adamc@18 707
adamc@18 708 [[
adamc@18 709 Definition tinstrDenote ts ts' (i : tinstr ts ts') (s : vstack ts) : vstack ts' :=
adamc@18 710 match i in (tinstr ts ts') return (vstack ts') with
adamc@18 711 | TINConst _ n => (n, s)
adamc@18 712 | TIBConst _ b => (b, s)
adamc@18 713 | TIBinop _ _ _ _ b =>
adamc@18 714 match s with
adamc@18 715 (arg1, (arg2, s')) => ((tbinopDenote b) arg1 arg2, s')
adamc@18 716 end
adamc@18 717 end.
adamc@18 718
adamc@205 719 ]]
adamc@205 720
adamc@18 721 The Coq type-checker complains that:
adamc@18 722
adamc@18 723 [[
adamc@18 724 The term "(n, s)" has type "(nat * vstack ts)%type"
adamc@18 725 while it is expected to have type "vstack (Nat :: t)"
adamc@18 726 ]]
adamc@18 727
adamc@18 728 Recall from our earlier discussion of [match] annotations that we write the annotations to express to the type-checker the relationship between the type indices of the case object and the result type of the [match]. Coq chooses to assign to the wildcard [_] after [TINConst] the name [t], and the type error is telling us that the type checker cannot prove that [t] is the same as [ts]. By moving [s] out of the [match], we lose the ability to express, with [in] and [return] clauses, the relationship between the shared index [ts] of [s] and [i].
adamc@18 729
adamc@18 730 There %\textit{%#<i>#are#</i>#%}% reasonably general ways of getting around this problem without pushing binders inside [match]es. However, the alternatives are significantly more involved, and the technique we use here is almost certainly the best choice, whenever it applies.
adamc@18 731
adamc@18 732 *)
adamc@18 733
adamc@18 734 (** We finish the semantics with a straightforward definition of program denotation. *)
adamc@18 735
adamc@14 736 Fixpoint tprogDenote ts ts' (p : tprog ts ts') {struct p} : vstack ts -> vstack ts' :=
adamc@14 737 match p in (tprog ts ts') return (vstack ts -> vstack ts') with
adamc@14 738 | TNil _ => fun s => s
adamc@14 739 | TCons _ _ _ i p' => fun s => tprogDenote p' (tinstrDenote i s)
adamc@14 740 end.
adamc@14 741
adamc@14 742
adamc@14 743 (** ** Translation *)
adamc@14 744
adamc@19 745 (** To define our compilation, it is useful to have an auxiliary function for concatenating two stack machine programs. *)
adamc@19 746
adamc@14 747 Fixpoint tconcat ts ts' ts'' (p : tprog ts ts') {struct p} : tprog ts' ts'' -> tprog ts ts'' :=
adamc@14 748 match p in (tprog ts ts') return (tprog ts' ts'' -> tprog ts ts'') with
adamc@14 749 | TNil _ => fun p' => p'
adamc@14 750 | TCons _ _ _ i p1 => fun p' => TCons i (tconcat p1 p')
adamc@14 751 end.
adamc@14 752
adamc@19 753 (** With that function in place, the compilation is defined very similarly to how it was before, modulo the use of dependent typing. *)
adamc@19 754
adamc@14 755 Fixpoint tcompile t (e : texp t) (ts : tstack) {struct e} : tprog ts (t :: ts) :=
adamc@14 756 match e in (texp t) return (tprog ts (t :: ts)) with
adamc@14 757 | TNConst n => TCons (TINConst _ n) (TNil _)
adamc@14 758 | TBConst b => TCons (TIBConst _ b) (TNil _)
adamc@14 759 | TBinop _ _ _ b e1 e2 => tconcat (tcompile e2 _)
adamc@14 760 (tconcat (tcompile e1 _) (TCons (TIBinop _ b) (TNil _)))
adamc@14 761 end.
adamc@14 762
adamc@40 763 (** One interesting feature of the definition is the underscores appearing to the right of [=>] arrows. Haskell and ML programmers are quite familiar with compilers that infer type parameters to polymorphic values. In Coq, it is possible to go even further and ask the system to infer arbitrary terms, by writing underscores in place of specific values. You may have noticed that we have been calling functions without specifying all of their arguments. For instance, the recursive calls here to [tcompile] omit the [t] argument. Coq's %\textit{%#<i>#implicit argument#</i>#%}% mechanism automatically inserts underscores for arguments that it will probably be able to infer. Inference of such values is far from complete, though; generally, it only works in cases similar to those encountered with polymorphic type instantiation in Haskell and ML.
adamc@19 764
adamc@19 765 The underscores here are being filled in with stack types. That is, the Coq type inferencer is, in a sense, inferring something about the flow of control in the translated programs. We can take a look at exactly which values are filled in: *)
adamc@19 766
adamc@14 767 Print tcompile.
adamc@14 768
adamc@19 769 (** [[
adamc@19 770
adamc@19 771 tcompile =
adamc@19 772 fix tcompile (t : type) (e : texp t) (ts : tstack) {struct e} :
adamc@19 773 tprog ts (t :: ts) :=
adamc@19 774 match e in (texp t0) return (tprog ts (t0 :: ts)) with
adamc@19 775 | TNConst n => TCons (TINConst ts n) (TNil (Nat :: ts))
adamc@19 776 | TBConst b => TCons (TIBConst ts b) (TNil (Bool :: ts))
adamc@19 777 | TBinop arg1 arg2 res b e1 e2 =>
adamc@19 778 tconcat (tcompile arg2 e2 ts)
adamc@19 779 (tconcat (tcompile arg1 e1 (arg2 :: ts))
adamc@19 780 (TCons (TIBinop ts b) (TNil (res :: ts))))
adamc@19 781 end
adamc@19 782 : forall t : type, texp t -> forall ts : tstack, tprog ts (t :: ts)
adamc@19 783 ]] *)
adamc@19 784
adamc@19 785
adamc@19 786 (** We can check that the compiler generates programs that behave appropriately on our sample programs from above: *)
adamc@19 787
adamc@19 788 Eval simpl in tprogDenote (tcompile (TNConst 42) nil) tt.
adamc@19 789 (** [[
adamc@19 790 = (42, tt) : vstack (Nat :: nil)
adamc@19 791 ]] *)
adamc@19 792 Eval simpl in tprogDenote (tcompile (TBConst true) nil) tt.
adamc@19 793 (** [[
adamc@19 794 = (true, tt) : vstack (Bool :: nil)
adamc@19 795 ]] *)
adamc@19 796 Eval simpl in tprogDenote (tcompile (TBinop TTimes (TBinop TPlus (TNConst 2) (TNConst 2)) (TNConst 7)) nil) tt.
adamc@19 797 (** [[
adamc@19 798 = (28, tt) : vstack (Nat :: nil)
adamc@19 799 ]] *)
adamc@19 800 Eval simpl in tprogDenote (tcompile (TBinop (TEq Nat) (TBinop TPlus (TNConst 2) (TNConst 2)) (TNConst 7)) nil) tt.
adamc@19 801 (** [[
adamc@19 802 = (false, tt) : vstack (Bool :: nil)
adamc@19 803 ]] *)
adamc@19 804 Eval simpl in tprogDenote (tcompile (TBinop TLt (TBinop TPlus (TNConst 2) (TNConst 2)) (TNConst 7)) nil) tt.
adamc@19 805 (** [[
adamc@19 806 = (true, tt) : vstack (Bool :: nil)
adamc@19 807 ]] *)
adamc@19 808
adamc@14 809
adamc@20 810 (** ** Translation Correctness *)
adamc@20 811
adamc@20 812 (** We can state a correctness theorem similar to the last one. *)
adamc@20 813
adamc@26 814 Theorem tcompile_correct : forall t (e : texp t), tprogDenote (tcompile e nil) tt = (texpDenote e, tt).
adamc@20 815 (* begin hide *)
adamc@20 816 Abort.
adamc@20 817 (* end hide *)
adamc@22 818 (* begin thide *)
adamc@20 819
adamc@20 820 (** Again, we need to strengthen the theorem statement so that the induction will go through. This time, I will develop an alternative approach to this kind of proof, stating the key lemma as: *)
adamc@14 821
adamc@26 822 Lemma tcompile_correct' : forall t (e : texp t)
adamc@14 823 ts (s : vstack ts),
adamc@14 824 tprogDenote (tcompile e ts) s
adamc@14 825 = (texpDenote e, s).
adamc@20 826
adamc@26 827 (** While lemma [compile_correct'] quantified over a program that is the "continuation" for the expression we are considering, here we avoid drawing in any extra syntactic elements. In addition to the source expression and its type, we also quantify over an initial stack type and a stack compatible with it. Running the compilation of the program starting from that stack, we should arrive at a stack that differs only in having the program's denotation pushed onto it.
adamc@20 828
adamc@20 829 Let us try to prove this theorem in the same way that we settled on in the last section. *)
adamc@20 830
adamc@14 831 induction e; crush.
adamc@20 832
adamc@20 833 (** We are left with this unproved conclusion:
adamc@20 834
adamc@20 835 [[
adamc@20 836
adamc@20 837 tprogDenote
adamc@20 838 (tconcat (tcompile e2 ts)
adamc@20 839 (tconcat (tcompile e1 (arg2 :: ts))
adamc@20 840 (TCons (TIBinop ts t) (TNil (res :: ts))))) s =
adamc@20 841 (tbinopDenote t (texpDenote e1) (texpDenote e2), s)
adamc@20 842 ]]
adamc@20 843
adamc@20 844 We need an analogue to the [app_ass] theorem that we used to rewrite the goal in the last section. We can abort this proof and prove such a lemma about [tconcat].
adamc@20 845 *)
adamc@14 846 Abort.
adamc@14 847
adamc@26 848 Lemma tconcat_correct : forall ts ts' ts'' (p : tprog ts ts') (p' : tprog ts' ts'')
adamc@14 849 (s : vstack ts),
adamc@14 850 tprogDenote (tconcat p p') s
adamc@14 851 = tprogDenote p' (tprogDenote p s).
adamc@14 852 induction p; crush.
adamc@14 853 Qed.
adamc@14 854
adamc@20 855 (** This one goes through completely automatically.
adamc@20 856
adamc@26 857 Some code behind the scenes registers [app_ass] for use by [crush]. We must register [tconcat_correct] similarly to get the same effect: *)
adamc@20 858
adamc@26 859 Hint Rewrite tconcat_correct : cpdt.
adamc@14 860
adamc@26 861 (** We ask that the lemma be used for left-to-right rewriting, and we ask for the hint to be added to the hint database called [cpdt], which is the database used by [crush]. Now we are ready to return to [tcompile_correct'], proving it automatically this time. *)
adamc@20 862
adamc@26 863 Lemma tcompile_correct' : forall t (e : texp t)
adamc@14 864 ts (s : vstack ts),
adamc@14 865 tprogDenote (tcompile e ts) s
adamc@14 866 = (texpDenote e, s).
adamc@14 867 induction e; crush.
adamc@14 868 Qed.
adamc@14 869
adamc@20 870 (** We can register this main lemma as another hint, allowing us to prove the final theorem trivially. *)
adamc@20 871
adamc@26 872 Hint Rewrite tcompile_correct' : cpdt.
adamc@14 873
adamc@26 874 Theorem tcompile_correct : forall t (e : texp t), tprogDenote (tcompile e nil) tt = (texpDenote e, tt).
adamc@14 875 crush.
adamc@14 876 Qed.
adamc@22 877 (* end thide *)